szsvm.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
 
!||====================================================================
!||    szsvm      ../engine/source/elements/solid/solidez/szsvm.F
!||--- called by ------------------------------------------------------
!||    s6zhour3   ../engine/source/elements/solid/solide6z/s6zhourg3.F90
!||    szhour3    ../engine/source/elements/solid/solidez/szhour3.F
!||====================================================================
      SUBROUTINE szsvm(
     1   JR0,     JS0,     JT0,     FHOUR,
     2   SIGY,    SIG0,    NU,      SVM1,
     3   SVM2,    NEL,     IINT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: IINT
      INTEGER NEL
      my_real
     .   fhour(nel,3,4),jr0(*),js0(*),jt0(*) ,
     .   sigy(*) ,sig0(nel,6),svm1(*),svm2(*),nu(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,IKT
      my_real
     .   S1,S2,S3,SVM0,SR1,SR2,SR3,SR4,
     .   ss1,ss2,ss3,ss4,st1,st2,st3,st4,svmr,svms,svmt,
     .   svmrst,coef,coef1, jr_1,js_1,jt_1,nu1,nu2,
     .   rs,st,rt,vt2(4),max0,min0    
C         coef= (3*8*0.75)^2 coef1 =1/0.75
          coef= threehundred24
          coef1= onep333
C-----------------------------------------------
      ikt = iint
      IF (ikt ==2) THEN
        coef1= coef/(ten*ikt)
        coef= max(coef1,em01)
      ELSEIF (ikt > 2) THEN
        coef1= coef/(ten*ikt)
        coef= max(coef1,em01)
      ENDIF
      DO i=1,nel
       svm1(i) = zero
       svm2(i) = zero
       IF (sigy(i)<zep9ep30) THEN
        s1 =sig0(i,1)-sig0(i,2)
        s2 =sig0(i,2)-sig0(i,3)
        s3 =sig0(i,1)-sig0(i,3)
        svm0 = (s1*s1+s2*s2+s3*s3)*half + three*(sig0(i,4)*sig0(i,4)
     .                +sig0(i,5)*sig0(i,5)+sig0(i,6)*sig0(i,6))
        nu1 =one/(one - nu(i))
        nu2 =nu(i)*nu1
        jr_1 = one/max(em20,jr0(i))
        js_1 = one/max(em20,js0(i))
        jt_1 = one/max(em20,jt0(i))
        sr1 =nu1*fhour(i,1,3)+nu2*fhour(i,3,1)
        sr2 =nu1*fhour(i,3,1)+nu2*fhour(i,1,3)
        sr3 =fhour(i,1,3)-fhour(i,3,1)
        sr4 =jt0(i)*jr_1*fhour(i,3,3)+jr0(i)*jt_1*fhour(i,1,1)
        svmr = two*(sr1*sr1+sr2*sr2+sr3*sr3)+3*sr4*sr4
        ss1 =fhour(i,1,2)-fhour(i,2,1)
        ss2 =nu1*fhour(i,2,1)+nu2*fhour(i,1,2)
        ss3 =nu1*fhour(i,1,2)+nu2*fhour(i,2,1)
        ss4 =js0(i)*jr_1*fhour(i,2,2)+jr0(i)*js_1*fhour(i,1,1)
        svms = two*(ss1*ss1+ss2*ss2+ss3*ss3) + three*ss4*ss4
        st1 =nu1*fhour(i,2,3)+nu2*fhour(i,3,2)
        st2 =fhour(i,2,3)-fhour(i,3,2)
        st3 =nu1*fhour(i,3,2)+nu2*fhour(i,2,3)
        st4 =js0(i)*jt_1*fhour(i,2,2)+jt0(i)*js_1*fhour(i,3,3)
        svmt = two*(st1*st1+st2*st2+st3*st3) + three*st4*st4
C
        rs =sr1*ss1
        rt =sr1*st1
        st =ss1*st1
        vt2(1) = rs+rt+st
        vt2(2) = rs-rt-st
        vt2(3) = -rs+rt-st
        vt2(4) = -rs-rt+st
        max0 =max(vt2(1),vt2(2),vt2(3),vt2(4))
        min0 =min(vt2(1),vt2(2),vt2(3),vt2(4))
        rs =sr2*ss2
        rt =sr2*st2
        st =ss2*st2
        vt2(1) = rs+rt+st
        vt2(2) = rs-rt-st
        vt2(3) = -rs+rt-st
        vt2(4) = -rs-rt+st
        max0 =max0+max(vt2(1),vt2(2),vt2(3),vt2(4))
        min0 =min0+min(vt2(1),vt2(2),vt2(3),vt2(4))
        rs =sr3*ss3
        rt =sr3*st3
        st =ss3*st3
        vt2(1) = rs+rt+st
        vt2(2) = rs-rt-st
        vt2(3) = -rs+rt-st
        vt2(4) = -rs-rt+st
        max0 =max0+max(vt2(1),vt2(2),vt2(3),vt2(4))
        min0 =min0+min(vt2(1),vt2(2),vt2(3),vt2(4))
        svmrst = svm0+coef*(svmr+svms+svmt)
        svm1(i) = sqrt(abs(svmrst+coef*max0))
        svm2(i) = sqrt(max(svmrst+coef*min0,zero))
        svm2(i) = min(svm2(i),svm0)
       ENDIF
      ENDDO 
C
      RETURN
      END