fail_johnson_ib.F File Reference

#include "implicit_f.inc"
#include "comlock.inc"
#include "lockon.inc"
#include "lockoff.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	fail_johnson_ib (nel, ngl, ipt, nuparam, uparam, time, tstar, signxx, signxy, signzx, dpla, epsd, off, foff, dfmax, tdel, iout, istdo, uelr, npg)

Function/Subroutine Documentation

fail_johnson_ib()

subroutine fail_johnson_ib	(	integer, intent(in)	nel,
		integer, dimension(nel), intent(in)	ngl,
		integer, intent(in)	ipt,
		integer, intent(in)	nuparam,
		intent(in)	uparam,
		intent(in)	time,
		intent(in)	tstar,
		intent(in)	signxx,
		intent(in)	signxy,
		intent(in)	signzx,
		intent(in)	dpla,
		intent(in)	epsd,
		intent(inout)	off,
		integer, dimension(nel), intent(inout)	foff,
		intent(inout)	dfmax,
		intent(inout)	tdel,
		integer, intent(in)	iout,
		integer, intent(in)	istdo,
		intent(inout)	uelr,
		integer, intent(in)	npg )

Definition at line 28 of file fail_johnson_ib.F.

C-----------------------------------------------
c    Johnson-Cook failure model for integrated beams
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include  "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include  "comlock.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER                     ,INTENT(IN)    :: NEL     ! size of element group
      INTEGER                     ,INTENT(IN)    :: NUPARAM ! size of parameter array
      INTEGER                     ,INTENT(IN)    :: IPT     ! current integration point
      INTEGER                     ,INTENT(IN)    :: IOUT    ! output file unit
      INTEGER                     ,INTENT(IN)    :: ISTDO   ! output file unit
      INTEGER ,DIMENSION(NEL)     ,INTENT(IN)    :: NGL     ! table of element identifiers
      my_real                     ,INTENT(IN)    :: time    ! current time
      my_real ,DIMENSION(NUPARAM) ,INTENT(IN)    :: uparam  ! failure model parameter array
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: dpla    ! plastic strain increment
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: epsd    ! strain rate
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: tstar   ! normalized temperature
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: off     ! element deactivation flag
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: signxx  ! stress component
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: signxy  ! stress component
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: signzx  ! stress component
      INTEGER ,DIMENSION(NEL)     ,INTENT(INOUT) :: FOFF    ! integration point deactivation flag
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: dfmax   ! maximum damage
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: tdel    ! desactivation time
      my_real, DIMENSION(NEL)     ,INTENT(INOUT) :: uelr
      INTEGER                     ,INTENT(IN)    :: NPG
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,NINDX,FAILIP
      INTEGER ,DIMENSION(NEL) :: INDX
      my_real :: d1,d2,d3,d4,d5,epsd0,p,epsf,svm,epsf_min
C=======================================================================
      nindx = 0  
      d1    = uparam(1)
      d2    = uparam(2)
      d3    = uparam(3)
      d4    = uparam(4)
      d5    = uparam(5)
      epsd0 = uparam(6)
      epsf_min = uparam(12)
      failip  = min(nint(uparam(13)),npg) 
c-----------------------------
      DO i=1,nel
        IF (off(i) == one .and. foff(i) == 1 .and. dpla(i) > zero) THEN
          p   = third*signxx(i)
          svm = signxx(i)**2 + three*(signxy(i)**2 + signzx(i)**2)
          svm = sqrt(svm)
          epsf = d3 * p / max(em20, svm)
          epsf = d1 + d2 * exp(epsf)
          IF (d4 /= zero)  epsf = epsf * (one + d4*log(max(one,epsd(i)/epsd0)))
          IF (d5 /= zero)  epsf = epsf * (one + d5*tstar(i))         
          epsf = max(epsf,epsf_min)  
          IF (epsf > zero) dfmax(i) = dfmax(i) + dpla(i) / epsf
          IF (dfmax(i) >= one) THEN ! total damage in integration point
            nindx = nindx + 1
            indx(nindx) = i  
            foff(i)     = 0
            tdel(i)     = time
            dfmax(i)    = one
            uelr(i)     = uelr(i) + one
            IF (nint(uelr(i)) >= failip) THEN 
              off(i)    = four_over_5
            ENDIF
          ENDIF
        ENDIF 
      ENDDO      
c------------------------
      IF (nindx > 0) THEN        
        DO j=1,nindx             
          i = indx(j)            
#include "lockon.inc"
          WRITE(iout, 1000) ngl(i),ipt,time
          WRITE(istdo,1000) ngl(i),ipt,time
#include "lockoff.inc" 
          IF (off(i) == four_over_5) THEN 
            WRITE(iout, 1111) ngl(i),time
            WRITE(istdo,1111) ngl(i),time
          ENDIF
        END DO                   
      END IF   ! NINDX             
c------------------
 1000 FORMAT(5x,'FAILURE (JC) OF BEAM ELEMENT ',i10,1x,',INTEGRATION PT',i5
     .      ,2x,'AT TIME :',1pe12.4)
 
 1111 FORMAT(1x,'DELETED BEAM ELEMENT ',i10,1x,'AT TIME :',1pe12.4)
c------------------
      RETURN