hm_read_fail_tensstrain.F File Reference

#include "implicit_f.inc"
#include "units_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_fail_tensstrain (fail, mat_id, fail_id, irupt, lsubmodel, unitab, unit_id)

Function/Subroutine Documentation

hm_read_fail_tensstrain()

subroutine hm_read_fail_tensstrain	(	type (fail_param_), intent(inout)	fail,
		integer, intent(in)	mat_id,
		integer, intent(in)	fail_id,
		integer, intent(in)	irupt,
		type (submodel_data), dimension(*), intent(in)	lsubmodel,
		type (unit_type_), intent(in)	unitab,
		integer, intent(in)	unit_id )

Definition at line 38 of file hm_read_fail_tensstrain.F.

C-----------------------------------------------
c    ROUTINE DESCRIPTION :
c    Read tensile strain failure model parameters
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE fail_param_mod
      USE unitab_mod
      USE message_mod 
      USE submodel_mod
      USE hm_option_read_mod 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER             ,INTENT(IN) :: FAIL_ID       ! failure model ID
      INTEGER             ,INTENT(IN) :: MAT_ID        ! material law ID
      INTEGER             ,INTENT(IN) :: UNIT_ID       ! 
      INTEGER             ,INTENT(IN) :: IRUPT         ! failure model number
      TYPE (UNIT_TYPE_)   ,INTENT(IN) :: UNITAB        ! table of input units
      TYPE (SUBMODEL_DATA),INTENT(IN) :: LSUBMODEL(*)  ! submodel table
      TYPE (FAIL_PARAM_)  ,INTENT(INOUT) :: FAIL       ! failure model data structure
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER    ::  ISHELL,ISOLID,IRFUN,FUNC_ID,FUNC_ID2,S_FLAG,STRDEF,FAILIP
      my_real    ::  rf1,rf2,epsp1,epsp2,scale_el,pthkf,
     .               el_ref,scale_temp,fscal_unit,unit_t
      LOGICAL    ::  IS_AVAILABLE,IS_ENCRYPTED
C=======================================================================
      is_encrypted = .false.
      is_available = .false.
C--------------------------------------------------
C
      CALL hm_option_is_encrypted(is_encrypted)
C
C--------------------------------------------------
      scale_el  = zero
      scale_temp= zero
      el_ref    = zero
      func_id   = 0
      func_id2  = 0
      IF (unit_id > 0) THEN
        unit_t = unitab%FAC_T(unit_id) ! USED FOR ABSCISSA OF IRFUN
      ELSE
        unit_t = one
      ENDIF
