qdlen2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    qdlen2             ../starter/source/elements/solid_2d/quad/qdlen2.F
!||--- called by ------------------------------------------------------
!||    binit2             ../starter/source/ale/bimat/binit2.F
!||    multifluid_init2   ../starter/source/multifluid/multifluid_init2.F
!||    q4init2            ../starter/source/elements/solid_2d/quad4/q4init2.F
!||    qinit2             ../starter/source/elements/solid_2d/quad/qinit2.F
!||--- calls      -----------------------------------------------------
!||    loi_fluid          ../starter/source/fluid/loi_fluid.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE qdlen2(IPARG, 
     .     AIRE, DELTAX, 
     .     Y1, Y2, Y3, Y4, 
     .     Z1, Z2, Z3, Z4)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE  ale_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
#include      "com01_c.inc"
C-----------------------------------------------
C   E x t e r n a l
C-----------------------------------------------
      LOGICAL,EXTERNAL :: LOI_FLUID
C-----------------------------------------------
C   D u m m y    A r g u m e n t s
C-----------------------------------------------
      INTEGER IPARG(63:63)
      my_real
     .     AIRE(*), DELTAX(*), 
     .     y1(*), y2(*), y3(*), y4(*),
     .     z1(*), z2(*), z3(*), z4(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, NFAC, ISFLUID
      my_real
     .   AL1(MVSIZ), AL2(MVSIZ), AL3(MVSIZ), AL4(MVSIZ), 
     .   almx(mvsiz), 
     .   xoff(mvsiz), atest(mvsiz)
C--------------------------------------------------------------------
C
      DO i=lft,llt
        xoff(i)=one
      END DO
 
      isfluid = 0
      IF(loi_fluid(mtn))isfluid=1
 
      IF(ale%GLOBAL%ICAA==1 .AND. n2d==2 .AND. isfluid==1 .AND. mtn/=5)THEN
        DO i=lft,llt
          al1(i)=(z3(i)-z1(i))*(z3(i)-z1(i))+(y3(i)-y1(i))*(y3(i)-y1(i))
          al2(i)=(z4(i)-z2(i))*(z4(i)-z2(i))+(y4(i)-y2(i))*(y4(i)-y2(i))
          almx(i)=fourth*(al1(i)+al2(i))
        ENDDO
      ELSE
        DO i=lft,llt
          al1(i)=(z2(i)-z1(i))*(z2(i)-z1(i))+
     .           (y2(i)-y1(i))*(y2(i)-y1(i))
          al2(i)=(z3(i)-z2(i))*(z3(i)-z2(i))+
     .           (y3(i)-y2(i))*(y3(i)-y2(i))
          al3(i)=(z4(i)-z3(i))*(z4(i)-z3(i))+
     .           (y4(i)-y3(i))*(y4(i)-y3(i))
          al4(i)=(z4(i)-z1(i))*(z4(i)-z1(i))+
     .           (y4(i)-y1(i))*(y4(i)-y1(i))
 
          almx(i)= max(al1(i),al2(i),al3(i),al4(i))
 
          al1(i)=(z3(i)-z1(i))*(z3(i)-z1(i))+
     .           (y3(i)-y1(i))*(y3(i)-y1(i))
          al2(i)=(z4(i)-z2(i))*(z4(i)-z2(i))+
     .           (y4(i)-y2(i))*(y4(i)-y2(i))
 
          almx(i)= max(al1(i),al2(i),almx(i))
          END DO
        IF(ale%GLOBAL%ICAA==0)THEN
          DO i=lft,llt
            atest(i)=em4*almx(i) 
            nfac=0
            IF(al1(i)<atest(i)) nfac=nfac+1
            IF(al2(i)<atest(i)) nfac=nfac+1
            IF(al3(i)<atest(i)) nfac=nfac+1
            IF(al4(i)<atest(i)) nfac=nfac+1
            IF(nfac>=2) xoff(i)=ep03
          END DO
        ENDIF
      ENDIF
      
      DO i=lft,llt
        deltax(i)=aire(i)*xoff(i)/sqrt(almx(i))
      END DO
      
      RETURN
      
      END