hm_read_table1_0.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_table1_0           ../starter/source/tools/curve/hm_read_table1_0.F
!||--- called by ------------------------------------------------------
!||    hm_read_table1             ../starter/source/tools/curve/hm_read_table.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                     ../starter/source/output/message/message.F
!||    hm_get_float_array_index   ../starter/source/devtools/hm_reader/hm_get_float_array_index.F
!||    hm_get_intv                ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted     ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    hm_option_read_key         ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start            ../starter/source/devtools/hm_reader/hm_option_start.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod         ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod                ../starter/share/message_module/message_mod.F
!||    submodel_mod               ../starter/share/modules1/submodel_mod.F
!||    table_mod                  ../starter/share/modules1/table_mod.F
!||====================================================================
      SUBROUTINE hm_read_table1_0(NTABLE0, NTABLE, TABLE ,NFUNCT, 
     .                            NPC ,PLD, L,
     .                            NOM_OPT,UNITAB, LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE table_mod
      USE message_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE unitab_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharfield
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER L,NTABLE,NTABLE0,NFUNCT,NPC(*)
      my_real  PLD(*)
      TYPE(ttable) TABLE(*)
      INTEGER NOM_OPT(LNOPT1,*)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE (UNIT_TYPE_), INTENT(IN)                       :: UNITAB
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr17_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, K, N,  NDIM, NX(4), NY, NPTS, STAT, LL
      CHARACTER(LEN=NCHARTITLE) :: TITR
      CHARACTER MESS*40
      DATA mess/' FUNCTION & TABLE DEFINITION            '/
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE
C======================================================================|
      is_encrypted = .false.
      is_available = .false.
 
      CALL hm_option_start('/TABLE/0')
      DO i=1,ntable0 
       CALL hm_option_read_key(lsubmodel, 
     .                         option_titr = titr, 
     .                         option_id = ll) 
       CALL hm_option_is_encrypted(is_encrypted)
C-----------------------------------------------
       nx(1) = 0
       nx(2) = 0
       nx(3) = 0
       nx(4) = 0
       CALL hm_get_intv('ORDER', ndim, is_available, lsubmodel)
       IF(ndim/=1.AND.ndim/=2.AND.ndim/=3.AND.ndim/=4)THEN
         CALL ancmsg(msgid=777,
     .               msgtype=msgerror,
     .               anmode=aninfo_blind_1,
     .               i1=ll,
     .               c1=titr)
       END IF
       IF(ndim > 0)CALL hm_get_intv('N1', nx(1), is_available, lsubmodel) 
       IF(ndim==1)THEN
          l=l+1
          npts=nx(1)
          npc(nfunct+l+1)=ll                                       
          npc(l+1)=npc(l)                                          
c read abscissa values      
          DO n = 1, npts
            CALL hm_get_float_array_index('temparray2d_N1',pld(npc(l)+ 2*n-2),n,is_available, lsubmodel, unitab)
          END DO
c read ordinate values          
          DO n = 1, npts
              CALL hm_get_float_array_index('ENG_FUNCT_yValues',pld(npc(l)+2*n-1),n,is_available,lsubmodel,unitab)
          END DO
          npc(l+1)=npc(l)+2*npts
C         build table structure
          table(l)%NOTABLE=ll
          table(l)%NDIM =1
 
          ALLOCATE(table(l)%X(1),stat=stat)
          IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,
     .                               msgtype=msgerror,
     .                         c1='TABLE')
          ALLOCATE(table(l)%X(1)%VALUES(npts),stat=stat)
          IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,
     .                               msgtype=msgerror,
     .                         c1='TABLE')
 
          ALLOCATE(table(l)%Y,stat=stat)
          IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,
     .                               msgtype=msgerror,
     .                         c1='TABLE')
          ALLOCATE(table(l)%Y%VALUES(npts),stat=stat)
          IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,
     .                               msgtype=msgerror,
     .                         c1='TABLE')
 
          DO n=1,npts
            table(l)%X(1)%VALUES(n)=pld(npc(l)+2*n-2)
            table(l)%Y%VALUES(n)   =pld(npc(l)+2*n-1)
          END DO
C
          IF (is_encrypted)THEN                                     
             WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'     
          ELSE     
            WRITE(iout,2100) table(l)%NOTABLE, table(l)%NDIM
            DO k=1,table(l)%NDIM
              nx(k)=SIZE( table(l)%X(k)%VALUES )
              WRITE(iout,2200) k
              WRITE(iout,2250) (table(l)%X(k)%VALUES(n),n=1,nx(k))
            END DO
            ny=SIZE(table(l)%Y%VALUES)
            WRITE(iout,2300)
            WRITE(iout,2350) (table(l)%Y%VALUES(n),n=1,ny)
           END if!(IS_ENCRYPTED > 0) 
          endif!(NDIM==1)
       ENDDO !I=1,NTABLE0 
      RETURN
C-----------------------------------------------------------------
2100  FORMAT(/'    TABLE ID . . . . . . . . . . . . . . =',i10/
     .        '    NUMBER OF PARAMETERS . . . . . . . . =',i10/)
2200  FORMAT(/'    VALUES FOR PARAMETER NUMBER. . . . . .',i4,':'/)
2250  FORMAT((3x,5(1x,g20.13))/)
2300  FORMAT(/'    ORDINATE VALUES . . . . . . . . . . . :'/)
2350  FORMAT((3x,5(1x,g20.13))/)
      END