ztgsna.f

Go to the documentation of this file.

*> \brief \b ZTGSNA
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download ZTGSNA + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ztgsna.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ztgsna.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ztgsna.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZTGSNA( JOB, HOWMNY, SELECT, N, A, LDA, B, LDB, VL,
*                          LDVL, VR, LDVR, S, DIF, MM, M, WORK, LWORK,
*                          IWORK, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          HOWMNY, JOB
*       INTEGER            INFO, LDA, LDB, LDVL, LDVR, LWORK, M, MM, N
*       ..
*       .. Array Arguments ..
*       LOGICAL            SELECT( * )
*       INTEGER            IWORK( * )
*       DOUBLE PRECISION   DIF( * ), S( * )
*       COMPLEX*16         A( LDA, * ), B( LDB, * ), VL( LDVL, * ),
*      $                   VR( LDVR, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZTGSNA estimates reciprocal condition numbers for specified
*> eigenvalues and/or eigenvectors of a matrix pair (A, B).
*>
*> (A, B) must be in generalized Schur canonical form, that is, A and
*> B are both upper triangular.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] JOB
*> \verbatim
*>          JOB is CHARACTER*1
*>          Specifies whether condition numbers are required for
*>          eigenvalues (S) or eigenvectors (DIF):
*>          = 'E': for eigenvalues only (S);
*>          = 'V': for eigenvectors only (DIF);
*>          = 'B': for both eigenvalues and eigenvectors (S and DIF).
*> \endverbatim
*>
*> \param[in] HOWMNY
*> \verbatim
*>          HOWMNY is CHARACTER*1
*>          = 'A': compute condition numbers for all eigenpairs;
*>          = 'S': compute condition numbers for selected eigenpairs
*>                 specified by the array SELECT.
*> \endverbatim
*>
*> \param[in] SELECT
*> \verbatim
*>          SELECT is LOGICAL array, dimension (N)
*>          If HOWMNY = 'S', SELECT specifies the eigenpairs for which
*>          condition numbers are required. To select condition numbers
*>          for the corresponding j-th eigenvalue and/or eigenvector,
*>          SELECT(j) must be set to .TRUE..
*>          If HOWMNY = 'A', SELECT is not referenced.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the square matrix pair (A, B). N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          The upper triangular matrix A in the pair (A,B).
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A. LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (LDB,N)
*>          The upper triangular matrix B in the pair (A, B).
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B. LDB >= max(1,N).
*> \endverbatim
*>
*> \param[in] VL
*> \verbatim
*>          VL is COMPLEX*16 array, dimension (LDVL,M)
*>          IF JOB = 'E' or 'B', VL must contain left eigenvectors of
*>          (A, B), corresponding to the eigenpairs specified by HOWMNY
*>          and SELECT.  The eigenvectors must be stored in consecutive
*>          columns of VL, as returned by ZTGEVC.
*>          If JOB = 'V', VL is not referenced.
*> \endverbatim
*>
*> \param[in] LDVL
*> \verbatim
*>          LDVL is INTEGER
*>          The leading dimension of the array VL. LDVL >= 1; and
*>          If JOB = 'E' or 'B', LDVL >= N.
*> \endverbatim
*>
*> \param[in] VR
*> \verbatim
*>          VR is COMPLEX*16 array, dimension (LDVR,M)
*>          IF JOB = 'E' or 'B', VR must contain right eigenvectors of
*>          (A, B), corresponding to the eigenpairs specified by HOWMNY
*>          and SELECT.  The eigenvectors must be stored in consecutive
*>          columns of VR, as returned by ZTGEVC.
*>          If JOB = 'V', VR is not referenced.
*> \endverbatim
*>
*> \param[in] LDVR
*> \verbatim
*>          LDVR is INTEGER
*>          The leading dimension of the array VR. LDVR >= 1;
*>          If JOB = 'E' or 'B', LDVR >= N.
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is DOUBLE PRECISION array, dimension (MM)
*>          If JOB = 'E' or 'B', the reciprocal condition numbers of the
*>          selected eigenvalues, stored in consecutive elements of the
*>          array.
*>          If JOB = 'V', S is not referenced.
*> \endverbatim
*>
*> \param[out] DIF
*> \verbatim
*>          DIF is DOUBLE PRECISION array, dimension (MM)
*>          If JOB = 'V' or 'B', the estimated reciprocal condition
*>          numbers of the selected eigenvectors, stored in consecutive
*>          elements of the array.
*>          If the eigenvalues cannot be reordered to compute DIF(j),
*>          DIF(j) is set to 0; this can only occur when the true value
*>          would be very small anyway.
*>          For each eigenvalue/vector specified by SELECT, DIF stores
*>          a Frobenius norm-based estimate of Difl.
*>          If JOB = 'E', DIF is not referenced.
*> \endverbatim
*>
*> \param[in] MM
*> \verbatim
*>          MM is INTEGER
*>          The number of elements in the arrays S and DIF. MM >= M.
*> \endverbatim
*>
*> \param[out] M
*> \verbatim
*>          M is INTEGER
*>          The number of elements of the arrays S and DIF used to store
*>          the specified condition numbers; for each selected eigenvalue
*>          one element is used. If HOWMNY = 'A', M is set to N.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK. LWORK >= max(1,N).
*>          If JOB = 'V' or 'B', LWORK >= max(1,2*N*N).
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (N+2)
*>          If JOB = 'E', IWORK is not referenced.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: Successful exit
*>          < 0: If INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex16OTHERcomputational
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  The reciprocal of the condition number of the i-th generalized
*>  eigenvalue w = (a, b) is defined as
*>
*>          S(I) = (|v**HAu|**2 + |v**HBu|**2)**(1/2) / (norm(u)*norm(v))
*>
*>  where u and v are the right and left eigenvectors of (A, B)
*>  corresponding to w; |z| denotes the absolute value of the complex
*>  number, and norm(u) denotes the 2-norm of the vector u. The pair
*>  (a, b) corresponds to an eigenvalue w = a/b (= v**HAu/v**HBu) of the
*>  matrix pair (A, B). If both a and b equal zero, then (A,B) is
*>  singular and S(I) = -1 is returned.
*>
*>  An approximate error bound on the chordal distance between the i-th
*>  computed generalized eigenvalue w and the corresponding exact
*>  eigenvalue lambda is
*>
*>          chord(w, lambda) <=   EPS * norm(A, B) / S(I),
*>
*>  where EPS is the machine precision.
*>
*>  The reciprocal of the condition number of the right eigenvector u
*>  and left eigenvector v corresponding to the generalized eigenvalue w
*>  is defined as follows. Suppose
*>
*>                   (A, B) = ( a   *  ) ( b  *  )  1
*>                            ( 0  A22 ),( 0 B22 )  n-1
*>                              1  n-1     1 n-1
*>
*>  Then the reciprocal condition number DIF(I) is
*>
*>          Difl[(a, b), (A22, B22)]  = sigma-min( Zl )
*>
*>  where sigma-min(Zl) denotes the smallest singular value of
*>
*>         Zl = [ kron(a, In-1) -kron(1, A22) ]
*>              [ kron(b, In-1) -kron(1, B22) ].
*>
*>  Here In-1 is the identity matrix of size n-1 and X**H is the conjugate
*>  transpose of X. kron(X, Y) is the Kronecker product between the
*>  matrices X and Y.
*>
*>  We approximate the smallest singular value of Zl with an upper
*>  bound. This is done by ZLATDF.
*>
*>  An approximate error bound for a computed eigenvector VL(i) or
*>  VR(i) is given by
*>
*>                      EPS * norm(A, B) / DIF(i).
*>
*>  See ref. [2-3] for more details and further references.
*> \endverbatim
*
*> \par Contributors:
*  ==================
*>
*>     Bo Kagstrom and Peter Poromaa, Department of Computing Science,
*>     Umea University, S-901 87 Umea, Sweden.
*
*> \par References:
*  ================
*>
*> \verbatim
*>
*>  [1] B. Kagstrom; A Direct Method for Reordering Eigenvalues in the
*>      Generalized Real Schur Form of a Regular Matrix Pair (A, B), in
*>      M.S. Moonen et al (eds), Linear Algebra for Large Scale and
*>      Real-Time Applications, Kluwer Academic Publ. 1993, pp 195-218.
*>
*>  [2] B. Kagstrom and P. Poromaa; Computing Eigenspaces with Specified
*>      Eigenvalues of a Regular Matrix Pair (A, B) and Condition
*>      Estimation: Theory, Algorithms and Software, Report
*>      UMINF - 94.04, Department of Computing Science, Umea University,
*>      S-901 87 Umea, Sweden, 1994. Also as LAPACK Working Note 87.
*>      To appear in Numerical Algorithms, 1996.
*>
*>  [3] B. Kagstrom and P. Poromaa, LAPACK-Style Algorithms and Software
*>      for Solving the Generalized Sylvester Equation and Estimating the
*>      Separation between Regular Matrix Pairs, Report UMINF - 93.23,
*>      Department of Computing Science, Umea University, S-901 87 Umea,
*>      Sweden, December 1993, Revised April 1994, Also as LAPACK Working
*>      Note 75.
*>      To appear in ACM Trans. on Math. Software, Vol 22, No 1, 1996.
*> \endverbatim
*>
*  =====================================================================
      SUBROUTINE ztgsna( JOB, HOWMNY, SELECT, N, A, LDA, B, LDB, VL,
     $                   LDVL, VR, LDVR, S, DIF, MM, M, WORK, LWORK,
     $                   IWORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          HOWMNY, JOB
      INTEGER            INFO, LDA, LDB, LDVL, LDVR, LWORK, M, MM, N
*     ..
*     .. Array Arguments ..
      LOGICAL            SELECT( * )
      INTEGER            IWORK( * )
      DOUBLE PRECISION   DIF( * ), S( * )
      COMPLEX*16         A( LDA, * ), B( LDB, * ), VL( LDVL, * ),
     $                   vr( ldvr, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      INTEGER            IDIFJB
      parameter( zero = 0.0d+0, one = 1.0d+0, idifjb = 3 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, SOMCON, WANTBH, WANTDF, WANTS
      INTEGER            I, IERR, IFST, ILST, K, KS, LWMIN, N1, N2
      DOUBLE PRECISION   BIGNUM, COND, EPS, LNRM, RNRM, SCALE, SMLNUM
      COMPLEX*16         YHAX, YHBX
*     ..
*     .. Local Arrays ..
      COMPLEX*16         DUMMY( 1 ), DUMMY1( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, DLAPY2, DZNRM2
      COMPLEX*16         ZDOTC
      EXTERNAL           lsame, dlamch, dlapy2, dznrm2, zdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlabad, xerbla, zgemv, zlacpy, ztgexc, ztgsyl
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dcmplx, max
*     ..
*     .. Executable Statements ..
*
*     Decode and test the input parameters
*
      wantbh = lsame( job, 'B' )
      wants = lsame( job, 'E' ) .OR. wantbh
      wantdf = lsame( job, 'V' ) .OR. wantbh
*
      somcon = lsame( howmny, 'S' )
*
      info = 0
      lquery = ( lwork.EQ.-1 )
*
      IF( .NOT.wants .AND. .NOT.wantdf ) THEN
         info = -1
      ELSE IF( .NOT.lsame( howmny, 'A' ) .AND. .NOT.somcon ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -6
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( wants .AND. ldvl.LT.n ) THEN
         info = -10
      ELSE IF( wants .AND. ldvr.LT.n ) THEN
         info = -12
      ELSE
*
*        Set M to the number of eigenpairs for which condition numbers
*        are required, and test MM.
*
         IF( somcon ) THEN
            m = 0
            DO 10 k = 1, n
               IF( SELECT( k ) )
     $            m = m + 1
   10       CONTINUE
         ELSE
            m = n
         END IF
*
         IF( n.EQ.0 ) THEN
            lwmin = 1
         ELSE IF( lsame( job, 'V' ) .OR. lsame( job, 'B' ) ) THEN
            lwmin = 2*n*n
         ELSE
            lwmin = n
         END IF
         work( 1 ) = lwmin
*
         IF( mm.LT.m ) THEN
            info = -15
         ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
            info = -18
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZTGSNA', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Get machine constants
*
      eps = dlamch( 'P' )
      smlnum = dlamch( 'S' ) / eps
      bignum = one / smlnum
      CALL dlabad( smlnum, bignum )
      ks = 0
      DO 20 k = 1, n
*
*        Determine whether condition numbers are required for the k-th
*        eigenpair.
*
         IF( somcon ) THEN
            IF( .NOT.SELECT( k ) )
     $         GO TO 20
         END IF
*
         ks = ks + 1
*
         IF( wants ) THEN
*
*           Compute the reciprocal condition number of the k-th
*           eigenvalue.
*
            rnrm = dznrm2( n, vr( 1, ks ), 1 )
            lnrm = dznrm2( n, vl( 1, ks ), 1 )
            CALL zgemv( 'N', n, n, dcmplx( one, zero ), a, lda,
     $                  vr( 1, ks ), 1, dcmplx( zero, zero ), work, 1 )
            yhax = zdotc( n, work, 1, vl( 1, ks ), 1 )
            CALL zgemv( 'N', n, n, dcmplx( one, zero ), b, ldb,
     $                  vr( 1, ks ), 1, dcmplx( zero, zero ), work, 1 )
            yhbx = zdotc( n, work, 1, vl( 1, ks ), 1 )
            cond = dlapy2( abs( yhax ), abs( yhbx ) )
            IF( cond.EQ.zero ) THEN
               s( ks ) = -one
            ELSE
               s( ks ) = cond / ( rnrm*lnrm )
            END IF
         END IF
*
         IF( wantdf ) THEN
            IF( n.EQ.1 ) THEN
               dif( ks ) = dlapy2( abs( a( 1, 1 ) ), abs( b( 1, 1 ) ) )
            ELSE
*
*              Estimate the reciprocal condition number of the k-th
*              eigenvectors.
*
*              Copy the matrix (A, B) to the array WORK and move the
*              (k,k)th pair to the (1,1) position.
*
               CALL zlacpy( 'Full', n, n, a, lda, work, n )
               CALL zlacpy( 'Full', n, n, b, ldb, work( n*n+1 ), n )
               ifst = k
               ilst = 1
*
               CALL ztgexc( .false., .false., n, work, n, work( n*n+1 ),
     $                      n, dummy, 1, dummy1, 1, ifst, ilst, ierr )
*
               IF( ierr.GT.0 ) THEN
*
*                 Ill-conditioned problem - swap rejected.
*
                  dif( ks ) = zero
               ELSE
*
*                 Reordering successful, solve generalized Sylvester
*                 equation for R and L,
*                            A22 * R - L * A11 = A12
*                            B22 * R - L * B11 = B12,
*                 and compute estimate of Difl[(A11,B11), (A22, B22)].
*
                  n1 = 1
                  n2 = n - n1
                  i = n*n + 1
                  CALL ztgsyl( 'N', idifjb, n2, n1, work( n*n1+n1+1 ),
     $                         n, work, n, work( n1+1 ), n,
     $                         work( n*n1+n1+i ), n, work( i ), n,
     $                         work( n1+i ), n, scale, dif( ks ), dummy,
     $                         1, iwork, ierr )
               END IF
            END IF
         END IF
*
   20 CONTINUE
      work( 1 ) = lwmin
      RETURN
*
*     End of ZTGSNA
*
      END