hm_convert_2d_elements_seatbelt.F File Reference

#include "implicit_f.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_convert_2d_elements_seatbelt (idmax_part, idmax_prop, idmax_mat, idmax_elem, idmax_th, seatbelt_converted_elements, nb_seatbelt_shells, lsubmodel)

Function/Subroutine Documentation

hm_convert_2d_elements_seatbelt()

subroutine hm_convert_2d_elements_seatbelt	(	integer, intent(in)	idmax_part,
		integer, intent(in)	idmax_prop,
		integer, intent(in)	idmax_mat,
		integer, intent(in)	idmax_elem,
		integer, intent(in)	idmax_th,
		integer, dimension(3,nb_seatbelt_shells), intent(inout)	seatbelt_converted_elements,
		integer, intent(in)	nb_seatbelt_shells,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel )

Definition at line 38 of file hm_convert_2d_elements_seatbelt.F.

C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   ROUTINE TO CONVERT /SHELL & /MAT/LAW119 -> /SPRING /PART /PROP/TYPE23 & /MAT/LAW114
C-----------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME          DESCRIPTION                         
C    
C     IDMAX_PART                    MAX ID PARTS
C     IDMAX_PROP                    MAX ID PROPS
C     IDMAX_MAT                     MAX ID MATS
C     IDMAX_ELEM                    MAX ID ELEMS
C     IDMAX_TH                      MAX ID TH
C     SEATBELT_CONVERTED_ELEMENTS   CORRESPONDANCE SHELL SPRING FOR SEATBLETS
C     NB_SEATBELT_SHELLS            NUMBER OF SEATELT SHELL
C     LSUBMODEL                     SUBMODEL STRUCTURE    
C============================================================================
C   M o d u l e s
C-----------------------------------------------
      USE message_mod       
      USE submodel_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : ncharline
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C INPUT ARGUMENTS
      INTEGER,INTENT(IN)::IDMAX_PART,IDMAX_PROP,IDMAX_MAT,IDMAX_ELEM,IDMAX_TH,
     .                    NB_SEATBELT_SHELLS
      INTEGER,INTENT(INOUT)::SEATBELT_CONVERTED_ELEMENTS(3,NB_SEATBELT_SHELLS)
      TYPE(SUBMODEL_DATA),INTENT(IN)::LSUBMODEL(NSUBMOD)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,ID,SUBMODEL_INDEX,OFFSET,NB_PART,NB_MAT,NB_MAT_119,MAT_ID,ELEM_INDEX,NB_THSHELL,PART_ID
      INTEGER, DIMENSION(:), ALLOCATABLE :: PART_SUB,PART_MAT119,MAT119_IDS
      CHARACTER(LEN=NCHARLINE) :: KEY
      LOGICAL :: IS_AVAILABLE
C-----------------------------------------------
      nb_mat_119 = 0
C-----------------------------------------------
C   Check existence of Mat laws 119 in the model
C-----------------------------------------------
      CALL hm_option_count('/MAT',nb_mat)
c
      CALL hm_option_start('/MAT')
      DO i=1,nb_mat
        key  = ''
        CALL hm_option_read_key(lsubmodel,
     .                          keyword2    = key)
        IF(key(1:6) == 'LAW119' .OR. key(1:11) == 'SH_SEATBELT') THEN
          nb_mat_119 = nb_mat_119 + 1
        ENDIF
      ENDDO
C-----------------------------------------------
C   Search Parts with Mat 119 
C-----------------------------------------------
      IF (nb_mat_119 /= 0) THEN
        ALLOCATE(mat119_ids(nb_mat_119))
        mat119_ids(1:nb_mat_119) = 0
        j = 0
        CALL hm_option_start('/MAT')
        DO i=1,nb_mat
          key  = ''
          CALL hm_option_read_key(lsubmodel,
     .                          option_id   = id,
     .                          keyword2    = key,
     .                          submodel_index = submodel_index)
          IF(key(1:6) == 'LAW119' .OR. key(1:11) == 'SH_SEATBELT') THEN 
            j = j + 1
            mat119_ids(j) = id
          ENDIF
        ENDDO
C-----------------------------------------------
        CALL hm_option_count('/PART',nb_part)
        ALLOCATE(part_sub(nb_part))
        ALLOCATE(part_mat119(nb_part))
        part_mat119(1:nb_part) = 0
c
        CALL hm_option_start('/PART')
        DO i=1,nb_part
          CALL hm_option_read_key(lsubmodel,
     .                       option_id = id,
     .                       submodel_index = submodel_index)
          CALL hm_get_intv('materialid',mat_id,is_available,lsubmodel)
          DO j=1,nb_mat_119
            IF(mat_id == mat119_ids(j)) part_mat119(i) = id
          ENDDO
        ENDDO
C-----------------------------------------------
C   Translate /SHELL -> /SPRING /PART /PROP/TYPE23 & /MAT/LAW114
C-----------------------------------------------
c
        elem_index = 0
        DO i=1,nb_part
          IF(part_mat119(i) /= 0) THEN
            offset = 0
            part_id = part_mat119(i)
            CALL cpp_convert_2d_elements_seatbelt(part_id,idmax_part,idmax_prop,idmax_mat,
     .                                           idmax_elem,offset,seatbelt_converted_elements,elem_index)
          ENDIF
        ENDDO
c
        IF (ALLOCATED(part_sub)) DEALLOCATE(part_sub)
        IF (ALLOCATED(part_mat119)) DEALLOCATE(part_mat119)
        IF (ALLOCATED(mat119_ids)) DEALLOCATE(mat119_ids)
C-----------------------------------------------
C   Translate /TH containing /SHELLs THAT ARE TRANSLATED TO /SPRINGs
C-----------------------------------------------
c
        CALL hm_option_count('/TH/SHEL',nb_thshell)
        CALL hm_option_start('/TH/SHEL')
        DO i=1,nb_thshell
          CALL hm_option_next()
          CALL cpp_get_submodel_index(submodel_index)
          offset = 0
          CALL cpp_convert_th_2d_element_seatbelt(idmax_th,offset,seatbelt_converted_elements,nb_seatbelt_shells)
        ENDDO
c
C--------------------------------------------------
      ENDIF
      RETURN
C