hm_read_eos_tillotson.F File Reference

#include "implicit_f.inc"
#include "param_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_eos_tillotson (iout, pm, unitab, iunit, lsubmodel, imideos, eos_tag, ieos, mat_param)

Function/Subroutine Documentation

hm_read_eos_tillotson()

subroutine hm_read_eos_tillotson	(	integer	iout,
			pm,
		type (unit_type_), intent(in)	unitab,
		integer	iunit,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel,
		integer, intent(in)	imideos,
		type(eos_tag_), dimension(0:maxeos), intent(inout)	eos_tag,
		integer, intent(in)	ieos,
		type(matparam_struct_), intent(inout)	mat_param )

Definition at line 35 of file hm_read_eos_tillotson.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod      
      USE elbuftag_mod
      USE matparam_def_mod, ONLY : matparam_struct_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   TILLOTSON EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IOUT,IUNIT
      INTEGER,INTENT(IN) :: IEOS
      my_real pm(npropm)
      TYPE(SUBMODEL_DATA), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      INTEGER,INTENT(IN) :: IMIDEOS
      TYPE(EOS_TAG_),DIMENSION(0:MAXEOS) ,INTENT(INOUT) :: EOS_TAG
      TYPE(MATPARAM_STRUCT_),INTENT(INOUT) :: MAT_PARAM
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real :: c1, c2, a, b, er, es, vs, e0, rho0,rhoi,rhor, alpha, beta,
     .           facc1,facc2,facpb,mu0,mu2,df,eta,
     .           omega,aa,bb,pp,xx,expa,expb,dpdmu, ssp0, g0, psh
      LOGICAL :: IS_ENCRYPTED,IS_AVAILABLE,IS_AVAILABLE_RHO0
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
      psh = zero
 
      eos_tag(ieos)%NVAR = 1  !saving Region id for H2D and ANIM output                         
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('EOS_C1', c1, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('EOS_C2', c2, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_A', a, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_B', b, is_available,lsubmodel,unitab)
 
      CALL hm_get_floatv('E_R',er, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('E_S', es, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Vs', vs, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_EA', e0 ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Refer_Rho', rho0 ,is_available_rho0,lsubmodel,unitab)
 
      CALL hm_get_floatv('Alpha', alpha ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Beta', beta ,is_available,lsubmodel,unitab)
 
      rhor = mat_param%RHO
      rhoi = mat_param%RHO0
      IF (rho0 > zero) THEN
        rhor = rho0
        mat_param%RHO = rho0
        pm(1)= rho0
      ELSE
        rho0=rhor                   
      ENDIF
 
      pm(23) = e0
      pm(32) = c1+b*e0   !BULK = (1+µ)*dP/dmu (partial derivative at constant E)
      pm(88) = psh
 
      mat_param%EOS%NUPARAM = 9
      mat_param%EOS%NIPARAM = 0
      mat_param%EOS%NFUNC   = 0
      mat_param%EOS%NTABLE  = 0
      CALL mat_param%EOS%CONSTRUCT() !allocations
 
      mat_param%EOS%UPARAM(1) = c1
      mat_param%EOS%UPARAM(2) = c2
      mat_param%EOS%UPARAM(3) = a
      mat_param%EOS%UPARAM(4) = b
      mat_param%EOS%UPARAM(5) = er
      mat_param%EOS%UPARAM(6) = es
      mat_param%EOS%UPARAM(7) = vs
      mat_param%EOS%UPARAM(8) = alpha
      mat_param%EOS%UPARAM(9) = beta
      mat_param%EOS%PSH       = psh
      mat_param%EOS%E0        = e0
!
      IF (mat_param%THERM%TINI == zero) THEN
        mat_param%THERM%TINI =three100
        pm(79) = three100
      END IF
 
      !COMPUTING INITIAL PRESSURE FOR PM(31) -> SIG(1:3,*)
      
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
 
      mu2   = mu0*mu0
      facc1 = one
      facc2 = one
      facpb = one
      IF(mu0<zero) THEN
        facc2=zero
        IF(df>vs .OR. (df<=vs .AND. e0>=es) ) THEN
         xx    = mu0/(one+mu0)
         expa  = exp(-alpha*xx*xx)
         expb  = exp(beta*xx)
         facc1 = expa*expb
         facpb = expa
        ENDIF
      ENDIF      
      eta   = one+mu0       
      omega = one+e0/(er*eta**2)
      aa    = facc1*c1*mu0+facc2*c2*mu2
      bb    = a+facpb*b/omega
      pp    = max(aa+bb*eta*e0,pm(37))
      pm(31)= pp
        
      !SSP0
      ssp0 = zero 
      g0   = pm(22)
      rhoi = pm(89)
      
      dpdmu=facc1*c1+two*facc2*c2*mu0+bb*eta*pp*df*df + e0*( bb+(two*e0/eta-pp*df*df)*b*facpb/(er*eta*omega**2) )
      dpdmu=max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0      
 
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)c1,c2,a,b,er,es,vs,e0,pm(31),alpha,beta
        IF(is_available_rho0)WRITE(iout,1501)pm(1)
      ENDIF
 
      RETURN
      
 1000 FORMAT(
     & 5x,'  tillotson eos     ',/,
     & 5X,'  --------------     ',/)
 1500 FORMAT(
     & 5X,'c1. . . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'c2. . . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'a . . . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'b . . . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'ref internal energy(per unit volume) . .=',1PG20.13/,
     & 5X,'sublimation energy(per unit volume) . .=',1PG20.13/,
     & 5X,'sublimation relative volume . . . . . . .=',1PG20.13/,
     & 5X,'initial internal energy(per unit volume).=',1PG20.13/,
     & 5X,'initial pressure. . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'alpha . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'beta. . . . . . . . . . . . . . . . . . .=',1PG20.13)
 1501 FORMAT(     
     & 5X,'eos reference density . . . . . . . . . .=',1PG20.13)     
 
      RETURN