hm_read_eos_murnaghan.F File Reference

#include "implicit_f.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_eos_murnaghan (npropm, iout, pm, unitab, iunit, lsubmodel, imideos, mat_param)

Function/Subroutine Documentation

hm_read_eos_murnaghan()

subroutine hm_read_eos_murnaghan	(	integer	npropm,
		integer	iout,
			pm,
		type (unit_type_), intent(in)	unitab,
		integer	iunit,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel,
		integer, intent(in)	imideos,
		type(matparam_struct_), intent(inout)	mat_param )

Definition at line 35 of file hm_read_eos_murnaghan.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod
      USE matparam_def_mod, ONLY : matparam_struct_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   MURNAGHAN EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IOUT, IUNIT, NPROPM
      my_real pm(npropm)
      TYPE(SUBMODEL_DATA), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE(MATPARAM_STRUCT_),INTENT(INOUT) :: MAT_PARAM
      INTEGER,INTENT(IN) :: IMIDEOS
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real  p0, e0, psh, rho0, k0, k1, rhoi, rhor, mu0, df, ssp0, g0, dpdmu
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('EOS_K0', k0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('K1', k1, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_P0', p0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_PSH', psh, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Refer_Rho', rho0, is_available_rho0,lsubmodel,unitab)
 
      rhor = pm(1)
      rhoi = pm(89)
 
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
        mat_param%RHO = rho0
      ELSE
        rho0=rhor                   
      ENDIF
      
      e0=zero
      
      IF(k0 <= zero)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,i1=imideos, c1='/EOS/MURNAGHAN', c2='K0 MUST BE POSITIVE')
      ENDIF
      
      pm(32)=k0 !BULK = (1+µ)*dP/dmu (partial derivative at constant E)
      pm(88)=psh
      pm(23)=e0
 
      mat_param%EOS%NUPARAM = 3
      mat_param%EOS%NIPARAM = 0
      mat_param%EOS%NFUNC   = 0
      mat_param%EOS%NTABLE  = 0
      CALL mat_param%EOS%CONSTRUCT() !allocations
 
      mat_param%EOS%UPARAM(1) = k0
      mat_param%EOS%UPARAM(2) = p0
      mat_param%EOS%UPARAM(3) = k1
      mat_param%EOS%PSH = psh
      mat_param%EOS%E0 = e0
      IF (mat_param%THERM%TINI == zero) THEN
        mat_param%THERM%TINI =three100
        pm(79) = three100
      END IF
 
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
      
      !P0
      pm(31) =  k0/k1 * (exp(k1*log(1+mu0)) - one )  + p0 - psh
      pm(104)=  k0/k1 * (exp(k1*log(1+mu0)) - one )  + p0 - psh      
         
      !SSP0
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89)      
      dpdmu = k0*exp( k1*log(1+mu0) )/(one+mu0)  
      dpdmu = max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0
      WRITE(iout,1000)
 
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'confidential data'
      ELSE
        WRITE(IOUT,1500)K0,K1,P0,PM(31),PSH
        IF(IS_AVAILABLE_RHO0)WRITE(IOUT,1501)PM(1)
      ENDIF
 
      RETURN
 1000 FORMAT(
     & 5X,'  murnaghan eos     ',/,
     & 5X,'  -------------     ',/)
 1500 FORMAT(
     & 5X,'k0. . . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'k1. . . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'p0. . . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'initial pressure. . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'psh . . . . . . . . . . . . . . . . . . .=',1PG20.13)
 1501 FORMAT(     
     & 5X,'eos reference density . . . . . . . . . .=',1PG20.13) 
      
 
      RETURN