table_values_2d.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    table_values_2d   ../starter/source/materials/tools/table_values_2d.F
!||--- called by ------------------------------------------------------
!||    func_table_copy   ../starter/source/materials/tools/func_table_copy.F90
!||    law70_table       ../starter/source/materials/mat/mat070/law70_table.F
!||====================================================================
       SUBROUTINE table_values_2d(LEN,NPTF,XI,YI,XF,YF)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
c   use common abscissa vector to calculate new interpolated function values
c   NPTF >= LEN
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
      implicit none
C-----------------------------------------------
C   I n c l u d e   F i l e s
C-----------------------------------------------
#include      "my_real.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: LEN                    ! length of input  X vector
      INTEGER ,INTENT(IN) :: NPTF                   ! length of output X vector
      my_real ,DIMENSION(LEN)  ,INTENT(IN)  :: xi   ! initial X coordinates 
      my_real ,DIMENSION(LEN)  ,INTENT(IN)  :: yi   ! initial Y values
      my_real ,DIMENSION(NPTF) ,INTENT(IN)  :: xf   ! output  X coordinates 
      my_real ,DIMENSION(NPTF) ,INTENT(OUT) :: yf   ! output function values
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: IPT,IDX,IPTM1
      my_real :: x1,x2,y1,y2,deri
c=======================================================================
      IF (nptf >= len) THEN
        idx = 1
        x1  = xi(idx)
        y1  = yi(idx)
        x2  = xi(idx+1)
        y2  = yi(idx+1)
        deri  = (y2 - y1) / (x2 - x1)
        DO ipt = 1,nptf
          IF (xf(ipt) >= x2 .and. idx+1 < len) THEN
            idx = idx + 1
            x1 = x2
            y1 = y2
            x2 = xi(idx+1)
            y2 = yi(idx+1)
            deri  = (y2 - y1) / (x2 - x1)
          END IF
          yf(ipt) = y1 + deri * (xf(ipt) - x1)
        END DO
      ELSE
        idx = 1
        x1  = xi(1)
        y1  = yi(1)
        x2  = xi(2)
        y2  = yi(2)
        deri = (y2 - y1) / (x2 - x1)
        yf(1) = y1
        iptm1 = 1
        DO ipt = 2,len
          IF (idx < nptf) THEN                                              ! NPTF is the length of XF last IDX is updated bellow
            IF (xf(idx+1) >= xi(iptm1)  .and. xf(idx+1) <= xi(ipt) ) THEN   ! XF(IDX+1) - the new X - must be between lower and upper bound of XI
                                                                            ! IPTM1 is the lower bound of previous used IPT
               idx = idx + 1
               x1 = xi(iptm1)
               y1 = yi(iptm1)
               x2 = xi(ipt)
               y2 = yi(ipt)
               deri  = (y2 - y1) / (x2 - x1)
               yf(idx) = y1 + deri * (xf(idx) - x1)
               iptm1 = ipt
            ENDIF
          END IF
        END DO
      END IF
c-----------
      RETURN
      END SUBROUTINE table_values_2d