spmd_sptool.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_inisph   ../engine/source/mpi/sph/spmd_sptool.F
!||--- called by ------------------------------------------------------
!||    rdresb        ../engine/source/output/restart/rdresb.F
!||--- calls      -----------------------------------------------------
!||    ancmsg        ../engine/source/output/message/message.F
!||    arret         ../engine/source/system/arret.F
!||    read_db       ../common_source/tools/input_output/read_db.F
!||    read_i_c      ../common_source/tools/input_output/write_routines.c
!||--- uses       -----------------------------------------------------
!||    message_mod   ../engine/share/message_module/message_mod.F
!||    sphbox        ../engine/share/modules/sphbox.F
!||====================================================================
      SUBROUTINE spmd_inisph(IFLG)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sphbox
      USE message_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "sphcom.inc"
#include      "spmd_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IFLG
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER P, IERROR, IERROR1
C-----------------------------------------------
      IF(iflg==1)THEN
       nsphr = 0
       nsphs = 0
       IF(numsphg>0.AND.nspmd>1)THEN
        ALLOCATE(psphr(nspmd),stat=ierror)
        ALLOCATE(psphs(nspmd),stat=ierror1)
        ierror = ierror + ierror1
        IF(ierror/=0) THEN
          CALL ancmsg(msgid=20,anmode=aninfo)
          CALL arret(2)
        END IF
        CALL read_i_c(psphr,nspmd)
        CALL read_i_c(psphs,nspmd)
        nsphr = 0
        nsphs = 0
        DO p = 1, nspmd
          nsphr = nsphr + psphr(p)
          nsphs = nsphs + psphs(p)
        END DO
        ierror = 0
        ierror1 = 0
        IF(nsphr/=0)ALLOCATE(isphr(nsphr),stat=ierror)
        IF(nsphs/=0)THEN
          ALLOCATE(isphs(nsphs),stat=ierror1)
          ierror = ierror + ierror1
          ALLOCATE(lsphs(nsphs),stat=ierror1)
          ierror = ierror + ierror1
          IF(ierror/=0) THEN
            CALL ancmsg(msgid=20,anmode=aninfo)
            CALL arret(2)
          END IF
          CALL read_i_c(lsphs,nsphs)
        END IF
        IF(nspcond>0)THEN
          ALLOCATE(ispsymr(nspcond,nsphr),stat=ierror)
          IF(ierror/=0) THEN
            CALL ancmsg(msgid=20,anmode=aninfo)
            CALL arret(2)
          END IF
          CALL read_i_c(ispsymr,nspcond*nsphr)
        END IF
       END IF
C
      ELSEIF(iflg==2.AND.nspmd>1)THEN
        IF(nsphr/=0)THEN
          ALLOCATE(xsphr(sizspc,nsphr),stat=ierror)
          ALLOCATE(wacompr(sizspw,nsphr),stat=ierror1)
          ierror = ierror + ierror1
          IF(ierror/=0) THEN
            CALL ancmsg(msgid=20,anmode=aninfo)
            CALL arret(2)
          END IF
          CALL read_db(xsphr,sizspc*nsphr)
        END IF
      END IF
C
      RETURN
      END 
C
!||====================================================================
!||    spmd_savesph   ../engine/source/mpi/sph/spmd_sptool.F
!||--- called by ------------------------------------------------------
!||    wrrestp        ../engine/source/output/restart/wrrestp.f
!||--- calls      -----------------------------------------------------
!||    write_db       ../common_source/tools/input_output/write_db.F
!||    write_i_c      ../common_source/tools/input_output/write_routines.c
!||--- uses       -----------------------------------------------------
!||    sphbox         ../engine/share/modules/sphbox.F
!||====================================================================
      SUBROUTINE spmd_savesph(IFLG,NUMSPHG)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sphbox
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "sphcom.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IFLG
      INTEGER, INTENT(IN) :: NUMSPHG
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      IF(numsphg>0.AND.nspmd>1)THEN
        IF(iflg==1)THEN
          CALL write_i_c(psphr,nspmd)
          CALL write_i_c(psphs,nspmd)
          IF(nsphs/=0)
     .      CALL write_i_c(lsphs,nsphs)
          IF(nspcond/=0.AND.nsphr/=0)   
     .      CALL write_i_c(ispsymr,nspcond*nsphr)
        ELSEIF(iflg==2)THEN
          IF(nsphr/=0)
     .      CALL write_db(xsphr,nsphr*sizspc)
        END IF
      END IF
C
      RETURN
      END 
C