fail_wierzbicki_c.F File Reference

#include "implicit_f.inc"
#include "units_c.inc"
#include "comlock.inc"
#include "lockon.inc"
#include "lockoff.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	fail_wierzbicki_c (nel, nuparam, uparam, nuvar, uvar, time, ngl, ipg, ilay, ipt, signxx, signyy, signxy, signyz, signzx, dpla, off, foff, dfmax, tdel)

Function/Subroutine Documentation

fail_wierzbicki_c()

subroutine fail_wierzbicki_c	(	integer, intent(in)	nel,
		integer, intent(in)	nuparam,
		intent(in)	uparam,
		integer, intent(in)	nuvar,
		intent(inout)	uvar,
		intent(in)	time,
		integer, dimension(nel), intent(in)	ngl,
		integer, intent(in)	ipg,
		integer, intent(in)	ilay,
		integer, intent(in)	ipt,
		intent(in)	signxx,
		intent(in)	signyy,
		intent(in)	signxy,
		intent(in)	signyz,
		intent(in)	signzx,
		intent(in)	dpla,
		intent(in)	off,
		integer, dimension(nel), intent(inout)	foff,
		intent(inout)	dfmax,
		intent(out)	tdel )

Definition at line 29 of file fail_wierzbicki_c.F.

C-----------------------------------------------
C    Xue-Wierzbicki
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include "units_c.inc"
#include "comlock.inc"
C---------+---------+---+---+--------------------------------------------
C VAR     | SIZE    |TYP| RW| DEFINITION
C---------+---------+---+---+--------------------------------------------
C NEL     |  1      | I | R | SIZE OF THE ELEMENT GROUP NEL 
C NUPARAM |  1      | I | R | SIZE OF THE USER PARAMETER ARRAY
C UPARAM  | NUPARAM | F | R | USER MATERIAL PARAMETER ARRAY
C NUVAR   |  1      | I | R | NUMBER OF USER ELEMENT VARIABLES
C UVAR    |NEL*NUVAR| F |R/W| USER ELEMENT VARIABLE ARRAY
C---------+---------+---+---+--------------------------------------------
C TIME    |  1      | F | R | CURRENT TIME
C---------+---------+---+---+--------------------------------------------
C SIGNXX  | NEL     | F | W | NEW ELASTO PLASTIC STRESS XX
C SIGNYY  | NEL     | F | W | NEW ELASTO PLASTIC STRESS YY
C ...     |         |   |   |
C DPLA    | NEL     | F | R | PLASTIC STRAIN INCREMENT
C---------+---------+---+---+--------------------------------------------
C OFF     | NEL     | F | R | DELETED ELEMENT FLAG (=1. ON, =0. OFF)
C FOFF    | NEL     | I |R/W| DELETED INTEGRATION POINT FLAG (=1 ON, =0 OFF)
C DFMAX   | NEL     | F |R/W| MAX DAMAGE FACTOR 
C TDEL    | NEL     | F | W | FAILURE TIME
C---------+---------+---+---+--------------------------------------------
C NGL                         ELEMENT ID
C IPG                         CURRENT GAUSS POINT (in plane)
C ILAY                        CURRENT LAYER
C IPT                         CURRENT INTEGRATION POINT IN THE LAYER
C---------+---------+---+---+--------------------------------------------
C   I N P U T   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: NEL,NUPARAM,NUVAR,IPG,ILAY,IPT
      INTEGER ,DIMENSION(NEL) ,INTENT(IN) :: NGL
      my_real ,INTENT(IN) :: time
      my_real ,DIMENSION(NEL) ,INTENT(IN) :: dpla,off,
     .   signxx,signyy,signxy,signyz,signzx
      my_real,DIMENSION(NUPARAM) ,INTENT(IN) :: uparam
C-----------------------------------------------
C   I N P U T   O U T P U T   A r g u m e n t s 
C-----------------------------------------------
      INTEGER ,DIMENSION(NEL) ,INTENT(INOUT) :: FOFF
      my_real ,DIMENSION(NEL) ,INTENT(INOUT) :: dfmax
      my_real ,DIMENSION(NEL) ,INTENT(OUT)   :: tdel
      my_real ,DIMENSION(NEL,NUVAR) ,INTENT(INOUT) :: uvar
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,NINDX
      INTEGER ,DIMENSION(NEL) :: INDX
      my_real :: c1,c2,c3,c4,cm,cn,p,epsf,svm,eta,xi
C=======================================================================
      c1 = uparam(1)
      c2 = uparam(2)
      c3 = uparam(3)
      c4 = uparam(4)
      cm = uparam(5)
      cn = uparam(6)
      nindx  = 0  
C-----------------------------------------------
      DO i=1,nel
        IF (off(i) == one .and. foff(i) == 1) THEN                               
          p = third*(signxx(i) + signyy(i))
          svm = sqrt(signxx(i)*signxx(i)
     .        + signyy(i)*signyy(i) - signxx(i)*signyy(i)
     .        + three*signxy(i)*signxy(i))
C 
          eta = p / max(em20,svm)                          
          xi = -half*(twenty + seven)*eta*(eta**2 - third) 
          epsf = (c1*exp(-c2*eta))**cn                     
     .         - (c3*exp(-c4*eta))**cn                     
          epsf = epsf * max(zero,(one - xi**cm))**(one/cm)   
          epsf = ((c1*exp(-c2*eta))**cn - epsf)**(one/cn)   
          IF (epsf > zero) dfmax(i) = dfmax(i) + dpla(i)*(one/epsf)       
          IF (dfmax(i) >= one) THEN         
            nindx = nindx + 1
            indx(nindx) = i
            foff(i) = 0
            tdel(i) = time
          ENDIF                                            
        ENDIF 
      ENDDO
c
c---  Maximum Damage storing for output : 0 < DFMAX < 1
      DO i=1,nel
        dfmax(i) = min(one,dfmax(i))
      ENDDO      
c------------------------
      IF (nindx > 0) THEN
        DO j=1,nindx
          i = indx(j)
#include  "lockon.inc"
          WRITE(iout, 2000) ngl(i),ipg,ilay,ipt
          WRITE(istdo,2100) ngl(i),ipg,ilay,ipt,time
#include  "lockoff.inc"
        END DO
      END IF              
c------------------------
 2000 FORMAT(1x,'FAILURE (WIERZBICKI) OF SHELL ELEMENT ',i10,1x,',GAUSS PT',
     .       i2,1x,',LAYER',i3,1x,',INTEGRATION PT',i3)
 2100 FORMAT(1x,'FAILURE (WIERZBICKI) OF SHELL ELEMENT ',i10,1x,',GAUSS PT',
     .       i2,1x,',LAYER',i3,1x,',INTEGRATION PT',i3,1x,'AT TIME :',1pe12.4)
c------------------------
      RETURN