spmd_sd_gau.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    spmd_sd_gau           ../engine/source/mpi/output/spmd_sd_gau.F
!||--- called by ------------------------------------------------------
!||    agauge0               ../engine/source/ale/agauge.F
!||    hist2                 ../engine/source/output/th/hist2.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_sd_gau(GAUGE,IGAUP,NGAUP)
C envoi vers p0 du tableau GAUGE calcule sur chaque proc
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IGAUP(*), NGAUP(*)
      my_real
     .        gauge(llgauge,*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,MSGOFF,IERROR,LOC_PROC,NN,L,I,K,N,II,J,
     .        IDEB,SIZ,A_AR,NBIRECV,INDEX,
     .        IRINDEX(NSPMD),REQ_R(NSPMD),IAD_RECV(NSPMD),
     .        STATUS(MPI_STATUS_SIZE)
      my_real
     .        buf(llgauge+1,nbgauge)
      DATA msgoff/202/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
      IF (loc_proc==1) THEN
        ideb = 1
        nbirecv = 0
        DO i = 2, nspmd
          iad_recv(i) = ideb
          IF(ngaup(i)>0)THEN
            nbirecv = nbirecv + 1
            irindex(nbirecv) = i
            nn = ngaup(i)
            siz = (llgauge+1)*nn
            msgtyp = msgoff
            CALL mpi_irecv(
     s        buf(1,ideb),siz,real,it_spmd(i),msgtyp,
     g        spmd_comm_world,req_r(nbirecv),ierror)
           ideb = ideb + nn
          END IF
        END DO
C
        DO ii = 1, nbirecv
          CALL mpi_waitany(nbirecv,req_r,index,status,ierror)
          i = irindex(index)
          l = iad_recv(i)
          nn = ngaup(i)
          DO n = l, l+nn-1
            k = nint(buf(1,n))
            DO j = 1, llgauge
              gauge(j,k) = buf(j+1,n)
            END DO
          END DO
        END DO
C
      ELSE
        k = 0
        DO n = 1, nbgauge
         IF(igaup(n)==loc_proc)THEN
           k = k + 1
           buf(1,k) = n
           DO j = 1, llgauge
             buf(j+1,k) = gauge(j,n)
           END DO
         END IF
        END DO
        IF(k>0)THEN
          siz = (llgauge+1)*k
          msgtyp=msgoff
          CALL mpi_send(
     s      buf,siz,real,it_spmd(1),msgtyp,
     g      spmd_comm_world,ierror)
        END IF
      END IF
C
#endif
      RETURN
      END