hm_read_eos_lszk.F File Reference

#include "implicit_f.inc"
#include "param_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_eos_lszk (iout, pm, unitab, iunit, lsubmodel, imideos, mat_param)

Function/Subroutine Documentation

hm_read_eos_lszk()

subroutine hm_read_eos_lszk	(	integer	iout,
			pm,
		type (unit_type_), intent(in)	unitab,
		integer	iunit,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel,
		integer, intent(in)	imideos,
		type(matparam_struct_), intent(inout)	mat_param )

Definition at line 35 of file hm_read_eos_lszk.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod
      USE matparam_def_mod, ONLY : matparam_struct_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   MURNAGHAN EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IOUT, IUNIT
      my_real pm(npropm)
      TYPE(SUBMODEL_DATA), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE(MATPARAM_STRUCT_),INTENT(INOUT) :: MAT_PARAM
      INTEGER,INTENT(IN) :: IMIDEOS
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real  gamma, p0, e0, psh, rho0, a, b, rhoi, rhor, mu0, df, ssp0, g0, dpdmu, pp
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('Gamma', gamma, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_P0', p0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_PSH', psh, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('a', a, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('b', b, is_available,lsubmodel,unitab)
 
      CALL hm_get_floatv('Refer_Rho', rho0, is_available_rho0,lsubmodel,unitab)
 
      rhor = pm(1)
      rhoi = pm(89)
 
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
        mat_param%RHO = rho0
      ELSE
        rho0=rhor                   
      ENDIF
      
      !ERREURS :
      ! GAMMA <=0
      
      IF(gamma <= zero)THEN
         CALL ancmsg(msgid=67,
     .               msgtype=msgerror,
     .               anmode=aninfo,
     .               i1=imideos,
     .               c1='/EOS/LSZK',
     .               c2='GAMMA MUST BE GREATER THAN 1.0')
      ENDIF
      
      pm(34) = gamma
      pm(88) = psh
 
      mat_param%EOS%NUPARAM = 4
      mat_param%EOS%NIPARAM = 0
      mat_param%EOS%NFUNC = 0
      mat_param%EOS%NTABLE = 0
      CALL mat_param%EOS%CONSTRUCT() !allocations
 
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
      
      IF(mu0 <= -one)mu0=-one+ep12
    
      IF(gamma > one)THEN
        e0 = (p0-a*exp(b*log(one+mu0)))/(gamma-one)/(one+mu0)
      ELSE
        e0 = zero ! this error is managed above
      ENDIF
 
      pm(32) = (gamma-one)*abs(e0) + a*b !bulk modulus
      
      IF(e0 < zero)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,
     .               i1=imideos,
     .               c1='/EOS/LSZK',
     .               c2='PARAMETERS RESULTS INTO A NEGATIVE INITIAL ENERGY')      
      ENDIF
                
      pm(23) = e0
      pm(31) = p0-psh
      pm(104)= p0-psh
 
      mat_param%EOS%UPARAM(1) = gamma
      mat_param%EOS%UPARAM(2) = p0
      mat_param%EOS%UPARAM(3) = a
      mat_param%EOS%UPARAM(4) = b
      mat_param%EOS%PSH = psh
      mat_param%EOS%E0 = e0
      IF (mat_param%THERM%TINI == zero) THEN
        mat_param%THERM%TINI =three100
        pm(79) = three100
      END IF
 
      !SSP0
      ssp0 = zero 
      g0 = pm(22)
      pp = (gamma-one)*(one+mu0)*e0 + a*exp(b*log(one+mu0))
      rhoi = pm(89)      
      dpdmu = (gamma-one)*e0+a*b/(one+mu0)*exp((b-one)*log(one+mu0))+(gamma-one)*df*pp   !total derivative
      dpdmu = max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0
      
      WRITE(iout,1000)
 
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)gamma,p0,psh,a,b
        IF(is_available_rho0)WRITE(iout,1501)pm(1)
      ENDIF
 
      RETURN
 1000 FORMAT(
     & 5x,'  LANDAU-STANYUKOVICH-ZELDOVICH-KOMPANEETS EOS (LSZK)    ',/,
     & 5x,'  ---------------------------------------------------     ',/)
 1500 FORMAT(
     & 5x,'GAMMA . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'P0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'PSH . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'A . . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'b . . . . . . . . . . . . . . . . . . . .=',1pg20.13)
 1501 FORMAT(     
     & 5x,'EOS REFERENCE DENSITY . . . . . . . . . .=',1pg20.13) 
 
      RETURN