kine_seatbelt_force.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    kine_seatbelt_force    ../engine/source/tools/seatbelts/kine_seatbelt_force.F
!||--- called by ------------------------------------------------------
!||    resol                  ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||    spmd_exch_a_seatbelt   ../engine/source/mpi/seatbelts/spmd_exch_a_seatbelt.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod           ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    seatbelt_mod           ../common_source/modules/seatbelt_mod.F
!||====================================================================
      SUBROUTINE kine_seatbelt_force(A,STIFN,FLAG_SLIPRING_UPDATE,FLAG_RETRACTOR_UPDATE)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod
      USE seatbelt_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "param_c.inc"
C-----------------------------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER FLAG_SLIPRING_UPDATE,FLAG_RETRACTOR_UPDATE
      my_real a(3,*),stifn(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,L,NODE2,ANCHOR_NODE
      my_real buf_exch(n_anchor_remote_send,4)
C---------------------------------------------------------
C
      l = 1
C
C----------------------------------------------------------
C-    KINEMATIC CONDITION OF SLIPRING - FORCE TRANSFER
C----------------------------------------------------------      
C
 
      DO i=1,nslipring
        DO j=1,slipring(i)%NFRAM
          slipring(i)%FRAM(j)%MATERIAL_FLOW_OLD = slipring(i)%FRAM(j)%MATERIAL_FLOW
          IF (abs(slipring(i)%FRAM(j)%UPDATE)==2) flag_slipring_update = flag_slipring_update + 2
          anchor_node = slipring(i)%FRAM(j)%ANCHOR_NODE
          node2 = slipring(i)%FRAM(j)%NODE(2)
          a(1,anchor_node)=a(1,anchor_node)+a(1,node2)
          a(2,anchor_node)=a(2,anchor_node)+a(2,node2)
          a(3,anchor_node)=a(3,anchor_node)+a(3,node2)
          stifn(anchor_node)=stifn(anchor_node)+stifn(node2) 
          IF (slipring(i)%FRAM(j)%N_REMOTE_PROC > 0) THEN
C--         Contribution stored to be exchanged to remote anchor node
            buf_exch(l,1) = a(1,node2)
            buf_exch(l,2) = a(2,node2)
            buf_exch(l,3) = a(3,node2)
            buf_exch(l,4) = stifn(node2)
            l = l + 1
          ENDIF
          a(1,node2)=zero
          a(2,node2)=zero
          a(3,node2)=zero
        ENDDO     
      ENDDO
 
C----------------------------------------------------------
C-    KINEMATIC CONDITION OF RETRACTOR - FORCE TRANSFER
C----------------------------------------------------------
 
      DO i=1,nretractor
         IF (abs(retractor(i)%UPDATE)==2) flag_retractor_update = flag_retractor_update + 2
         anchor_node = retractor(i)%ANCHOR_NODE
         node2 = retractor(i)%NODE(2)
         a(1,anchor_node)=a(1,anchor_node)+a(1,node2)
         a(2,anchor_node)=a(2,anchor_node)+a(2,node2)
         a(3,anchor_node)=a(3,anchor_node)+a(3,node2)
         stifn(anchor_node)=stifn(anchor_node)+stifn(node2)  
         IF (retractor(i)%N_REMOTE_PROC > 0) THEN
C--        Contribution stored to be exchanged to remote anchor node
            buf_exch(l,1) = a(1,node2)
            buf_exch(l,2) = a(2,node2)
            buf_exch(l,3) = a(3,node2)
            buf_exch(l,4) = stifn(node2)
            l = l + 1
         ENDIF
         a(1,node2)=zero
         a(2,node2)=zero
         a(3,node2)=zero    
      ENDDO
 
C----------------------------------------------------------
C-    EXCHANGE OF CONTRIBUTION FOR REMOTE ANCHOR NODES
C----------------------------------------------------------
C
C--   PARITH/ON is ensured because anchor node can only be on one slipring or retractor
C
      IF (nspmd > 1) THEN
        CALL spmd_exch_a_seatbelt(a,stifn,buf_exch)
      ENDIF
 
C----------------------------------------------------------
C
 
C----------------------------------------------------------      
C
      RETURN
                
      END