tfcum3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    tfcum3   ../engine/source/elements/truss/tfcum3.F
!||--- called by ------------------------------------------------------
!||    tforc3   ../engine/source/elements/truss/tforc3.F
!||====================================================================
      SUBROUTINE tfcum3(
     1   F,       FOR,     STIFN,   STI,
     2   FX1,     FX2,     FY1,     FY2,
     3   FZ1,     FZ2,     OFFG,    OFF,
     4   NC1,     NC2,     EX,      EY,
     5   EZ,      NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER NC1(MVSIZ),NC2(MVSIZ)
      my_real
     .   F(3,*),FOR(*),STIFN(*),STI(*),
     .   FX1(MVSIZ),FY1(MVSIZ),FZ1(MVSIZ),
     .   fx2(mvsiz),fy2(mvsiz),fz2(mvsiz),
     .   offg(mvsiz),off(mvsiz),ex(mvsiz),ey(mvsiz),ez(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J
      my_real
     .   F11(MVSIZ),F21(MVSIZ),F31(MVSIZ),OFF_L
C-----------------------------------------------      
      DO I=1,nel
        f11(i)=ex(i)*for(i)
        f21(i)=ey(i)*for(i)
        f31(i)=ez(i)*for(i)
      ENDDO
c
      off_l=zero
      DO i=1,nel
        IF (off(i) < one) offg(i) = off(i)
        off_l = min(off_l,offg(i))
      ENDDO
c
      IF (off_l < zero) THEN
        DO i=1,nel
          IF (offg(i) < zero) THEN
            f11(i)=zero
            f21(i)=zero
            f31(i)=zero
            sti(i)=zero
          ENDIF
        ENDDO
      ENDIF
C-------------------------
C     ASSEMBLE
C-------------------------
      DO i=1,nel
        f(1,nc1(i))=f(1,nc1(i))+f11(i)
        f(2,nc1(i))=f(2,nc1(i))+f21(i)
        f(3,nc1(i))=f(3,nc1(i))+f31(i)
        fx1(i) = -f11(i)
        fy1(i) = -f21(i)
        fz1(i) = -f31(i)
c
        f(1,nc2(i))=f(1,nc2(i))-f11(i)
        f(2,nc2(i))=f(2,nc2(i))-f21(i)
        f(3,nc2(i))=f(3,nc2(i))-f31(i)
        fx2(i) = f11(i)
        fy2(i) = f21(i)
        fz2(i) = f31(i)
c
        stifn(nc1(i)) = stifn(nc1(i))+sti(i)
        stifn(nc2(i)) = stifn(nc2(i))+sti(i)
      ENDDO 
C-----------------------------------------------
      RETURN
      END