tmass.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    tmass     ../starter/source/elements/truss/tmass.F
!||--- called by ------------------------------------------------------
!||    inivoid   ../starter/source/elements/initia/inivoid.F
!||    tinit3    ../starter/source/elements/truss/tinit3.F
!||====================================================================
      SUBROUTINE tmass(X      ,NC      ,GEO  ,PM   ,MS ,
     .     STIFN  ,PARTSAV ,V    ,IPART,MST,
     .     STIFINT,STT     ,AREA , MXT, NC1, NC2,
     .     X1, X2, Y1, Y2, Z1, Z2)
C----------------------------------------------
C     INITIALISATION DES MASSES NODALES
C----------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "vect01_c.inc"
#include      "scr12_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NC(NIXT,*),IPART(*), MXT(*), NC1(*), NC2(*)
      my_real
     .     X(3,*),GEO(NPROPG,*),PM(NPROPM,*),MS(*),STIFN(*),
     .     v(3,*),partsav(20,*),mst(*),stifint(*),stt(*),area(*),
     .     x1(*), x2(*), y1(*), y2(*), z1(*), z2(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,IP,I1,I2,J,K
      my_real
     .   XX,YY,ZZ,XY,YZ,ZX
      my_real
     .   al(mvsiz),
     .   rho(mvsiz),ems(mvsiz),
     .   e,sti(mvsiz),dx,dy,dz
C
C---------------------------------------------------------------------
      DO i=lft,llt
       rho(i) =pm(89,mxt(i))
      ENDDO
C----------------------------------------------
C     MASSE ELEMENT /2
C----------------------------------------------
      DO i=lft,llt
       al(i)=sqrt((x2(i)-x1(i))**2
     .           +(y2(i)-y1(i))**2
     .           +(z2(i)-z1(i))**2)
       ems(i)=rho(i)*al(i)*area(i)*half
      ENDDO
C----------------------------------------------
C     INITIALISATION DES MASSES NODALES
C----------------------------------------------
C     mass init parith/on spmd
      DO i=lft,llt
        mst(i)=ems(i)
      ENDDO
C----------------------------------------------
C     INITIALISATION DES RIGIDITES NODALES
C     et RIGIDITES NODALES POUR INTERFACES
C----------------------------------------------
      DO i=lft,llt
       sti(i) = pm(20,mxt(i)) * area(i) / al(i)
       stifn(nc1(i))=stifn(nc1(i))+sti(i)
       stifn(nc2(i))=stifn(nc2(i))+sti(i)
      ENDDO
      IF (i7stifs /= 0) THEN
        DO i=lft,llt
         stt(i)=sti(i)
        ENDDO
      ENDIF
C
      DO i=lft,llt
        i1 = nc1(i)
        i2 = nc2(i)
C
        ip=ipart(i)
        partsav(1,ip)=partsav(1,ip) + two*ems(i)
        partsav(2,ip)=partsav(2,ip) + ems(i)*(x(1,i1)+x(1,i2))
        partsav(3,ip)=partsav(3,ip) + ems(i)*(x(2,i1)+x(2,i2))
        partsav(4,ip)=partsav(4,ip) + ems(i)*(x(3,i1)+x(3,i2))
        xx = (x(1,i1)*x(1,i1)+x(1,i2)*x(1,i2))
        xy = (x(1,i1)*x(2,i1)+x(1,i2)*x(2,i2))
        yy = (x(2,i1)*x(2,i1)+x(2,i2)*x(2,i2))
        yz = (x(2,i1)*x(3,i1)+x(2,i2)*x(3,i2))
        zz = (x(3,i1)*x(3,i1)+x(3,i2)*x(3,i2))
        zx = (x(3,i1)*x(1,i1)+x(3,i2)*x(1,i2))
        partsav(5,ip) =partsav(5,ip) + ems(i) * (yy+zz)
        partsav(6,ip) =partsav(6,ip) + ems(i) * (zz+xx)
        partsav(7,ip) =partsav(7,ip) + ems(i) * (xx+yy)
        partsav(8,ip) =partsav(8,ip)  - ems(i) * xy
        partsav(9,ip) =partsav(9,ip)  - ems(i) * yz
        partsav(10,ip)=partsav(10,ip) - ems(i) * zx
C
        partsav(11,ip)=partsav(11,ip) + ems(i)*(v(1,i1)+v(1,i2))
        partsav(12,ip)=partsav(12,ip) + ems(i)*(v(2,i1)+v(2,i2))
        partsav(13,ip)=partsav(13,ip) + ems(i)*(v(3,i1)+v(3,i2))
        partsav(14,ip)=partsav(14,ip) + half * ems(i) *
     .     (v(1,i1)*v(1,i1)+v(2,i1)*v(2,i1)+v(3,i1)*v(3,i1)
     .     +v(1,i2)*v(1,i2)+v(2,i2)*v(2,i2)+v(3,i2)*v(3,i2))
      ENDDO
C
      RETURN
      END