create_part_clause.F File Reference

#include "implicit_f.inc"
#include "com04_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	create_part_clause (clause, ipartm1, jclause, opt_g, is_available, lsubmodel)
subroutine	create_part_list (clause, ipartm1, jclause, is_available, lsubmodel)
subroutine	create_part_list_g (clause, ipartm1, jclause, is_available, lsubmodel)

Function/Subroutine Documentation

create_part_clause()

subroutine create_part_clause	(	type (set_)	clause,
		integer, dimension(npart,2), intent(in)	ipartm1,
		integer	jclause,
		integer	opt_g,
		logical	is_available,
		type(submodel_data), dimension(*), intent(in)	lsubmodel )

Definition at line 36 of file create_part_clause.F.

C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   Treat the PART Clause, read PARTs from HM_READER & fill clause
C   Calls CREATE_PART_LIST (simple list)
C   Calls CREATE_PART_LIST_G (PART_G : All parts from a MIN to MAX with increment)
C------------------------------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME          DESCRIPTION                         
C
C     CLAUSE        (SET structure) Clause to be treated
C     IPARTM1       MAP Table UID -> LocalID
C     JCLAUSE       parameter with HM_READER (current clause read)
C     Opt_G         Opt_G operator 1 if PART_G is set, 0 else
C     IS_AVAILABLE  Bool / Result of HM_interface
C     LSUBMODEL     SUBMODEL Structure.
C============================================================================
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE setdef_mod
      USE submodel_mod
      USE message_mod
      USE hm_option_read_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JCLAUSE,OPT_G
      LOGICAL :: IS_AVAILABLE
      INTEGER, INTENT(IN), DIMENSION(NPART,2) :: IPARTM1
C-----------------------------------------------
      TYPE (SET_) ::  CLAUSE
      TYPE(SUBMODEL_DATA),INTENT(IN):: LSUBMODEL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
!
      IF(npart == 0)THEN
         CALL ancmsg(msgid=2007,anmode=aninfo,
     .               msgtype=msgwarning,
     .               i1 = clause%SET_ID,
     .               c1=trim(clause%TITLE),
     .               c2='PARTS')
         clause%NB_PART = 0
         RETURN
      ENDIF
 
        IF (opt_g == 1 ) THEN
             CALL create_part_list_g(clause,  ipartm1  ,jclause ,is_available ,lsubmodel)
        ELSE
             CALL create_part_list  (clause,  ipartm1  ,jclause ,is_available ,lsubmodel)
        ENDIF
C-----------------------------------------------

create_part_list()

subroutine create_part_list	(	type (set_)	clause,
		integer, dimension(npart,2), intent(in)	ipartm1,
		integer	jclause,
		logical	is_available,
		type(submodel_data), dimension(*), intent(in)	lsubmodel )

Definition at line 117 of file create_part_clause.F.

C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   Create PART Clause from LIST
C------------------------------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME          DESCRIPTION                         
C
C     CLAUSE        (SET structure) Clause to be treated
C     IPARTM1       MAP Table UID -> LocalID
C     JCLAUSE       parameter with HM_READER (current clause read)
C     IS_AVAILABLE  Bool / Result of HM_interface
C     LSUBMODEL     SUBMODEL Structure.
C============================================================================
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE setdef_mod
      USE submodel_mod
      USE message_mod
      USE hm_option_read_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JCLAUSE
      LOGICAL :: IS_AVAILABLE
      INTEGER, INTENT(IN), DIMENSION(NPART,2) :: IPARTM1
!
      TYPE (SET_) ::  CLAUSE
      TYPE(SUBMODEL_DATA),INTENT(IN):: LSUBMODEL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,IDS,NINDX,LIST_SIZE,IDS_MAX,PARTM
      INTEGER IWORK(70000)
!
      INTEGER, ALLOCATABLE, DIMENSION(:) :: PART_READ_TMP,SORTED_PARTS,INDEX
C
      INTEGER SET_USRTOS
      EXTERNAL set_usrtos
C=======================================================================
 
      CALL hm_get_int_array_index('idsmax' ,ids_max ,jclause,is_available,lsubmodel)
 
      ALLOCATE(part_read_tmp(ids_max))
      ALLOCATE(sorted_parts(ids_max))
 
      ALLOCATE(index(2*ids_max))
      index = 0
 
      nindx = 0
      list_size = 0
 
      ! Read & convert Parts
      ! ---------------------
      DO i=1,ids_max
         CALL hm_get_int_array_2indexes('ids',ids,jclause,i,is_available,lsubmodel)
