law77_upd.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    law77_upd              ../starter/source/materials/mat/mat077/law77_upd.F
!||--- called by ------------------------------------------------------
!||    updmat                 ../starter/source/materials/updmat.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    func_slope             ../starter/source/tools/curve/func_slope.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    table_mod              ../starter/share/modules1/table_mod.F
!||====================================================================
      SUBROUTINE law77_upd(TITR    ,MAT_ID   ,NUPARAM ,MAT_PARAM ,
     .                     UPARAM  ,NFUNC    ,IFUNC   ,NPC       ,PLD      )
C----------------------------------------------- 
C   M o d u l e s
C-----------------------------------------------
      USE message_mod      
      USE matparam_def_mod
      USE table_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER  MAT_ID,NFUNC,NUPARAM
      INTEGER STF,SNPC
      INTEGER ,DIMENSION(NFUNC)   :: IFUNC
      INTEGER :: NPC(*)
      my_real pld(*)
      my_real uparam(nuparam)
      CHARACTER(LEN=NCHARTITLE)  :: TITR 
      TYPE(matparam_struct_) :: MAT_PARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,K,II,JJ,NDIM,NLOAD,NULOAD,NPT,NEPSP,FUNC_ID,
     .           func_t,func_c,func_s,icas,iconv,
     .           npt_trac,npt_comp,npt_shear,nptmax,ifun_nup,ifx,ify,stat,
     .           len,ix0,iy0,iflag,iflag0,nf,itens,ichk,ic1,ic2,ibid
      my_real :: xint,yint,emax,e0,epsmax,eps0,epst1,fac,deri,
     .           x0,y0,x1,y1,dx,dy,stiffmin,stiffmax,stiffini,stiffavg
      INTEGER ,DIMENSION(:)  ,ALLOCATABLE :: SIZE
      my_real ,DIMENSION(:)  ,ALLOCATABLE :: x_comp,y_comp
      my_real ,DIMENSION(NFUNC) :: rate,yfac
C=======================================================================
      nload  = int(uparam(7))
      nuload = int(uparam(8))
      e0     = uparam(2)
      epsmax = uparam(4)
      emax   = uparam(2*nfunc + 12)
      itens  = uparam(2*nfunc + 13)
c      
      DO i = 1,nfunc
        rate(i) = uparam(i + 8)
        yfac(i) = uparam(i + 8 + nfunc)
      END DO
C=======================================================================
      ibid = mat_param%ILAW
      iflag = 0
c     When Emax=0 we consider the max curve slope.
      IF (emax == zero) THEN
        DO k=1,nfunc
          func_id = ifunc(k)
          fac = yfac(k)
          CALL func_slope(func_id,fac,npc,pld,stiffmin,stiffmax,stiffini,stiffavg)
          uparam(2*nfunc + 12) = stiffmax
          uparam(3) = (stiffmax - e0)/stiffmax
          CALL ancmsg(msgid=1219,msgtype=msginfo,anmode=aninfo_blind_1,
     .                i1=mat_id,
     .                c1=titr,
     .                r1=emax)
         END DO
c         IF (STIFFMAX < E0) IFLAG0 = 1
       ENDIF ! emax
c      automatic modification of EPST1 and E0
       eps0  = one
       iflag = 0
       iflag0= 0
       epst1 = one            
       DO k=1,nload
          func_id = ifunc(k)
          ichk = 0
          IF (func_id > 0 ) THEN
             fac = yfac(k)
             ic1 = npc(func_id)
             ic2 = npc(func_id+1)
C         loading function
             x0 = pld(ic1)
             DO ii = ic1,ic2-4,2
               jj = ii+2
               dx = pld(jj)   - x0
               dy = pld(jj+1) - pld(ii+1)
               y0 =  fac*pld(ii+1)
               y1 =  fac*pld(jj+1)
               deri = fac * dy / dx
               x1 =  pld(jj)
               IF(x1 > zero .AND. ichk == 0 ) THEN
                  ichk = 1
C                 check of initial rigidity
                  IF(deri > e0) THEN
                    iflag0 = 1
                    e0 = deri
                    IF(emax <e0)emax = e0
                  ENDIF
               ENDIF
               IF ( deri >= emax .AND. x0 > zero) THEN
                 eps0 = min(eps0, x0 )
                 iflag = 1
                 IF(x0 == eps0) THEN
                    epst1 = min(epst1,abs(eps0 - y0/emax))
                 ENDIF
               ENDIF
               x0 =  pld(jj)
             ENDDO
          ENDIF
      ENDDO ! NLOAD
C      
      IF (iflag == 1) THEN
          e0 = min(e0, emax)
          uparam(3) = (emax - e0)/epst1
          uparam(4) = eps0
          CALL ancmsg(msgid=864,msgtype=msginfo,anmode=aninfo_blind_1,
     .                i1=mat_id,
     .                c1=titr,
     .                r1=eps0)
      ENDIF
      IF (iflag0 == 1) THEN
          e0 = min(e0, emax)
          uparam(3) = (emax - e0)/epst1
          uparam(2) = e0
          CALL ancmsg(msgid=865,msgtype=msgwarning,anmode=aninfo_blind_1,
     .                i1=mat_id,
     .                c1=titr,
     .                r1=e0)
      ENDIF
c--------------------------------------------------------
      RETURN
      END