sstra3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sstra3       ../engine/source/elements/solid/solide/sstra3.F
!||--- called by ------------------------------------------------------
!||    ig3duforc3   ../engine/source/elements/ige3d/ig3duforc3.F
!||    s10forc3     ../engine/source/elements/solid/solide10/s10forc3.F
!||    s16forc3     ../engine/source/elements/thickshell/solide16/s16forc3.F
!||    s20forc3     ../engine/source/elements/solid/solide20/s20forc3.F
!||    s4forc3      ../engine/source/elements/solid/solide4/s4forc3.F
!||    s6cforc3     ../engine/source/elements/thickshell/solide6c/s6cforc3.F
!||    s8cforc3     ../engine/source/elements/thickshell/solide8c/s8cforc3.F
!||    s8eforc3     ../engine/source/elements/solid/solide8e/s8eforc3.F
!||    s8sforc3     ../engine/source/elements/solid/solide8s/s8sforc3.F
!||    s8zforc3     ../engine/source/elements/solid/solide8z/s8zforc3.F
!||    scforc3      ../engine/source/elements/thickshell/solidec/scforc3.F
!||    sforc3       ../engine/source/elements/solid/solide/sforc3.F
!||    spstres      ../engine/source/elements/sph/spstres.F
!||    szforc3      ../engine/source/elements/solid/solidez/szforc3.F
!||====================================================================
      SUBROUTINE sstra3(
     1   DXX,     DYY,     DZZ,     D4,
     2   D5,      D6,      STRAIN,  WXX,
     3   WYY,     WZZ,     OFF,     NEL,
     4   JCVT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: JCVT
      INTEGER, INTENT(IN) :: NEL
      my_real DXX(*), DYY(*), DZZ(*), D4(*), D5(*), D6(*), 
     .        STRAIN(NEL,6), WXX(*), WYY(*), WZZ(*),OFF(*) 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real WXXF, WYYF, WZZF, Q1, Q2, Q3, SS1, SS2, SS3, 
     .        SS4, SS5, SS6, DTOFF(NEL)
C-      
      wxxf = zero
      wyyf = zero
      wzzf = zero
      q1 = zero
      q2= zero
      q3=0
      dtoff(1:nel) = dt1*off(1:nel)
      IF(jcvt>0)THEN 
        DO i=1,nel
          strain(i,1)=strain(i,1)+dxx(i)*dtoff(i)
          strain(i,2)=strain(i,2)+dyy(i)*dtoff(i)
          strain(i,3)=strain(i,3)+dzz(i)*dtoff(i)
          strain(i,4)=strain(i,4)+d4(i)*dtoff(i)
          strain(i,5)=strain(i,5)+d5(i)*dtoff(i)
          strain(i,6)=strain(i,6)+d6(i)*dtoff(i)
        ENDDO
      ELSE    
        DO i=1,nel
C
           wxxf=wxx(i)*off(i)
           wyyf=wyy(i)*off(i)
           wzzf=wzz(i)*off(i)
C
           q1=strain(i,4)*wzzf
           q2=strain(i,6)*wyyf
           q3=strain(i,5)*wxxf
           ss1=strain(i,1)-q1+q2
           ss2=strain(i,2)+q1-q3
           ss3=strain(i,3)-q2+q3
           ss4=strain(i,4)+2.*wzzf*(strain(i,1)-strain(i,2))+
     .         wyyf*strain(i,5)-wxxf*strain(i,6)
           ss5=strain(i,5)+2.*wxxf*(strain(i,2)-strain(i,3))+
     .         wzzf*strain(i,6)-wyyf*strain(i,4)
           ss6=strain(i,6)+2.*wyyf*(strain(i,3)-strain(i,1))+
     .         wxxf*strain(i,4)-wzzf*strain(i,5)
           strain(i,1)= ss1 + dxx(i)*dtoff(i)
           strain(i,2)= ss2 + dyy(i)*dtoff(i)
           strain(i,3)= ss3 + dzz(i)*dtoff(i)
           strain(i,4)= ss4 + d4(i)*dtoff(i)
           strain(i,5)= ss5 + d5(i)*dtoff(i)
           strain(i,6)= ss6 + d6(i)*dtoff(i)
         ENDDO
       ENDIF
c------------
       RETURN      
       END SUBROUTINE sstra3