fail_cockroft_c.F File Reference

#include "implicit_f.inc"
#include "units_c.inc"
#include "comlock.inc"
#include "lockon.inc"
#include "lockoff.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	fail_cockroft_c (nel, nuvar, time, uparam, ngl, ipt, ilay, npt0, iptt, ipg, signxx, signyy, signxy, epsxx, epsyy, epsxy, epsyz, epszx, dpla, uvar, uel, foff, off, dfmax, tdel)

Function/Subroutine Documentation

fail_cockroft_c()

subroutine fail_cockroft_c	(	integer	nel,
		integer	nuvar,
			time,
			uparam,
		integer, dimension(nel)	ngl,
		integer	ipt,
		integer, intent(in)	ilay,
		integer	npt0,
		integer, intent(in)	iptt,
		integer, intent(in)	ipg,
			signxx,
			signyy,
			signxy,
			epsxx,
			epsyy,
			epsxy,
			epsyz,
			epszx,
			dpla,
			uvar,
			uel,
		integer, dimension(nel), intent(inout)	foff,
			off,
			dfmax,
			tdel )

Definition at line 29 of file fail_cockroft_c.F.

C--------------------------------------------------------------------
C   /FAIL/COCKROFT - Cockroft-Latham failure criteria for shells and solids
C--------------------------------------------------------------------
C-----------------------------------------------
C I m p l i c i t T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include "units_c.inc"
#include "comlock.inc"
C---------+--------+---+---+-------------------------------------------
C VAR     | SIZE   |TYP| RW| DEFINITION
C---------+--------+---+---+-------------------------------------------
C NEL     | 1      | I | R | SIZE OF THE ELEMENT GROUP NEL
C NUPARAM | 1      | I | R | SIZE OF THE USER PARAMETER ARRAY
C NUVAR   | 1      | I | R | NUMBER OF USER ELEMENT VARIABLES
C NPT0    | 1      | I | R | NUMBER OF LAYERS OR INTEGRATION POINTS
C IPT     | 1      | I | R | LAYER OR INTEGRATION POINT NUMBER
C NGL     | NEL    | I | R | ELEMENT NUMBER
C---------+--------+---+---+-------------------------------------------
C TIME    | 1      | F | R | CURRENT TIME
C UPARAM  | NUPARAM| F | R | USER MATERIAL PARAMETER ARRAY
C EPSPXX  | NEL    | F | R | STRAIN RATE XX
C EPSPYY  | NEL    | F | R | STRAIN RATE YY
C ...     |        |   |   |
C EPSXX   | NEL    | F | R | STRAIN XX
C EPSYY   | NEL    | F | R | STRAIN YY
C---------+--------+---+---+-------------------------------------------
C SIGNXX  | NEL    | F |R/W| NEW ELASTO PLASTIC STRESS XX
C SIGNYY  | NEL    | F |R/W| NEW ELASTO PLASTIC STRESS YY
C ...     |        |   |   |
C---------+--------+---+---+-------------------------------------------
C PLA     | NEL    | F | R | PLASTIC STRAIN
C DPLA    | NEL    | F | R | INCREMENTAL PLASTIC STRAIN
C EPSP    | NEL    | F | R | EQUIVALENT STRAIN RATE
C UVAR    |NEL*NUVAR| F|R/W| USER ELEMENT VARIABLE ARRAY
C OFF     | NEL    | F |R/W| DELETED ELEMENT FLAG (=1. ON, =0. OFF)
C FOFF    | NEL     | I |R/W| DELETED INTEGRATION POINT FLAG (=1 ON, =0 OFF)
C---------+--------+--+--+-------------------------------------------
C I N P U T A r g u m e n t s
C-----------------------------------------------
       INTEGER, INTENT(IN) :: ILAY,IPTT,IPG
       INTEGER NEL,  NUVAR, NGL(NEL),
     .   IPT,NPT0,NOFF(NEL)
       my_real time,uparam(*),dpla(nel),
     .   epsxx(nel) ,epsyy(nel) ,epsxy(nel),
     .   epsyz(nel) ,epszx(nel),
     .   dfmax(nel) ,tdel(nel)
 
