thick_ilev.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    thick_ilev     ../starter/source/elements/xfem/thick_ilev.F
!||--- called by ------------------------------------------------------
!||    cbufxfe        ../starter/source/elements/xfem/cbufxfe.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE thick_ilev(ELBUF_STR,XFEM_STR,
     .                      LFT      ,LLT  ,NLAY  ,IR  ,IS  ,
     .                      NPTT     ,IXFEM,THKLY ,POSLY,IREP,IXEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
#include  "mvsiz_p.inc"
C-----------------------------------------------
C   I N P U T   A r g u m e n t s
C-----------------------------------------------
      INTEGER NLAY,NPTT,LFT,LLT,IXFEM,IR,IS,IREP,IXEL
      my_real 
     .   thkly(*),posly(mvsiz,*)
C
      TYPE(ELBUF_STRUCT_), TARGET, intent(inout) :: ELBUF_STR
      TYPE(ELBUF_STRUCT_), TARGET, intent(inout)  :: XFEM_STR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,II,ILAY,IT,J,IPT,L_DIRA,L_DIRB
      my_real 
     .   thkt
      my_real,
     .  DIMENSION(:) ,POINTER  ::  dir1,dir2,dir1x,dir2x
C
      TYPE(g_bufel_)     , POINTER :: GBUF
      TYPE(L_BUFEL_)     , POINTER :: LBUF
C=======================================================================
c     layer thickness
c
      IF (nlay > 1) THEN  ! multilayer
        DO ilay=1,nlay
          DO i=lft,llt
            j = (ilay-1)*llt + i
            thkt = elbuf_str%GBUF%THK(i)   !  total element thickness
            xfem_str%BUFLY(ilay)%LBUF(1,1,1)%THK(i) = thkly(j)*thkt
          ENDDO
        ENDDO  !  DO ILAY=1,NLAY
      ELSE  
c       monolayer : already filled within "C1BUF3.F"
      ENDIF  !  IF(NLAY > 1)THEN
c
c     layer orthotropy directions - copy to XFEM buffer
c
      l_dira = elbuf_str%BUFLY(1)%LY_DIRA
      l_dirb = elbuf_str%BUFLY(1)%LY_DIRB
      DO ilay=1,nlay
        dir1  => elbuf_str%BUFLY(ilay)%DIRA(1:l_dira*llt)
        dir2  => elbuf_str%BUFLY(ilay)%DIRB(1:l_dirb*llt)
        dir1x => xfem_str%BUFLY(ilay)%DIRA(1:l_dira*llt)
        dir2x => xfem_str%BUFLY(ilay)%DIRB(1:l_dirb*llt)
        DO i=lft,llt
          ii = 2*(i-1)
          IF (l_dira == 0) THEN
            CONTINUE
          ELSEIF (irep == 0 .OR. irep == 1) THEN
            dir1x(ii+1) = dir1(ii+1)
            dir1x(ii+2) = dir1(ii+2)
          ELSEIF (irep == 2) THEN
            dir1x(ii+1) = dir1(ii+1)
            dir1x(ii+2) = dir1(ii+2)
            dir2x(ii+1) = dir2(ii+1)
            dir2x(ii+2) = dir2(ii+2)
          ENDIF
        ENDDO
      ENDDO  !  DO ILAY=1,NLAY
C---
      IF (nlay > 1) THEN  ! multilayer
        DO ilay=1,nlay
          lbuf => xfem_str%BUFLY(ilay)%LBUF(1,1,1)
          DO i=lft,llt
            lbuf%OFF(i) = -one
          ENDDO
        ENDDO
      ELSE  ! monolayer
        gbuf => xfem_str%GBUF
        DO i=lft,llt
          gbuf%OFF(i) = -one
        ENDDO
      ENDIF  !  IF(NLAY > 1)THEN
C---
      RETURN
      END