hm_read_visc.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_visc            ../starter/source/materials/visc/hm_read_visc.F
!||--- called by ------------------------------------------------------
!||    read_material_models    ../starter/source/materials/read_material_models.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                  ../starter/source/output/message/message.F
!||    hm_option_count         ../starter/source/devtools/hm_reader/hm_option_count.F
!||    hm_option_read_key      ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start         ../starter/source/devtools/hm_reader/hm_option_start.F
!||    hm_read_visc_lprony     ../starter/source/materials/visc/hm_read_visc_lprony.F
!||    hm_read_visc_plas       ../starter/source/materials/visc/hm_read_visc_plas.F90
!||    hm_read_visc_prony      ../starter/source/materials/visc/hm_read_visc_prony.F
!||    init_mat_keyword        ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod            ../starter/share/modules1/elbuftag_mod.F
!||    hm_option_read_mod      ../starter/share/modules1/hm_option_read_mod.F
!||    hm_read_visc_plas_mod   ../starter/source/materials/visc/hm_read_visc_plas.F90
!||    message_mod             ../starter/share/message_module/message_mod.F
!||    submodel_mod            ../starter/share/modules1/submodel_mod.F
!||    table_mod               ../starter/share/modules1/table_mod.F
!||====================================================================
      SUBROUTINE hm_read_visc(MAT_PARAM   ,IPM        ,BUFMAT      ,
     .                        UNITAB      ,LSUBMODEL  ,TABLE       )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE elbuftag_mod            
      USE matparam_def_mod
      USE message_mod           
      USE submodel_mod
      USE hm_option_read_mod
      USE table_mod
      USE names_and_titles_mod , ONLY : ncharkey
      USE hm_read_visc_plas_mod
C============================================================================
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "units_c.inc"
#include      "tablen_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER ,DIMENSION(NPROPMI,NUMMAT)    ,INTENT(INOUT) :: IPM
      my_real ,DIMENSION(*)                 ,INTENT(INOUT) :: bufmat
      TYPE(submodel_data) ,DIMENSION(*)     ,INTENT(IN)    :: LSUBMODEL
      TYPE(ttable) TABLE(NTABLE)
      TYPE(matparam_struct_) ,DIMENSION(NUMMAT) ,INTENT(INOUT) :: MAT_PARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,NV,IMAT,MAT_ID,IMID,ILAW,IVISC,UID,IUNIT,FLAGUNIT,
     .   n_net,iadd,hm_nvisc,flagmat,imatvis
      CHARACTER(LEN=NCHARKEY)::KEY
c======================================================================-       
c     COUNT VISCOSITY MODELS USING CFG FILES
c--------------------------------------------------
c      
      CALL hm_option_count('/VISC',hm_nvisc)
c
c--------------------------------------------------
c     START BROWSING VISCOSITY MODELS
c--------------------------------------------------
c
      CALL hm_option_start('/VISC')
c
c--------------------------------------------------
c
      DO nv = 1,hm_nvisc
c
        CALL hm_option_read_key(lsubmodel,
     .                          option_id   = mat_id ,
     .                          unit_id     = uid    ,
     .                          keyword2    = key    )
c
c--------------------------------------------------
c       Check MAT_Id
c--------------------------------------------------
        flagmat = 0
        DO imat=1,nummat-1
          imid = ipm(1,imat)
          IF (imid == mat_id) THEN
            flagmat = 1
            EXIT
          ENDIF
        ENDDO
        IF (mat_id > 0 .AND. flagmat == 0) THEN
          CALL ancmsg(msgid=1663,anmode=aninfo,msgtype=msgerror,
     .                i1= mat_id,
     .                c1='VISCOSITY',
     .                c2= key,
     .                c3='')                              
        ENDIF
c--------------------------------------------------
c       Check Unit_ID
c--------------------------------------------------
        flagunit = 0
        DO iunit=1,unitab%NUNITS
          IF (unitab%UNIT_ID(iunit) == uid) THEN
            flagunit = 1
            EXIT
          ENDIF
        ENDDO
        IF (uid > 0 .AND. flagunit == 0) THEN
          CALL ancmsg(msgid=659,anmode=aninfo,msgtype=msgerror,
     .                i1= mat_id,
     .                i2= uid,
     .                c1='MATERIAL',
     .                c2='VISCOSITY MODEL',
     .                c3='')                              
        ENDIF
c--------------------------------------------------
c       Read Viscosity models
c--------------------------------------------   
        DO i=1,nummat-1
          imid  = ipm(1,i)
          ilaw  = ipm(2,i)
          IF (imid == mat_id) THEN
            WRITE(iout,1000) trim(key),mat_id
c
            imatvis = ipm(216,i)
            CALL init_mat_keyword(mat_param(imat),"VISC") ! flag compatibility
c--------------------------------------------      
            IF (key(1:5) == 'PRONY')THEN 
c           -----------------------------------   
              ivisc = 1 
              CALL hm_read_visc_prony(
     .             mat_param(imat)%VISC,ivisc ,
     .             ntable   ,table    ,mat_id   ,unitab  ,lsubmodel)
 
              IF (imatvis > 0) THEN
                imatvis = 3
              ELSE
                imatvis = 1
              END IF
c           -----------------------------------   
            ELSE IF (key(1:6) == 'LPRONY') THEN 
c           -----------------------------------   
              ivisc = 2
              CALL hm_read_visc_lprony(
     .             mat_param(imat)%VISC,ivisc ,mat_id   ,unitab  ,lsubmodel)
c              
            ELSE IF (key(1:6) == 'PLAS') THEN 
c           -----------------------------------   
              ivisc = 3
              CALL hm_read_visc_plas(
     .             mat_param(imat)%VISC,ivisc  ,iout, unitab  ,lsubmodel)
            END IF  ! visc model
c-------------------------
            mat_param(imat)%IVISC = ivisc
c
            IF (ivisc == 1 .AND. ilaw == 100) THEN
              iadd = ipm(7,i)  ! number of networks in law 100
              n_net = nint(bufmat(iadd) )
              IF (n_net /= 0) CALL ancmsg(msgid=1568 ,msgtype=msgerror,  
     .                                    anmode=aninfo_blind_2, i1=imid    )
            ENDIF
c-----------------------------
c           duplicate storage for compatibility with old code and output until cleaning
c-----------------------------
            ipm(216 ,i) = imatvis  ! hourglass treatment flag specific for viscoelastic maaterials
!            IPM(222 ,I) = IVISC
!            ipm(225 ,i) = mat_param(imat)%VISC%NUVAR
c--------------------------------------------------
          ENDIF   !IMID == MAT_ID
c--------------------------------------------------
        END DO ! NUMMAT
c--------------------------------------------------
c
      ENDDO      !  HM_NVISC
c-----------       
      RETURN
c--------------------------------------------------
 1000 FORMAT(//
     & 5x,'VISCOSITY MODEL: ',5x,a,/,
     & 5x,'MATERIAL ID  . . . . . . . . . . . .=',i10/)
c-----------       
      END