ingrbric_nodes.F File Reference

#include "implicit_f.inc"
#include "units_c.inc"
#include "com04_c.inc"
#include "param_c.inc"
#include "scr03_c.inc"
#include "tabsiz_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	ingrbric_nodes (msn, ibufssg, itab, msv, ixs, nbric, nale, ipm, bufmat, s_msv)

Function/Subroutine Documentation

ingrbric_nodes()

subroutine ingrbric_nodes	(	integer, intent(inout)	msn,
		integer, dimension(nbric), intent(in)	ibufssg,
		integer, dimension(numnod), intent(in)	itab,
		integer, dimension(1:s_msv), intent(inout)	msv,
		integer, dimension(nixs,numels), intent(in)	ixs,
		integer, intent(in)	nbric,
		integer, dimension(numnod), intent(in)	nale,
		integer, dimension(npropmi,nummat), intent(in)	ipm,
		dimension(sbufmat), target	bufmat,
		integer, intent(in)	s_msv )

Definition at line 35 of file ingrbric_nodes.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
        USE ale_mod
        USE format_mod , ONLY : fmw_10i
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "scr03_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN)    :: NBRIC,S_MSV
      INTEGER,INTENT(INOUT) :: MSN
      INTEGER,INTENT(IN)    :: IBUFSSG(NBRIC), ITAB(NUMNOD), IXS(NIXS,NUMELS)
      INTEGER,INTENT(INOUT) :: MSV(1:S_MSV)
      INTEGER,INTENT(IN) :: NALE(NUMNOD)
      INTEGER,INTENT(IN) :: IPM(NPROPMI,NUMMAT)
      my_real,INTENT(IN),TARGET :: bufmat(sbufmat)
C-----------------------------------------------
C   L o c a l   V a r a i b l e s
C-----------------------------------------------
      INTEGER :: I, J, TMP, INOD
      INTEGER, DIMENSION(:),ALLOCATABLE,TARGET :: MSVTMP
      my_real, DIMENSION(:), POINTER :: uparam
      INTEGER NPAR, IADBUF, IFORM, IMAT, IELEM, ILAW
      LOGICAL IS_ELEM_A_BOUNDARY_MAT
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      ALLOCATE(msvtmp(1:numnod))
      msvtmp(1:numnod)=0
 
      !TAG NODES - remove lagrangian nodes
      DO i=1,nbric
        ielem = ibufssg(i)
        DO j=2,9
          inod = ixs(j,ielem)
          IF(nale(inod)/=0 .AND. inod>0)msvtmp(inod)=1   !NALE(node_i)==0 <=> lagrangian node_i
        ENDDO      
      ENDDO
      !TAG NODES - remove nodes from boundary materials (law11, & law51 iform=2,3,4,5,6)
      ! (do not loop unnecessarily otherwise)
      IF(ale%GLOBAL%IS_BOUNDARY_MATERIAL)THEN
        DO i=1,nbric
          ielem = ibufssg(i)
          is_elem_a_boundary_mat = .false.
          imat = ixs(1,ielem)
          ilaw = ipm(2,imat)
          iform = 0
          IF(ilaw == 51)THEN
            npar   = ipm(9,imat)                
            iadbuf = ipm(7,imat)                
            iadbuf = max(1,iadbuf)                
            uparam => bufmat(iadbuf:iadbuf+npar)  
            iform  = nint(uparam(31))
            IF(iform>=2 .AND. iform<=6)is_elem_a_boundary_mat=.true.
          ELSEIF(ilaw == 11)THEN
            is_elem_a_boundary_mat=.true.
          ENDIF
          IF(is_elem_a_boundary_mat)THEN
            DO j=2,9
              inod = ixs(j,ielem)
              msvtmp(inod)=0
            ENDDO
          ENDIF
        END DO
      ENDIF
 
      !ORDERING
      tmp=0
      DO i=1,numnod
        IF(msvtmp(i)==1)THEN
          msvtmp(tmp+1)=i
          tmp=tmp+1
        ENDIF     
      END DO      
      msn = tmp ! size of ordered list
      
      DO i=1,s_msv
        msv(i)=msvtmp(i)
      ENDDO   
      DEALLOCATE(msvtmp)
 
      !PRINTOUT
      IF(ipri >= 1) THEN
        WRITE(iout,'(/,A,/)')' NODES EXTRACTED FROM SOLID ELEMENTS'
        WRITE(iout,fmt=fmw_10i)(itab(msv(i)),i=1,msn)
      ENDIF
C------------------------------------------------------------
      RETURN