sortho3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sortho3     ../starter/source/elements/solid/solide/sortho3.F
!||--- called by ------------------------------------------------------
!||    s4refsta3   ../starter/source/elements/solid/solide4/s4refsta3.F
!||    srcoor3     ../starter/source/elements/solid/solide/srcoor3.F
!||    srefsta3    ../starter/source/elements/solid/solide/srefsta3.F
!||====================================================================
      SUBROUTINE sortho3(
     .    RX   ,RY   ,RZ   ,SX   ,SY   ,SZ   ,TX   ,TY   ,TZ   ,     
     .    E1X  ,E1Y  ,E1Z  ,E2X  ,E2Y  ,E2Z  ,E3X  ,E3Y  ,E3Z  )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C     REAL
      my_real
     .   rx(*), ry(*), rz(*),
     .   sx(*), sy(*), sz(*), 
     .   tx(*), ty(*), tz(*),  
     .   e1x(*), e1y(*), e1z(*),
     .   e2x(*), e2y(*), e2z(*),
     .   e3x(*), e3y(*), e3z(*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,N,NITER
C     REAL
      my_real
     .   ux(mvsiz),uy(mvsiz),uz(mvsiz),
     .   vx(mvsiz),vy(mvsiz),vz(mvsiz),
     .   wx(mvsiz),wy(mvsiz),wz(mvsiz)
      my_real
     .   aa,bb
      DATA niter/3/
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      DO i=lft,llt
      ux(i)=rx(i)
      uy(i)=ry(i)
      uz(i)=rz(i)
      vx(i)=sx(i)
      vy(i)=sy(i)
      vz(i)=sz(i)
      wx(i)=tx(i)
      wy(i)=ty(i)
      wz(i)=tz(i)
      ENDDO
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
c     norme r s t
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      DO 50 i=lft,llt
      aa = sqrt(ux(i)*ux(i) + uy(i)*uy(i) + uz(i)*uz(i))
      if ( aa/=zero) aa = one/ aa
      ux(i) = ux(i) * aa
      uy(i) = uy(i) * aa
      uz(i) = uz(i) * aa
      aa = sqrt(vx(i)*vx(i) + vy(i)*vy(i) + vz(i)*vz(i))
      if ( aa/=zero) aa = one / aa
      vx(i) = vx(i) * aa
      vy(i) = vy(i) * aa
      vz(i) = vz(i) * aa
      aa = sqrt(wx(i)*wx(i) + wy(i)*wy(i) + wz(i)*wz(i))
      if ( aa/=zero) aa = one / aa
      wx(i) = wx(i) * aa
      wy(i) = wy(i) * aa
      wz(i) = wz(i) * aa
 50   CONTINUE
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
c     iterations
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      n=0
111   CONTINUE
      n=n+1
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      DO 100 i=lft,llt
       e1x(i) = vy(i) * wz(i) - vz(i) * wy(i) + ux(i)
       e1y(i) = vz(i) * wx(i) - vx(i) * wz(i) + uy(i)
       e1z(i) = vx(i) * wy(i) - vy(i) * wx(i) + uz(i)
c
       e2x(i) = wy(i) * uz(i) - wz(i) * uy(i) + vx(i)
       e2y(i) = wz(i) * ux(i) - wx(i) * uz(i) + vy(i)
       e2z(i) = wx(i) * uy(i) - wy(i) * ux(i) + vz(i)
c
       e3x(i) = uy(i) * vz(i) - uz(i) * vy(i) + wx(i)
       e3y(i) = uz(i) * vx(i) - ux(i) * vz(i) + wy(i)
       e3z(i) = ux(i) * vy(i) - uy(i) * vx(i) + wz(i)
c
       bb = sqrt(e1x(i)*e1x(i) + e1y(i)*e1y(i) + e1z(i)*e1z(i))
       if ( bb/=zero) bb = one / bb
       ux(i) = e1x(i) * bb
       uy(i) = e1y(i) * bb
       uz(i) = e1z(i) * bb
c
       bb = sqrt(e2x(i)*e2x(i) + e2y(i)*e2y(i) + e2z(i)*e2z(i))
       if ( bb/=zero) bb = one / bb
       vx(i) = e2x(i) * bb
       vy(i) = e2y(i) * bb
       vz(i) = e2z(i) * bb
c
       bb = sqrt(e3x(i)*e3x(i) + e3y(i)*e3y(i) + e3z(i)*e3z(i))
       if ( bb/=zero) bb = one / bb
       wx(i) = e3x(i) * bb
       wy(i) = e3y(i) * bb
       wz(i) = e3z(i) * bb
c
 100  CONTINUE
      IF (n<niter) GOTO 111
c     norme et orthogonalisation
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      DO 200 i=lft,llt
      e1x(i) = ux(i)
      e1y(i) = uy(i)
      e1z(i) = uz(i)
c
      e3x(i) = e1y(i) * vz(i) - e1z(i) * vy(i)
      e3y(i) = e1z(i) * vx(i) - e1x(i) * vz(i)
      e3z(i) = e1x(i) * vy(i) - e1y(i) * vx(i)
c
      aa = sqrt(e3x(i)*e3x(i) + e3y(i)*e3y(i) + e3z(i)*e3z(i))
      if ( aa/=zero) aa = one / aa
      e3x(i) = e3x(i) * aa
      e3y(i) = e3y(i) * aa
      e3z(i) = e3z(i) * aa
c
      e2x(i) = e3y(i) * e1z(i) - e3z(i) * e1y(i)
      e2y(i) = e3z(i) * e1x(i) - e3x(i) * e1z(i)
      e2z(i) = e3x(i) * e1y(i) - e3y(i) * e1x(i)
 200  CONTINUE
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      RETURN
      END