h3d_update_fvmbag_centroids.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    h3d_update_fvmbag_centroids   ../engine/source/output/h3d/h3d_build_fortran/h3d_update_fvmbag_centroids.F
!||--- called by ------------------------------------------------------
!||    genh3d                        ../engine/source/output/h3d/h3d_results/genh3d.F
!||--- calls      -----------------------------------------------------
!||    c_h3d_update_fvmbag_nodes     ../engine/source/output/h3d/h3d_build_cpp/c_h3d_update_fvmbag_nodes.cpp
!||--- uses       -----------------------------------------------------
!||    fvbag_mod                     ../engine/share/modules/fvbag_mod.F
!||    groupdef_mod                  ../common_source/modules/groupdef_mod.F
!||====================================================================
      SUBROUTINE h3d_update_fvmbag_centroids(H3DTITLE,LEN_H3DTITLE,IH3D,MONVOL,VOLMON, NFVBAG, SMONVOL, SVOLMON,
     .                                       FVDATA_P, AIRBAGS_NODE_ID_SHIFT)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C     This suroutine updates orphan nodes entities located at polyhedra centroids
C     (Visualization purpose)
C-----------------------------------------------
C   P r e - C o n d i t i o n s
C-----------------------------------------------
C     none
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE fvbag_mod , only: fvbag_data, airbags_total_fvm_in_h3d
      USE groupdef_mod , only:group_
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "vect01_c.inc"
#include      "param_c.inc"
#include      "inter22.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: NFVBAG, SMONVOL,SVOLMON, AIRBAGS_NODE_ID_SHIFT
      my_real,INTENT(IN) :: volmon(svolmon)
      INTEGER,INTENT(IN) :: MONVOL(SMONVOL) 
      CHARACTER*80,INTENT(IN):: H3DTITLE  
      INTEGER,INTENT(IN) :: LEN_H3DTITLE , IH3D 
      TYPE(fvbag_data),INTENT(IN) :: FVDATA_P(NFVBAG)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: K1        !< index shift for MONVOL ARRAY
      INTEGER :: NN, II    !< loop
      INTEGER :: ITYP      !< monvol type (refer to read_monvol.F)
      INTEGER :: IH3D_FLAG !< flag for H3D output
      INTEGER :: NNODES    !< number of centroids
      INTEGER :: IFV       !< FVMBAG identifier in [1, NFVBAG] where NFVBAG <= NVOLU
      INTEGER :: NPOLH     !< number of polyhedra for a given airbag
      my_real :: value_x   !< polyhedron centroid X-value
      my_real :: value_y   !< polyhedron centroid Y-value
      my_real :: value_z   !< polyhedron centroid Z-value            
      INTEGER :: ILEN      !< loop upper bound
      
      INTEGER, ALLOCATABLE,DIMENSION(:) :: ITAB_FVMBAG
      my_real, ALLOCATABLE,DIMENSION(:,:) :: xyz_fvmbag,disp_fvmbag
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------    
 
 
      !loop over all airbags, skip ones which are not FVMBAG (no internal mesh)
      ! then generate H3D (orphan) nodes at centroids
      k1=1
      nnodes = 0
      DO nn=1,nvolu
         ityp=monvol(k1-1+2)
         IF (ityp == 6.OR.ityp == 8 .OR. ityp == 11) THEN   ! /MONVOL/FVMBAG, or FVMBAG1, or FVMBAG2
            ih3d_flag = monvol(k1-1 +75)  !GRNOD internal identifier in [1:NGRNOD]
            ifv = monvol(k1-1 +45)
            !check if grnod_id was provided, otherwise skip
            IF(ih3d_flag == 1 .AND. ifv /= 0)THEN
              npolh = fvdata_p(ifv)%NPOLH
              
              IF(npolh > 0)THEN ! if there are any polyhedron
 
                 ALLOCATE(itab_fvmbag(npolh))
                 ALLOCATE(disp_fvmbag(3,npolh))
                 
                 DO ii=1, fvdata_p(ifv)%NPOLH !loop over polyhedra composing the airbag mesh
                   
                   disp_fvmbag(1,ii) = fvdata_p(ifv)%CENTROID_POLH(1,ii)
                   disp_fvmbag(2,ii) = fvdata_p(ifv)%CENTROID_POLH(2,ii)
                   disp_fvmbag(3,ii) = fvdata_p(ifv)%CENTROID_POLH(3,ii)
 
                   itab_fvmbag(ii) = airbags_node_id_shift+nnodes+ii
                 enddo! next I (next polyhedron)
 
                 CALL c_h3d_update_fvmbag_nodes(h3dtitle,len_h3dtitle,ih3d,itab_fvmbag,npolh,disp_fvmbag)
                 
                 DEALLOCATE(itab_fvmbag)
                 DEALLOCATE(disp_fvmbag)
                 nnodes = nnodes + fvdata_p(ifv)%NPOLH
 
              ENDIF !NNODES>0
               
            ENDIF !IH3D_FLAG>0
             
         ENDIF ! ITYP
         k1=k1+nimv
      ENDDO !next NN
      
      
      
      !loop from NNODES +1 to AIRBAGS_TOTAL_FVM_IN_H3D : locate them to  0,0,0
      ilen = airbags_total_fvm_in_h3d - nnodes
      ALLOCATE(itab_fvmbag(ilen+1))
      ALLOCATE(disp_fvmbag(3,ilen+1))
 
      DO ii=1,ilen
        itab_fvmbag(ii) = airbags_node_id_shift+nnodes+ii
        disp_fvmbag(1,ii) = zero
        disp_fvmbag(2,ii) = zero
        disp_fvmbag(3,ii) = zero                    
      ENDDO 
 
      CALL c_h3d_update_fvmbag_nodes(h3dtitle,len_h3dtitle,ih3d,itab_fvmbag,ilen,disp_fvmbag)
 
      DEALLOCATE(itab_fvmbag)
      DEALLOCATE(disp_fvmbag)
 
      
      RETURN
      END