spmd_tri22vox0.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    spmd_tri22vox0   ../engine/source/mpi/interfaces/spmd_tri22vox0.F
!||--- called by ------------------------------------------------------
!||    i22main_tri      ../engine/source/interfaces/intsort/i22main_tri.F
!||--- uses       -----------------------------------------------------
!||    element_mod      ../common_source/modules/elements/element_mod.F90
!||    tri7box          ../engine/share/modules/tri7box.F
!||====================================================================
      SUBROUTINE spmd_tri22vox0(
     1   X      ,BMINMA_FLU_L ,NBRIC  , IXS   , BUFBRIC, 
     2   ITASK  ,ITAB         ,XMINS  , YMINS , ZMINS  ,
     3   XMAXS  ,YMAXS        ,ZMAXS  , BMINMA_LAG_R ,IS_CONTACT,
     4   BMINMA_AND ) 
C-----------------------------------------------
C   D e s  c r i p t i o n
C-----------------------------------------------
C This subroutine is marking SPMD voxel if brick is inside
C lagrangian domain (from local domain)
C X       : Node coordinates
C BMINMAL : Fluid Bounds for local domain
C IXS     : Brick node ids
C BUFBRIC : Brick Group for interface for current domain
C ITASK   : Current Thread
C CRVOXEL : SPMD Voxel
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE tri7box
      use element_mod , only :nixs
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, intent(in) ::   NBRIC, IXS(NIXS,*), ITAB(*)
      my_real, intent(in) ::
     .                         X(3,*), 
     .                         BMINMA_FLU_L(6), BMINMA_LAG_R(6)
      my_real, intent(inout) ::
     .                         bminma_and(6)
      my_real
     .        xmaxs(nbric), ymaxs(nbric), zmaxs(nbric),
     .        xmins(nbric), ymins(nbric), zmins(nbric)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
      INTEGER LOC_PROC,IB,
     .        NBX,NBY,NBZ,
     .        IX1,IY1,IZ1,IX2,IY2,IZ2,IX,IY,IZ,
     .        BUFBRIC(NBRIC),NBF,NBL,ITASK
      my_real
     .        xmaxb,ymaxb,zmaxb,xminb,yminb,zminb,
     .        
     .           
     .           
     .           
     .        dx,dy,dz
      LOGICAL :: IS_CONTACT
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
C
C=======================================================================
C     tag of boxes containing facets
C     and creation of candidates
C=======================================================================
 
      loc_proc = ispmd + 1
 
      nbx = lrvoxel
      nby = lrvoxel
      nbz = lrvoxel
 
      ! to search for distant candidate facets,
      ! we look at the intersection of the local fluid domain with the remote lagrangian domains
      ! this is the domain that we voxelize to search for the remote facets
      xmaxb = min( bminma_flu_l(1), bminma_lag_r(1) )
      ymaxb = min( bminma_flu_l(2), bminma_lag_r(2) )
      zmaxb = min( bminma_flu_l(3), bminma_lag_r(3) )
      xminb = max( bminma_flu_l(4), bminma_lag_r(4) )
      yminb = max( bminma_flu_l(5), bminma_lag_r(5) )
      zminb = max( bminma_flu_l(6), bminma_lag_r(6) )
 
      dx = xmaxb-xminb
      dy = ymaxb-yminb
      dz = zmaxb-zminb
 
      !Test Interaction between domains (local / distant fluid)    
      IF ( (dx<=zero).OR.(dy<=zero).OR.(dz<=zero) ) THEN
        is_contact = .false.
        RETURN
      ELSE
        is_contact = .true.
      END IF
 
      bminma_and(1)=xmaxb
      bminma_and(2)=ymaxb
      bminma_and(3)=zmaxb
      bminma_and(4)=xminb
      bminma_and(5)=yminb
      bminma_and(6)=zminb
 
      nbf = 1+itask*nbric/nthread
      nbl = (itask+1)*nbric/nthread
 
      DO ib=nbf,nbl
         !-------------------------------------------!
         !  VOXEL OCCUPIED BY THE BRICK              !
         !-------------------------------------------!
         !Voxel_lower_left_bound for this element---+
         ix1=int(nbx*(xmins(ib)-xminb)/dx)
         iy1=int(nby*(ymins(ib)-yminb)/dy)
         iz1=int(nbz*(zmins(ib)-zminb)/dz)
         ix1=max(ix1,0) !pos for ibset must be correctly defined
         iy1=max(iy1,0) !CRVOXEL (0:LRVOXEL,...
         iz1=max(iz1,0) !CRVOXEL (0:LRVOXEL,...
         !Voxel_upper_right_bound for this element---+
         ix2=int(nbx*(xmaxs(ib)-xminb)/dx)
         iy2=int(nby*(ymaxs(ib)-yminb)/dy)
         iz2=int(nbz*(zmaxs(ib)-zminb)/dz)
         ix2=min(ix2,nbx) !pos for ibset must be correctly defined
         iy2=min(iy2,nby) !CRVOXEL (0:LRVOXEL,...
         iz2=min(iz2,nbz) !CRVOXEL (0:LRVOXEL,...
         !------------------------------------------------------!
         ! VOXEL MARKING TO SPOT BRIC LOCATIONS (LOCAL DOMAIN)  !
         !------------------------------------------------------!
#include "lockon.inc"
         DO iz = iz1, iz2
           DO iy = iy1, iy2
             DO ix = ix1, ix2
               crvoxel(iy,iz,loc_proc)=ibset(crvoxel(iy,iz,loc_proc),ix)
             END DO
           END DO
         END DO
#include "lockoff.inc"     
      ENDDO !IB=NBF,NBL
 
C
      RETURN
      END