anim_nodal_contour_fvmbags.F File Reference

#include "implicit_f.inc"
#include "com01_c.inc"
#include "com04_c.inc"
#include "vect01_c.inc"
#include "param_c.inc"
#include "inter22.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	anim_nodal_contour_fvmbags (key, wa4, monvol, volmon, fvdata_p, nfvbag, smonvol, svolmon, airbags_total_fvm, is_written_node_fvm, airbags_node_id_shift)

Function/Subroutine Documentation

anim_nodal_contour_fvmbags()

subroutine anim_nodal_contour_fvmbags	(	character*4, intent(in)	key,
		real, dimension(airbags_total_fvm), intent(inout)	wa4,
		integer, dimension(smonvol), intent(in)	monvol,
		dimension(svolmon), intent(in)	volmon,
		type(fvbag_data), dimension(nfvbag), intent(in)	fvdata_p,
		integer, intent(in)	nfvbag,
		integer, intent(in)	smonvol,
		integer, intent(in)	svolmon,
		integer, intent(in)	airbags_total_fvm,
		integer, dimension(airbags_total_fvm), intent(inout)	is_written_node_fvm,
		integer, intent(in)	airbags_node_id_shift )

Definition at line 36 of file anim_nodal_contour_fvmbags.F.

C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C     This suroutine computes nodal contour from fvmbag polyhedra (fvm case)
C     Done when requested by Engine keyword
C        pressure    : /ANIM/NODA/P or /H3D/NODA/P
C        density     : /ANIM/NODA/DENS or /H3D/NODA/DENS
C        temperature : /ANIM/NODA/TEMP or /H3D/NODA/TEMP
C        volume      : /ANIM/NODA/ZVOL or /H3D/NODA/ZVOL
C-----------------------------------------------
C   P r e - C o n d i t i o n s
C-----------------------------------------------
C     none
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE fvbag_mod , only:fvbag_data !data structure definition
      USE groupdef_mod , only:group_
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "vect01_c.inc"
#include      "param_c.inc"
#include      "inter22.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      CHARACTER*4, INTENT(IN) :: KEY
      INTEGER,INTENT(IN) :: NFVBAG, SMONVOL,SVOLMON, AIRBAGS_TOTAL_FVM, AIRBAGS_NODE_ID_SHIFT
      REAL,INTENT(INOUT) :: WA4(AIRBAGS_TOTAL_FVM)
      my_real,INTENT(IN) :: volmon(svolmon)
      INTEGER,INTENT(IN) :: MONVOL(SMONVOL)
      TYPE(FVBAG_DATA), INTENT(IN) :: FVDATA_P(NFVBAG) 
      INTEGER,INTENT(INOUT) :: IS_WRITTEN_NODE_FVM(AIRBAGS_TOTAL_FVM)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: K1        !< index shift for MONVOL ARRAY
      INTEGER :: NN, II    !< loop
      INTEGER :: ITYP      !< monvol type (refer to read_monvol.F)
      INTEGER :: IH3D_FLAG !< node group identifier
      INTEGER :: NNODES    !< number of nodes in group
      INTEGER :: IFV       !< FVMBAG identifier in [1, NFVBAG] where NFVBAG <= NVOLU
      my_real :: VALUE     !< polyhedron value
      INTEGER :: K_SHIFT   !< shift value for index : sum of previous NPOLH
      INTEGER :: INDX
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------    
 
 
      !loop over all airbags, skip ones which are not FVMBAG (no internal mesh)
      ! then if grnod_id is provided get corresponding value in the output buffer WA4 depending on KEY value (pressure, temperature, density ...)  
      k1=1
      k_shift=0
      DO nn=1,nvolu
         ityp=monvol(k1-1+2)
         IF (ityp == 6.OR.ityp == 8 .OR. ityp == 11) THEN   ! /MONVOL/FVMBAG, or FVMBAG1, or FVMBAG2
            ih3d_flag = monvol(k1-1 +75)  !GRNOD internal identifier in [1:NGRNOD]
            ifv = monvol(k1-1 +45)
            !check if grnod_id was provided, otherwise skip
            IF(ih3d_flag == 1 .AND. ifv /= 0)THEN
              
              IF(fvdata_p(ifv)%NPOLH > 0)THEN !if GRNOD is not empty and if there are any polyhedron
                                 
                 SELECT CASE (trim(key))
                 
                   CASE('P','PRES')
                     DO ii=1,fvdata_p(ifv)%NPOLH !loop over polyhedra composing the airbag mesh
                       VALUE = fvdata_p(ifv)%PPOLH(ii)
                       wa4(k_shift+ii) = VALUE
                       is_written_node_fvm(k_shift+ii) = 1
                    enddo! next I (next polyhedron)
 
                   CASE('T','TEMP')
                     DO ii=1, fvdata_p(ifv)%NPOLH !loop over polyhedra composing the airbag mesh
                       VALUE = fvdata_p(ifv)%TPOLH(ii)
                       wa4(k_shift+ii) = VALUE
                       is_written_node_fvm(k_shift+ii) = 1
                    enddo! next I (next polyhedron)
 
                   CASE('D','DENS')
                     DO ii=1, fvdata_p(ifv)%NPOLH !loop over polyhedra composing the airbag mesh
                       VALUE = fvdata_p(ifv)%RPOLH(ii)
                       wa4(k_shift+ii) = VALUE
                       is_written_node_fvm(k_shift+ii) = 1
                    enddo! next I (next polyhedron)
                    
                   CASE('SSP')
                     DO ii=1, fvdata_p(ifv)%NPOLH !loop over polyhedra composing the airbag mesh
                       VALUE = fvdata_p(ifv)%SSPPOLH(ii)
                       wa4(k_shift+ii) = VALUE
                       is_written_node_fvm(k_shift+ii) = 1
                    enddo! next I (next polyhedron)           
                    
                   CASE('DT')
                     DO ii=1, fvdata_p(ifv)%NPOLH !loop over polyhedra composing the airbag mesh
                       VALUE = fvdata_p(ifv)%DTPOLH(ii)
                       wa4(k_shift+ii) = VALUE
                       is_written_node_fvm(k_shift+ii) = 1
                    enddo! next I (next polyhedron)                               
 
                   CASE('V', 'VOL', 'ZVOL')
                     DO ii=1, fvdata_p(ifv)%NPOLH !loop over polyhedra composing the airbag mesh
                       VALUE = zero
                       IF(abs(fvdata_p(ifv)%RPOLH(ii)) > em20 )THEN
                         VALUE = fvdata_p(ifv)%MPOLH(ii) / fvdata_p(ifv)%RPOLH(ii)
                       ENDIF
                       wa4(k_shift+ii) = VALUE
                       is_written_node_fvm(k_shift+ii) = 1
                    enddo! next I (next polyhedron)                                                    
 
                END SELECT
 
 
 
              ENDIF !NPOLH>0>0 
            ENDIF !IH3D_FLAG>0
            k_shift = k_shift + fvdata_p(ifv)%NPOLH
         ENDIF ! ITYP
         k1=k1+nimv
 
      ENDDO !next NN
      
      ! set minimum value to other nodes in the group (otherwise visualization may lead to unsuitable color legend/gradient)          
      IF(k_shift < airbags_total_fvm)THEN                                                                       
        DO ii= k_shift+1,airbags_total_fvm                                                                      
          wa4(ii) = zero      
          is_written_node_fvm(ii) = 0                                                                                                 
        ENDDO                                                                                                                         
      ENDIF        
 
      
      RETURN