C--------------------------------------------------
C EXTRACT DATAS (REAL VALUES)
C--------------------------------------------------
      CALL hm_get_floatv         ('Epsilon_t1',rf1   ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv         ('Epsilon_t2',rf2   ,is_available,lsubmodel,unitab)
      CALL hm_get_intv           ('fct_ID'    ,irfun ,is_available,lsubmodel)
      CALL hm_get_floatv         ('Epsilon_f1',epsp1 ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv         ('Epsilon_f2',epsp2 ,is_available,lsubmodel,unitab)
      CALL hm_get_intv           ('S_Flag'    ,s_flag,is_available,lsubmodel) 
      CALL hm_get_intv           ('FAILIP'       ,failip  ,is_available,lsubmodel) 
      IF (failip == 0)  failip  = 1
c
      IF (s_flag == 2  .or. s_flag == 3 .or. s_flag == 12 .or. s_flag == 13 .or. 
     .    s_flag == 22 .or. s_flag == 23) THEN
        CALL hm_get_intv           ('fct_IDel' ,func_id ,is_available,lsubmodel)
        CALL hm_get_floatv         ('Fscale_el',scale_el,is_available,lsubmodel,unitab)
        CALL hm_get_floatv         ('EI_ref'   ,el_ref  ,is_available,lsubmodel,unitab)
c
        CALL hm_get_intv           ('fct_IDt' ,func_id2 ,is_available,lsubmodel)
        CALL hm_get_floatv         ('FscaleT',scale_temp,is_available,lsubmodel,unitab)
c
        !units 
        CALL hm_get_floatv_dim('Fscale_el',fscal_unit    ,is_available, lsubmodel, unitab)
        IF (scale_el == zero) scale_el = one*fscal_unit
c
        CALL hm_get_floatv_dim('EI_ref',fscal_unit    ,is_available, lsubmodel, unitab)
        IF (el_ref == zero) el_ref = one *fscal_unit           
      ENDIF
c--------------------------------------------------
      IF (s_flag == 0) s_flag = 1
      IF (s_flag == 11 .or. s_flag == 12 .or. s_flag == 13) THEN
        s_flag = s_flag - 10
        strdef = 2  ! input = engineering strain
      ELSEIF (s_flag == 21 .or. s_flag == 22 .or. s_flag == 23) THEN
        s_flag = s_flag - 20
        strdef = 3  ! input = true strain
      ELSE
        strdef = 1  ! input = strain defined by Ismstr flag in the property
      END IF
c        
      IF (scale_temp == zero) scale_temp = one
      IF (scale_el   == zero) scale_el = one
      IF (el_ref     == zero) el_ref = one
      IF (rf1 <= zero) rf1 = ep20
      IF (rf2 <= zero) rf2 = two*ep20
C
      IF (rf1 > rf2) THEN
        CALL ancmsg(msgid=617, msgtype=msgerror, anmode=aninfo_blind_1,
     .              i1=mat_id)
      ENDIF     
      pthkf = em06      ! % of thickness to fail <=> 1 integration point
c---------------------------
      fail%KEYWORD = 'TENS_STRAIN' 
      fail%IRUPT   = irupt 
      fail%FAIL_ID = fail_id 
      fail%NUPARAM = 11
      fail%NIPARAM = 0
      fail%NUVAR   = 2
      fail%NFUNC   = 3
      fail%NTABLE  = 0
      fail%NMOD    = 0
      fail%PTHK    = pthkf
c            
      ALLOCATE (fail%UPARAM(fail%NUPARAM))
      ALLOCATE (fail%IPARAM(fail%NIPARAM))
      ALLOCATE (fail%IFUNC (fail%NFUNC))
      ALLOCATE (fail%TABLE (fail%NTABLE))
c-----------------------
      fail%UPARAM(1) = rf1 
      fail%UPARAM(2) = rf2
      fail%UPARAM(3) = epsp1
      fail%UPARAM(4) = epsp2
      fail%UPARAM(5) = scale_el
      fail%UPARAM(6) = el_ref    
      fail%UPARAM(7) = scale_temp
      fail%UPARAM(8) = s_flag
      fail%UPARAM(9) = unit_t
      fail%UPARAM(10)= strdef
      fail%UPARAM(11)= failip
c       
      fail%IFUNC(1)  = irfun
      fail%IFUNC(2)  = func_id
      fail%IFUNC(3)  = func_id2
C--------------------------------------------------
      IF(is_encrypted)THEN
        WRITE(iout, 1000)
      ELSE
        WRITE(iout, 1100) rf1,rf2,irfun,strdef,failip
        IF (epsp1 > zero .OR. epsp2 > zero) THEN
          WRITE(iout, 2000)epsp1,epsp2
        ENDIF
        IF (s_flag == 2) WRITE(iout, 2900)
        IF (s_flag == 3) WRITE(iout, 2950)
        WRITE(iout, 3000) func_id,scale_el,el_ref,func_id2,scale_temp
        IF (fail_id > zero) THEN
          WRITE(iout, 4000) fail_id
        ENDIF
      ENDIF
      RETURN
C-------------------------------------------------- 
 1000 FORMAT(
     & 5x,40h    crypted DATA in failure model             /,
     & 5x,40h    -----------------------------             /)
 1100 FORMAT(
     & 5x,40h    tension strain failure model               /,
     & 5x,40h    ------------------------                  /,
     & 5x,'MAXIMUM TENSION STRAIN 1. . . . . . . . . . . . . . . . =',e12.4/
     & 5x,'MAXIMUM TENSION STRAIN 2. . . . . . . . . . . . . . . . =',e12.4/
     & 5x,'MAXIMUM STRAINS SCALING FUNCTION. . . . . . . . . . . . =',i10/
     & 5x,'FAILURE STRAIN INPUT TYPE . . . . . . . . . . . . . . . =',i10/
     & 5x,'                 =1 (STRAIN MEASURE DEFINED IN PROPERTY) ',/
     & 5x,'                 =2 (ENGINEERING STRAIN) . . . . . . . . ',/
     & 5x,'                 =3 (TRUE STRAIN). . . . . . . . . . . . ',/
     & 5x,'NUMBER OF FAILED INTG. POINTS PRIOR TO ELEM DELETION  .=',i10/)
 2000 FORMAT(
     & 5x,'MAXIMUM FIRST PRINCIPAL STRAIN FOR ELEMENT DELETION . . =',e12.4/ 
     & 5x,'MAXIMUM SECOND PRINCIPAL STRAIN FOR ELEMENT DELETION. . =',e12.4/)
 2900 FORMAT(
     & 5x,'EQUIVALENT STRAIN METHOD USED '/)
 2950 FORMAT(
     & 5x,'FIRST PRINCIPAL STRAIN METHOD USED '/)
 3000 FORMAT(
     & 5x,'ELEMENT LENGTH REGULARIZATION USED:     ',/
     & 5x,'REGULARIZATION FUNCTION . . . . . . . . . . . . . . . . =',i10/ 
     & 5x,'EL SCALING FACTOR . . . . . . . . . . . . . . . . . . . =',e12.4/
     & 5x,'REFERENCE ELEMENT LENGTH. . . . . . . . . . . . . . . . =',e12.4/
     & 5x,'TEMPERATURE FUNCTION. . . . . . . . . . . . . . . . . . =',i10/ 
     & 5x,'TEMP SCALING FACTOR . . . . . . . . . . . . . . . . . . =',e12.4/)
 4000 FORMAT(
     & 5x,'FAIL_ID . . . . . . . . . . . . . . . . . . . . . . . . =',i10/)