upwind4.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    upwind4    ../engine/source/elements/solid/solide4/upwind4.F
!||--- called by ------------------------------------------------------
!||    a4momt3    ../engine/source/elements/solid/solide4/a4momt3.F
!||    a4momtn3   ../engine/source/elements/solid/solide4/a4momtn3.F
!||--- uses       -----------------------------------------------------
!||    ale_mod    ../common_source/modules/ale/ale_mod.F
!||====================================================================
      SUBROUTINE upwind4(
     1   RHO,     VIS,     VDX,     VDY,
     2   VDZ,     R,       S,       T,
     3   GAM,     NEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE ale_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      my_real
     .   R(MVSIZ,3),S(MVSIZ,3),T(MVSIZ,3),
     .   vdx(*),vdy(*),vdz(*),rho(*),vis(*),gam(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real
     .  fac,pe,d1,d2,d3,dist,ch1,ch2,
     .  dv(mvsiz),v(mvsiz)
      INTEGER I
C-----------------------------------------------
C   S o u r c e   C o d e
C-----------------------------------------------
 
      !-------------!
      !   /UPWM/TG  !
      !-------------!
      IF(ale%UPWIND%UPWM==2)THEN
        fac=ale%UPWIND%CUPWM*half*dt1
        DO i=1,nel
          gam(i)=fac
        END DO
        
      !-------------!
      !  /UPWM/SUPG !
      !-------------!
      ELSEIF(ale%UPWIND%UPWM==3)THEN
        DO  i=1,nel
          v(i)=vdx(i)**2+vdy(i)**2+vdz(i)**2
          d1=abs(r(i,1)*vdx(i)+r(i,2)*vdy(i)+r(i,3)*vdz(i)) 
          d2=abs(s(i,1)*vdx(i)+s(i,2)*vdy(i)+s(i,3)*vdz(i)) 
          d3=abs(t(i,1)*vdx(i)+t(i,2)*vdy(i)+t(i,3)*vdz(i)) 
          gam(i)=max(d1,d2,d3) !dominant direction
        ENDDO 
 
        ch2=ale%UPWIND%CUPWM*half
        ch1=ch2*third
       
       !SU/PG weighting function for current node.
       !SUPG is a Finite Element Method !
        DO  i=1,nel
          fac=half*rho(i)/max(em20,vis(i))
          pe=fac*gam(i)
          IF(pe<=em3)THEN
            gam(i)=zero
          ELSEIF(pe<three)THEN
            gam(i)=ch1*fac*gam(i)**2/v(i)
          ELSE
            gam(i)=ch2*gam(i)/v(i)
          ENDIF
        ENDDO
      ENDIF
 
      RETURN
      END