invoi2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    invoi2   ../starter/source/interfaces/inter2d1/invoi2.F
!||--- called by ------------------------------------------------------
!||    inint2   ../starter/source/interfaces/inter2d1/inint2.F
!||====================================================================
      SUBROUTINE invoi2(X,IRECT,LMSR,MSR,NSV,ILOC,IRTL,NSEG,NSN,NRT)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C FOR A GIVEN SECOND NODE FIND THE NEAREST MAIN SEGMENT
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NSN,NRT
      INTEGER IRECT(4,*), LMSR(*), MSR(*), NSV(*), ILOC(*), IRTL(*),NSEG(*)
      my_real x(3,*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER II, I, J, K, NUM, NPT, JJ, LL, L, LG, M, MG
      my_real cms, dms, result, c2, c3, s2, s3, cs, d2, cc
C-----------------------------------------------
C   P r e - C o n d i t i o n
C-----------------------------------------------
      IF(nrt == 0) RETURN
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
 
      DO ii=1,nsn !loop over nodes in list
        i=nsv(ii)  ! current secnd node
        j=iloc(ii) ! nearest main node
        k=msr(j)
        cms = (x(2,i)-x(2,k))**2 + (x(3,i)-x(3,k))**2
        num=nseg(j+1)-nseg(j) ! number of connected main segments
        npt=nseg(j)-1 !pointer/index
        !---------------------------------------------
        !     NEAREST NODE
        !---------------------------------------------
        DO jj=1,num !loop over connected main segments
          ll=lmsr(npt+jj) ! segment
          l=irect(1,ll)   ! first node of segment
          IF(l == j) l=irect(2,ll)
          lg=msr(l)
          dms = (x(2,i)-x(2,lg))**2 + (x(3,i)-x(3,lg))**2
          IF(dms < cms)THEN
           cms=dms
           j=l
           k=lg
          ENDIF
        ENDDO
        iloc(ii)=j
        num=nseg(j+1)-nseg(j)
        npt=nseg(j)-1
        !------------------------------------------------
        !     nearest segment : check if node projection si inside or outside the tested segment
        !    D2 = (projected length on main segment)² - (segment length)²
        !    a>0, b>0 : a²-b² > 0 => a-b >0 ;     a²-b² < 0 => a-b < 0
        !------------------------------------------------
        !  CASE D2 < 0                CASE D2 > 0
        !   projection of I             projection of I
        !   lies on segment             is out of segment
        !
        !         I
        !         +                                    I     <- second node
        !        /                                     +
        !      /                                       |
        !    /                                         |
        !   +-D2-X ----++ --------+ X <-Main segment
        !  MG          K                  MG        K
        !
 
        result=ep20
        DO jj=1,num !loop over connected segment
          ll=lmsr(jj+npt) !lag segment
          m=irect(1,ll) !first node
          IF(m == j) m=irect(2,ll)
          mg=msr(m)
          ! main segment
          c2=x(2,mg)-x(2,k)
          c3=x(3,mg)-x(3,k)
          !  other node on this segment -> second node
          s2=x(2,i)-x(2,k)
          s3=x(3,i)-x(3,k)
          !
          cs=c2*s2+c3*s3 ! Dot Product
          d2=s2*s2+s3*s3 ! distance : lag second node -> fluid node
          IF(cs > zero)THEN
           cc=c2*c2+c3*c3 ! lagrange segment : length
           d2=d2-cs*cs/cc  !
          ENDIF
          IF(d2 <= result)THEN
            result = d2
            irtl(ii)=ll !nearest segment
          ENDIF
        ENDDO !next JJ
 
 
      ENDDO ! NEXT II
 
      RETURN
      END