C
C-----------------------------------------------
C I N P U T O U T P U T A r g u m e n t s
C-----------------------------------------------
       INTEGER ,DIMENSION(NEL), INTENT(INOUT) :: FOFF
       my_real uvar(nel,nuvar), off(nel),offl(nel),
     .   signxx(nel),signyy(nel),uel(nel),
     .   signxy(nel)
 
C-----------------------------------------------
C L o c a l V a r i a b l e s
C-----------------------------------------------
       INTEGER I,J,NINDX,LEN
       INTEGER, DIMENSION(NEL) :: INDX
       my_real   e_hyd,e_11,e_22,e_33,e_12,e_23,e_13,
     .           eeq,d_eeq,sig_11,sig_a,sig_b
C-----------------------------------------------
C Ex : ELEMENT IS OFF iF COLA > C0
C-----------------------------------------------
       my_real   c0 , ema
 
C-----------------------------------------------
C Ex : ELEMENT IS OFF number if IPs due to Cockroft-Latham criteria reached P_thick
C-----------------------------------------------
C!      UVAR(I,1) contains previous equivalent strain value increment
C!      UVAR(I,2) contains the Cockroft-Latham accumulated value
c!      UVAR(I,3) contains the previous first principal stress
       c0                  = uparam(1)
       ema                 = uparam(2)
       nindx               = 0       
C-----------------------------------------------
       DO i =1,nel
         IF(off(i) >= one .AND. foff(i) == 1 ) THEN
c! equivalent strain calculation (negative = total strain ; positive = plastic strain)
          IF(c0 < zero)THEN
            e_hyd = third * (epsxx(i) + epsyy(i))
            e_11  = epsxx(i) - e_hyd
            e_22  = epsyy(i) - e_hyd
            e_33  =  -e_hyd
            e_12  = half*epsxy(i)
            e_23  = half*epsyz(i)
            e_13  = half*epszx(i)
            
            eeq   = e_11**2 + e_22**2 + e_33**2
            eeq   = eeq + two * (e_12**2) + two * (e_23**2) + two * (e_13**2)
            eeq   = 0.8164965809 * sqrt(eeq) ! sqrt (2/3)*sqrt(...)
            
            d_eeq = eeq - uvar(i,1)
            IF (d_eeq <= zero) d_eeq = zero
            uvar(i,1) = eeq             
          ELSE                               ! positive = plastic strain increment
            d_eeq = dpla(i)
            uvar(i,1) = uvar(i,1) + dpla(i)
          ENDIF
 
c! first principal stress Sigma_1 calculation          
          sig_a  = (signxx(i) + signyy(i))/two
          sig_b  = sqrt(((signxx(i)-signyy(i))/two)**2+signxy(i)**2)
          sig_11 = sig_a + sig_b
          sig_11   = sig_11 * ema + (one-ema)* uvar(i,3)
          uvar(i,3)= sig_11
          uvar(i,2) = uvar(i,2) + max(sig_11,zero) * d_eeq
          
          dfmax(i) =  min(uvar(i,2) / max(em20,abs(c0)),one)
          
          IF (dfmax(i) >= one) THEN
            nindx = nindx + 1
            indx(nindx) = i  
            foff(i) = 0
            tdel(i) = time            
          ENDIF 
         ENDIF
       ENDDO
C!
       DO j=1,nindx
         i = indx(j)
#include "lockon.inc"
          WRITE(iout, 2000) ngl(i),ipg,ilay,iptt
          WRITE(istdo,2100) ngl(i),ipg,ilay,iptt,time
#include "lockoff.inc" 
 
       ENDDO
c------------------
 2000 FORMAT(1x,'FAILURE (COCKROFT-LATHAM) OF SHELL ELEMENT ',i10,1x,',GAUSS PT',i2,1x,',LAYER',i3,
     .       1x,',INTEGRATION PT',i3)
 2100 FORMAT(1x,'FAILURE (COCKROFT-LATHAM) OF SHELL ELEMENT ',i10,1x,',GAUSS PT',i2,1x,',LAYER',i3,
     .       1x,',INTEGRATION PT',i3,1x,'AT TIME :',1pe12.4)
c------------------
 
       RETURN