hm_read_mat190.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat190           ../starter/source/materials/mat/mat190/hm_read_mat190.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat              ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_floatv_dim        ../starter/source/devtools/hm_reader/hm_get_floatv_dim.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    init_mat_keyword         ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||    table_mod                ../starter/share/modules1/table_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat190(
     .           NUVAR    ,NUMTABL  ,MAXTABL  ,ITABLE   ,PARMAT   ,UNITAB   ,    
     .           PM       ,LSUBMODEL,MAT_ID   ,TITR     ,MATPARAM ,NVARTMP  ,
     .           IMATVIS  ) 
C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   FOAM_DUBOIS path dependent foam material 
C   isotropic material law for foam
C-------------------------------------------------------------------------
C-------------------------------------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME            DESCRIPTION                         
C-----------------------------------------------
C     IPM             MATERIAL ARRAY(INTEGER)
C     PM              MATERIAL ARRAY(REAL)
C     UNITAB          UNITS ARRAY
C     ID              MATERIAL ID(INTEGER)
C     TITR            MATERIAL TITLE
C     LSUBMODEL       SUBMODEL STRUCTURE
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE elbuftag_mod
      USE message_mod
      USE submodel_mod
      USE matparam_def_mod          
      USE table_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "units_c.inc"
#include      "com04_c.inc"
C----------------------------------------------- 
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (unit_type_),INTENT(IN)                  :: unitab 
      INTEGER, INTENT(IN)                           :: MAT_ID,MAXTABL
      my_real, DIMENSION(NPROPM) ,INTENT(INOUT)     :: PM     
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN)         :: TITR
      INTEGER, INTENT(INOUT)                        :: NUVAR,NUMTABL,NVARTMP,IMATVIS
      INTEGER, DIMENSION(MAXTABL) ,INTENT(INOUT)    :: ITABLE
      my_real, DIMENSION(100),INTENT(INOUT)         :: parmat
      TYPE(submodel_data), DIMENSION(*),INTENT(IN)  :: LSUBMODEL
      TYPE (MATPARAM_STRUCT_) ,INTENT(INOUT)        :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      LOGICAL :: IS_AVAILABLE,IS_ENCRYPTED
      INTEGER :: ILAW
      my_real :: RHO0,NU,BULK,E,EMOD,G,A11,HU, SHAPE,
     .    scale_1_unit,xscale_1_unit,xfac(2)
C=======================================================================
      ilaw = 190
      is_encrypted   = .false.
      is_available   = .false.
      imatvis = 2
c
      CALL hm_option_is_encrypted(is_encrypted)
card1
      ! Initial density
      CALL hm_get_floatv('MAT_RHO'   ,rho0    ,is_available, lsubmodel, unitab)
card2 
      ! Initial young modulus
      CALL hm_get_floatv('MAT_E'     ,emod    ,is_available, lsubmodel, unitab)
      nu = zero
card3
      ! Unloading parameters
      CALL hm_get_floatv('MAT_HU'    ,hu      ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_SHAPE' ,shape   ,is_available, lsubmodel, unitab)
card4
      ! Loading table
      CALL hm_get_intv  ('FUN_1'     ,itable(1),is_available, lsubmodel)
      CALL hm_get_floatv('XSCALE_1'  ,xfac(1)  ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('SCALE_1'   ,xfac(2)  ,is_available, lsubmodel, unitab)
c
      ! Check scale factor units
      CALL hm_get_floatv_dim('XSCALE_1' ,xscale_1_unit  ,is_available, lsubmodel, unitab)
      IF (xfac(1) == zero) xfac(1) = one * xscale_1_unit
      CALL hm_get_floatv_dim('SCALE_1'  ,scale_1_unit   ,is_available, lsubmodel, unitab)
      IF (xfac(2) == zero) xfac(2) = one * scale_1_unit      
c
      ! Check default value and compute elastic parameters
      e    = emod
      g    = emod / two / (one+nu)
      bulk = emod / three / (one-two * nu)      
      a11  = emod * (one - nu) / (one + nu) / (one-two * nu)
      IF (hu == zero) hu = one                    
c
!--------------------------
!     Filling buffer tables
!-------------------------- 
      nuvar   = 13         ! Number of User Element Variables and Curves
      numtabl = 2          ! Number of tables
      nvartmp = 18         ! Number of temporary variables
      matparam%NUPARAM = 7 ! Number of real parameters
c
      ! Allocate and fill real parameters table
      ALLOCATE(matparam%UPARAM(matparam%NUPARAM))
      matparam%UPARAM(1) = emod
      matparam%UPARAM(2) = bulk
      matparam%UPARAM(3) = g
      matparam%UPARAM(4) = xfac(1)
      matparam%UPARAM(5) = xfac(2)
      matparam%UPARAM(6) = hu
      matparam%UPARAM(7) = shape
c
      ! PM table
      pm(1)  = rho0
      pm(89) = rho0
c
      ! PARMAT table
      parmat(1)  = bulk
      parmat(2)  = e
      parmat(3)  = nu
      parmat(16) = 2
      parmat(17) = (one - two*nu)/(one - nu)
c
      ! Material settings
      CALL init_mat_keyword(matparam,"TOTAL")
      CALL init_mat_keyword(matparam,"COMPRESSIBLE")
c
      ! Properties compatibility
      CALL init_mat_keyword(matparam,"SOLID_ISOTROPIC")
c
!--------------------------
!     Parameters printout
!--------------------------
      WRITE(iout,900) trim(titr),mat_id,ilaw
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1050) rho0
        WRITE(iout,1110) e,bulk,g
        WRITE(iout,1150) hu,shape
        WRITE(iout,1200) itable(1),xfac(1),xfac(2)
      ENDIF
 900  FORMAT(/
     & 5x,a,/,
     & 5x,'MATERIAL NUMBER . . . . . . . . . . . . . . . =',i10/,
     & 5x,'MATERIAL LAW. . . . . . . . . . . . . . . . . =',i10/)
 1000 FORMAT(/                                                        
     & 5x,'-----------------------------------------------',/          
     & 5x,' MATERIAL MODEL: ISOTROPIC PATH DEPENDENT FOAM ',/,      
     & 5x,'-----------------------------------------------',/)
 1050 FORMAT(/
     & 5x,'INITIAL DENSITY. . . . . . . . . . . . . . . .=',1pg20.13/)  
 1110 FORMAT(/
     & 5x,'INITIAL YOUNG MODULUS E. . . . . . . . . . . .=',1pg20.13/ 
     & 5x,'INITIAL BULK MODULUS K . . . . . . . . . . . .=',1pg20.13/ 
     & 5x,'INITIAL SHEAR MODULUS G. . . . . . . . . . . .=',1pg20.13/)
 1150 FORMAT(/
     & 5x,'HYSTERETIC UNLOADING FACTOR HU . . . . . . . .=',1pg20.13/ 
     & 5x,'SHAPE FACTOR FOR UNLOADING . . . . . . . . . .=',1pg20.13/)
 1200 FORMAT(/
     & 5x,'LOADING TABLE IDENTIFIER . . . . . . . . . . .=',i10/ 
     & 5x,'REFERENCE STRAIN RATE (SCALE FACTOR) . . . . .=',1pg20.13/
     & 5x,'LOADING STRESS SCALE FACTOR. . . . . . . . . .=',1pg20.13/)
c
      END