ebcs5.F File Reference

#include "implicit_f.inc"
#include "com08_c.inc"
#include "scr11_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	ebcs5 (nseg, iseg, segvar, a, v, x, liste, nod, irect, la, fv, ms, stifn, ebcs)

Function/Subroutine Documentation

ebcs5()

subroutine ebcs5	(	integer	nseg,
		integer, dimension(nseg)	iseg,
		type(t_segvar)	segvar,
			a,
			v,
			x,
		integer, dimension(nod)	liste,
		integer	nod,
		integer, dimension(4,nseg)	irect,
			la,
			fv,
			ms,
			stifn,
		type(t_ebcs_normv), intent(in)	ebcs )

Definition at line 31 of file ebcs5.F.

      USE ebcs_mod
      USE segvar_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
#include      "scr11_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NSEG,NOD,ISEG(NSEG),LISTE(NOD),IRECT(4,NSEG)
      my_real
     .        a(3,*),v(3,*),x(3,*),
     .        la(3,nod),ms(*),stifn(*),fv(*)
      TYPE(t_ebcs_normv), INTENT(IN) :: EBCS
      TYPE(t_segvar) :: SEGVAR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,IS,KSEG,N1,N2,N3,N4,NG1,NG2,NG3,NG4,N,IVIMP,
     . IRHO,IENER
      my_real
     .       orient,rho,c,roc,fac,
     .       x13,y13,z13,x24,y24,z24,nx,ny,nz,s,
     .       roou,enou,vmx,vmy,vmz,fluxi,fluxo,p,dvx,dvy,dvz,vimp,ener
C-----------------------------------------------
      ivimp=ebcs%ivimp
      irho=ebcs%irho
      iener=ebcs%iener
      IF(ivimp>0)THEN
        vimp=ebcs%vimp*fv(ivimp)
      ELSE
        vimp=ebcs%vimp
      ENDIF
      IF(irho>0)THEN
        rho=ebcs%rho*fv(irho)
      ELSE
        rho=ebcs%rho
      ENDIF
      IF(iener>0)THEN
        ener=ebcs%ener*fv(iener)
      ELSE
        ener=ebcs%ener
      ENDIF
c      write(6,*)'ebcs5 V rho e',VIMP,RHO,ENER
      c=ebcs%c
      roc=rho*c
C
C     INITIALISATION DES DENSITES ET ENERGIES INITIALES
C
C SURFACE NORMALE NODALES
      DO i=1,nod
         la(1,i)=zero
         la(2,i)=zero
         la(3,i)=zero
      ENDDO
      DO is=1,nseg
        kseg=abs(iseg(is))
        orient=float(iseg(is)/kseg)
        n1=irect(1,is)
        n2=irect(2,is)
        n3=irect(3,is)
        n4=irect(4,is)
        IF(n4==0 .OR. n4==n3) THEN
          fac=one_over_6*orient
          n4=n3
        ELSE
          fac=one_over_8*orient
        ENDIF
c
        ng1=liste(n1)
        ng2=liste(n2)
        ng3=liste(n3)
        ng4=liste(n4)
        x13=x(1,ng3)-x(1,ng1)
        y13=x(2,ng3)-x(2,ng1)
        z13=x(3,ng3)-x(3,ng1)
        x24=x(1,ng4)-x(1,ng2)
        y24=x(2,ng4)-x(2,ng2)
        z24=x(3,ng4)-x(3,ng2)
c
        nx=(y13*z24-z13*y24)*fac
        ny=(z13*x24-x13*z24)*fac
        nz=(x13*y24-y13*x24)*fac
c
        la(1,n1)=la(1,n1)+nx
        la(2,n1)=la(2,n1)+ny
        la(3,n1)=la(3,n1)+nz
        la(1,n2)=la(1,n2)+nx
        la(2,n2)=la(2,n2)+ny
        la(3,n2)=la(3,n2)+nz
        la(1,n3)=la(1,n3)+nx
        la(2,n3)=la(2,n3)+ny
        la(3,n3)=la(3,n3)+nz 
C
        vmx=v(1,ng1)+v(1,ng2)+v(1,ng3)
        vmy=v(2,ng1)+v(2,ng2)+v(2,ng3)
        vmz=v(3,ng1)+v(3,ng2)+v(3,ng3)
        IF(n4/=n3) THEN
           la(1,n4)=la(1,n4)+nx
           la(2,n4)=la(2,n4)+ny
           la(3,n4)=la(3,n4)+nz
           vmx=vmx+v(1,ng4)
           vmy=vmy+v(2,ng4)
           vmz=vmz+v(3,ng4)
        ENDIF
C
c bilan masse et energie totale
c
        roou = segvar%RHO(kseg)
        enou = segvar%EINT(kseg)
c
        fluxo=(vmx*nx+vmy*ny+vmz*nz)*dt1
        fluxi=min(fluxo,zero)
        fluxo=max(fluxo,zero)
c
        dmf=dmf-fluxo*roou-fluxi*rho
        def=def-fluxo*enou-fluxi*ener
C
C stockage densit  et  nergie entrante dans buffer facette
C
        segvar%RHO(kseg)=rho
        segvar%EINT(kseg)=ener
      ENDDO
C
      IF(tt==0)THEN
        DO i=1,nod
          n=liste(i)
          fac=vimp/sqrt(la(1,i)**2+la(2,i)**2+la(3,i)**2)
          v(1,n)=fac*la(1,i)
          v(2,n)=fac*la(2,i)
          v(3,n)=fac*la(3,i)
        ENDDO
      ENDIF
C
      DO i=1,nod
        n=liste(i)
        s=sqrt(la(1,i)**2+la(2,i)**2+la(3,i)**2)
        dvx=v(1,n)-vimp*la(1,i)/s
        dvy=v(2,n)-vimp*la(2,i)/s
        dvz=v(3,n)-vimp*la(3,i)/s
c        write(6,*)I,N,v(3,N),v0(3,I),roc
        p=roc*(dvx*la(1,i)+dvy*la(2,i)+dvz*la(3,i))/s
c
        a(1,n)=a(1,n)-p*la(1,i)
        a(2,n)=a(2,n)-p*la(2,i)
        a(3,n)=a(3,n)-p*la(3,i)
        stifn(n)=stifn(n)+(two*(s*roc)**2)/ms(n)
      ENDDO
c
      RETURN