fail_energy_b.F File Reference

#include "implicit_f.inc"
#include "comlock.inc"
#include "lockon.inc"
#include "lockoff.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	fail_energy_b (nel, ngl, nuparam, uparam, time, epsd, off, dfmax, tdel, iout, istdo, ifunc, area, f1, f2, f3, m1, m2, m3, snpc, npf, stf, tf, epsxx, epsxy, epsxz, kxx, kyy, kzz, nvar, uvar, dmgscl)

Function/Subroutine Documentation

fail_energy_b()

subroutine fail_energy_b	(	integer, intent(in)	nel,
		integer, dimension(nel), intent(in)	ngl,
		integer, intent(in)	nuparam,
		intent(in)	uparam,
		intent(in)	time,
		intent(in)	epsd,
		intent(inout)	off,
		intent(inout)	dfmax,
		intent(inout)	tdel,
		integer, intent(in)	iout,
		integer, intent(in)	istdo,
		integer, dimension(100), intent(in)	ifunc,
		intent(in)	area,
		intent(in)	f1,
		intent(in)	f2,
		intent(in)	f3,
		intent(in)	m1,
		intent(in)	m2,
		intent(in)	m3,
		integer, intent(in)	snpc,
		integer, dimension(snpc), intent(in)	npf,
		integer, intent(in)	stf,
		intent(in)	tf,
		intent(in)	epsxx,
		intent(in)	epsxy,
		intent(in)	epsxz,
		intent(in)	kxx,
		intent(in)	kyy,
		intent(in)	kzz,
		integer, intent(in)	nvar,
		intent(inout)	uvar,
		intent(inout)	dmgscl )

Definition at line 30 of file fail_energy_b.F.

C-----------------------------------------------
c    energy failure model for standard beams (TYPE 3)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include  "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include  "comlock.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER                     ,INTENT(IN)    :: NEL     ! size of element group
      INTEGER                     ,INTENT(IN)    :: NUPARAM ! size of parameter array
      INTEGER                     ,INTENT(IN)    :: IOUT    ! output file unit
      INTEGER                     ,INTENT(IN)    :: ISTDO   ! output file unit
      INTEGER                     ,INTENT(IN)    :: SNPC 
      INTEGER                     ,INTENT(IN)    :: STF       
      INTEGER ,DIMENSION(NEL)     ,INTENT(IN)    :: NGL     ! table of element identifiers
      INTEGER ,DIMENSION(100)     ,INTENT(IN)    :: IFUNC   ! table of functions identifiers
      INTEGER ,DIMENSION(SNPC)    ,INTENT(IN)    :: NPF
      INTEGER                     ,INTENT(IN)    :: NVAR
      my_real                     ,INTENT(IN)    :: time    ! current time
      my_real                     ,INTENT(IN)    :: area
      my_real ,DIMENSION(NUPARAM) ,INTENT(IN)    :: uparam  ! failure model parameter array
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: epsd    ! strain rate
      my_real ,DIMENSION(STF)     ,INTENT(IN)    :: tf
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: off     ! element deactivation flag
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: dfmax   ! maximum damage
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: tdel    ! deactivation time
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: f1,f2,f3
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: m1,m2,m3
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: epsxx,epsxy,epsxz
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: kxx,kyy,kzz
      my_real ,DIMENSION(NEL,NVAR),INTENT(INOUT) :: uvar    ! User variable
      my_real, DIMENSION(NEL)     ,INTENT(INOUT) :: dmgscl 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,NINDX
      INTEGER ,DIMENSION(NEL) :: INDX
      my_real :: rfac,r1,r2,ie_sp,dydx,rief1,rief2,xfac,finter,fact
      EXTERNAL finter
      my_real ,DIMENSION(NEL) :: damage
C=======================================================================
      nindx = 0  
      rief1    = uparam(1)             
      rief2    = uparam(2)           
      xfac     = uparam(4)           
      DO i=1,nel
        damage(i) = zero
        uvar(i,1) = uvar(i,1) + (
     .              f1(i)*epsxx(i) + f2(i)*epsxy(i) + f3(i)*epsxz(i) + 
     .              m1(i)*kxx(i)   + m2(i)*kyy(i)   + m3(i)*kzz(i))
      ENDDO
c-----------------------------
      DO i=1,nel
        IF (off(i) == one ) THEN
          IF (ifunc(1) /= 0) THEN
            rfac = finter(ifunc(1),epsd(i)*xfac,npf,tf,dydx)
            rfac = max(rfac,em20)
          ELSE
            rfac = one
          ENDIF  
          r1 = rief1*rfac
          r2 = rief2*rfac
          ie_sp = uvar(i,1)/area
 
          IF (ie_sp > r1) THEN
            damage(i) = (ie_sp-r1)/(r2-r1)
            damage(i) = min(one,damage(i))
            dfmax(i)  = max(dfmax(i) ,damage(i)) 
          ENDIF
 
          IF (ie_sp > r2) THEN
            nindx = nindx + 1
            indx(nindx) = i  
            tdel(i)     = time
            dfmax(i)    = one
            off(i)      = four_over_5
          ENDIF
        ENDIF 
        dmgscl(i) = one - dfmax(i) 
      ENDDO        
c------------------------
      IF (nindx > 0) THEN        
        DO j=1,nindx             
          i = indx(j)            
#include "lockon.inc"
          WRITE(iout, 1000) ngl(i),time
          WRITE(istdo,1000) ngl(i),time
#include "lockoff.inc" 
        END DO                   
      END IF   ! NINDX             
c------------------
 1000 FORMAT(5x,'FAILURE (ENERGY) OF BEAM ELEMENT ',i10,1x,'AT TIME :',1pe12.4)
c------------------
      RETURN