i25sors.F File Reference

#include "implicit_f.inc"
#include "param_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	i25sors (nsn, nrts, itab, ilev, ipari, intbuf_tab)

Function/Subroutine Documentation

i25sors()

subroutine i25sors	(	integer	nsn,
		integer	nrts,
		integer, dimension(*)	itab,
		integer	ilev,
		integer, dimension(npari)	ipari,
		type(intbuf_struct_)	intbuf_tab )

Definition at line 32 of file i25sors.F.

C
      USE message_mod
      USE intbufdef_mod 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NSN, NRTS, ITAB(*), ILEV, IPARI(NPARI)
      TYPE(INTBUF_STRUCT_) INTBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER J, N, M, K, NISUB, NISUBS
      INTEGER IERROR,WORK(70000)
      INTEGER, DIMENSION(:),ALLOCATABLE :: ITRI, INDEX, LISUBS, INFLG_SUBS, ADDSUBS
      INTEGER, DIMENSION(:,:),ALLOCATABLE :: ISAV
C-----------------------------------------------
      ALLOCATE (itri(nsn),isav(3,nsn),index(2*nsn),stat=ierror)
      IF (ierror /= 0) 
     .  CALL ancmsg(msgid=268,anmode=aninfo,
     .                     msgtype=msgerror,
     .               c1='SORTING SECONDARY NODES IN INTERFACE TYPE25')
C--------------------------------------------------------------
C     Tri nds SECONDARYs vs ID
C--------------------------------------------------------------
C
       DO n=1,nsn
         itri(n)  =itab(intbuf_tab%NSV(n))
         isav(1,n)=intbuf_tab%NSV(n)
         IF(ilev==2) isav(2,n)=intbuf_tab%NBINFLG(n)
       END DO
C
       nisub = ipari(36)
       nisubs =ipari(37)
       IF(nisub > 0)THEN
         ALLOCATE (lisubs(nisubs),inflg_subs(nisubs),addsubs(nsn+1),stat=ierror)
         IF (ierror /= 0) 
     .     CALL ancmsg(msgid=268,anmode=aninfo,
     .                     msgtype=msgerror,
     .                     c1='SORTING SECONDARY NODES IN INTERFACE TYPE25')
         addsubs(1:nsn+1)    =intbuf_tab%ADDSUBS(1:nsn+1)
         lisubs(1:nisubs)    =intbuf_tab%LISUBS(1:nisubs)
         inflg_subs(1:nisubs)=intbuf_tab%INFLG_SUBS(1:nisubs)
       END IF
C
       CALL my_orders(0,work,itri,index,nsn,1)
C
       DO n=1,nsn
         intbuf_tab%NSV(n)    =isav(1,index(n))
         IF(ilev==2) intbuf_tab%NBINFLG(n)=isav(2,index(n))
       END DO
C
       IF(nisub > 0)THEN
         intbuf_tab%ADDSUBS(1)=1         
         DO n=1,nsn
           m=index(n)
           intbuf_tab%ADDSUBS(n+1)= intbuf_tab%ADDSUBS(n)
     .                            + addsubs(m+1) - addsubs(m)
           DO k=addsubs(m),addsubs(m+1)-1
             intbuf_tab%LISUBS(intbuf_tab%ADDSUBS(n)+k-addsubs(m))    =lisubs(k)
             intbuf_tab%INFLG_SUBS(intbuf_tab%ADDSUBS(n)+k-addsubs(m))=inflg_subs(k)
           END DO
         END DO
       END IF
C
       DO n=1,nrts
         DO j=1,4
           m = intbuf_tab%IRECTS(4*(n-1)+j)
           IF(m/=0) intbuf_tab%IRECTS(4*(n-1)+j)=isav(1,index(m))
         END DO
       END DO
C
      DEALLOCATE (itri,isav,index)
      IF(nisub > 0)DEALLOCATE (lisubs,inflg_subs,addsubs)
C--------------------------------------------------------------
      RETURN