!
         partm = set_usrtos(ids,ipartm1,npart)
         IF(partm == 0)THEN        
           ! Part was not found. Issue a Warning & Skip.
           CALL ancmsg(msgid=1902,anmode=aninfo,
     .                             msgtype=msgwarning,
     .                             i1 = clause%SET_ID,
     .                             i2=ids,
     .                             c1=trim(clause%TITLE),
     .                             c2='PART')
         ELSE
 
           partm=ipartm1(partm,2)
 
           nindx=nindx+1    !   nb of CLAUSE parts
           part_read_tmp(nindx) = partm
         ENDIF
 
      ENDDO ! DO K=1,IDS_MAX
 
      ! Sort the Readed PARTs and remove eventual duplicates
      ! ---------------------------------------------------- 
 
      DO i=1,nindx
        index(i) = i
      ENDDO
      CALL my_orders(0,iwork,part_read_tmp,index,nindx,1)
                
      DO i=1,nindx
         sorted_parts(i) = part_read_tmp(index(i))
      ENDDO
 
      CALL remove_duplicates( sorted_parts,nindx,list_size)
 
      ! Copy in final SET
      ! ------------------
      clause%NB_PART = list_size  
      ALLOCATE( clause%PART( list_size ) )
 
      DO i=1,list_size
        clause%PART(i) = sorted_parts(i)
      ENDDO
!---
 
C-------------------------
       DEALLOCATE(part_read_tmp)
       DEALLOCATE(sorted_parts)
       DEALLOCATE(index)
C-------------------------
      RETURN

create_part_list_g()

subroutine create_part_list_g	(	type (set_)	clause,
		integer, dimension(npart,2), intent(in)	ipartm1,
		integer	jclause,
		logical	is_available,
		type(submodel_data), dimension(*), intent(in)	lsubmodel )

Definition at line 251 of file create_part_clause.F.

C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   Create PART Clause from Generation All parts from Min to Max with Increment (Opt_G)
C--------------------------------------------------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME          DESCRIPTION                         
C
C     CLAUSE        (SET structure) Clause to be treated
C     IPARTM1       MAP Table UID -> LocalID
C     JCLAUSE       parameter with HM_READER (current clause read)
C     IS_AVAILABLE  Bool / Result of HM_interface
C     LSUBMODEL     SUBMODEL Structure.
C============================================================================
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE setdef_mod
      USE submodel_mod
      USE message_mod
      USE hm_option_read_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JCLAUSE
      LOGICAL :: IS_AVAILABLE
      INTEGER, INTENT(IN), DIMENSION(NPART,2) :: IPARTM1
!
      TYPE (SET_) ::  CLAUSE
      TYPE(SUBMODEL_DATA),INTENT(IN):: LSUBMODEL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,IDS,LIST_SIZE,IDS_MAX,PARTM,GENE_MAX,K,P,P1
      INTEGER START_GENE,END_GENE,INCR_GENE,PSTART,PSTOP,STACK,STACK_ONE,NB_RESULT
!-
      INTEGER, ALLOCATABLE, DIMENSION(:) :: PART_READ_TMP,
     .         PART_READ_ONE,RESULT
C
      INTEGER  SET_USRTOS_NEAREST
      EXTERNAL set_usrtos_nearest
C=======================================================================
 
      CALL hm_get_int_array_index('genemax' ,gene_max ,jclause,is_available,lsubmodel)
 
      ALLOCATE(part_read_tmp(npart))
      ALLOCATE(part_read_one(npart))
 
      IF (gene_max > 1) THEN
          ALLOCATE(result(npart))
      ENDIF
 
      stack=0
 
      DO k=1,gene_max
          CALL hm_get_int_array_2indexes('start'  ,start_gene,jclause,k,is_available,lsubmodel)
          CALL hm_get_int_array_2indexes('end'    ,end_gene  ,jclause,k,is_available,lsubmodel)
          CALL hm_get_int_array_2indexes('by'     ,incr_gene ,jclause,k,is_available,lsubmodel)
 
          ! set value by default for increment to 1
          IF (incr_gene == 0) incr_gene = 1
 
          pstart = set_usrtos_nearest(start_gene,ipartm1,npart,1)
          pstop  = set_usrtos_nearest(end_gene,ipartm1,npart,2)
     
          stack_one=0
 
          DO p=pstart, pstop
             p1 = ipartm1(p,1)
             IF ( mod( p1-start_gene , incr_gene) == 0 ) THEN
                stack_one = stack_one+1
                part_read_one(stack_one) = ipartm1(p,2)
             ENDIF
          ENDDO
 
          IF (stack==0) THEN
             part_read_tmp(1:stack_one) = part_read_one(1:stack_one)
             stack = stack_one
          ELSE
             ! This code will not go if  GENE_MAX == 1 / Result does not need to be allocated
             CALL union_2_sorted_sets( part_read_tmp, stack ,
     *                                 part_read_one, stack_one ,
     *                                 result,        nb_result )
 
            part_read_tmp(1:nb_result) = result(1:nb_result)
            stack = nb_result
          ENDIF
      ENDDO
 
      clause%NB_PART = stack
      ALLOCATE(clause%PART(stack))
      clause%PART(1:stack) = part_read_tmp(1:stack)
!
      DEALLOCATE (part_read_tmp)
      DEALLOCATE (part_read_one)
      IF (ALLOCATED(result)) DEALLOCATE (result)
!