mstrain_rate.F File Reference

#include "implicit_f.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	mstrain_rate (nel, israte, asrate, epsd, idev, ep1, ep2, ep3, ep4, ep5, ep6)

Function/Subroutine Documentation

mstrain_rate()

subroutine mstrain_rate	(	integer	nel,
		integer	israte,
			asrate,
		intent(inout)	epsd,
		integer	idev,
		intent(in)	ep1,
		intent(in)	ep2,
		intent(in)	ep3,
		intent(in)	ep4,
		intent(in)	ep5,
		intent(in)	ep6 )

Definition at line 31 of file mstrain_rate.F.

C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER  NEL,ISRATE,IDEV
      my_real  asrate
      my_real, DIMENSION(NEL), INTENT(IN)    :: ep1, ep2, ep3, ep4, ep5, ep6
      my_real, DIMENSION(NEL), INTENT(INOUT) :: epsd
C---------------------------------------------------
C   L o c a l   V a r i a b l e s
C---------------------------------------------------
      INTEGER I
      my_real :: e1, e2, e3, e4, e5, e6, dav, epsp
      my_real :: epsdot(nel)
c-----------------------------------------------------------------------
c  COMPUTE EQUIVALENT STRAIN RATE
c        IDEV = 0 => total strain rate
c        IDEV = 1 => deviatoric strain rate
C=======================================================================
      IF (israte >= 0) THEN   ! calculate strain rate
        IF (idev == 0) THEN   ! total strain rate
          DO i=1,nel
            e1 = ep1(i)
            e2 = ep2(i)
            e3 = ep3(i)
            e4 = half*ep4(i)
            e5 = half*ep5(i)
            e6 = half*ep6(i)
            epsp = e1**2 + e2**2 + e3**2 + two*(e4**2 + e5**2 + e6**2)
            epsdot(i) = sqrt(epsp)
          ENDDO
        ELSE                  ! deviatoric strain rate
          DO i=1,nel
            dav = (ep1(i)+ep2(i)+ep3(i))*third
            e1  = ep1(i) - dav
            e2  = ep2(i) - dav
            e3  = ep3(i) - dav
            e4  = half*ep4(i)
            e5  = half*ep5(i)
            e6  = half*ep6(i)
            epsp = half*(e1**2 + e2**2 + e3**2) + e4**2 + e5**2 + e6**2
            epsdot(i) = sqrt(three*epsp)/three_half
          ENDDO
        ENDIF
      ENDIF
c
      IF (israte == 0) THEN
        epsd(:) = epsdot(:)
      ELSEIF (israte > 0) THEN
        epsd(:) = asrate*epsdot(:) + (one - asrate)*epsd(:)
      ENDIF
c-----------
      RETURN