multi_face_data_elem.F File Reference

#include "implicit_f.inc"
#include "param_c.inc"
#include "com01_c.inc"
#include "task_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	multi_face_elem_data (itask, iparg, ixs, ixq, ixtg, xgrid, wgrid, multi_fvm)

Function/Subroutine Documentation

multi_face_elem_data()

subroutine multi_face_elem_data	(	integer, intent(in)	itask,
		integer, dimension(nparg, *), intent(in)	iparg,
		integer, dimension(nixs, *), intent(in)	ixs,
		integer, dimension(nixq, *), intent(in)	ixq,
		integer, dimension(nixtg, *), intent(in)	ixtg,
		dimension(3, *), intent(in)	xgrid,
		dimension(3, *), intent(in)	wgrid,
		type(multi_fvm_struct), intent(inout)	multi_fvm )

Definition at line 40 of file multi_face_data_elem.F.

C-----------------------------------------------
C     M o d u l e s
C-----------------------------------------------
      USE multi_fvm_mod
C-----------------------------------------------
C     I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"      
C-----------------------------------------------
C     C o m m o n   B l o c k s
C-----------------------------------------------
C     NIXS, NIXQ, NIXTG, NPARG
#include      "param_c.inc"
C     NGROUP
#include      "com01_c.inc"
C     NTHREAD
#include      "task_c.inc"
C-----------------------------------------------
C     D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: ITASK, IPARG(NPARG, *), IXS(NIXS, *), IXQ(NIXQ, *), IXTG(NIXTG, *)
      my_real, INTENT(IN) :: xgrid(3, *), wgrid(3, *)
      TYPE(MULTI_FVM_STRUCT), INTENT(INOUT) :: MULTI_FVM
C-----------------------------------------------
C     L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: NG, MTN, NEL, ITY, ISOLNOD, NFT, JALE
      LOGICAL :: COMPUTE_CENTROID
      
      compute_centroid = (multi_fvm%MUSCL > 0) .OR. multi_fvm%NS_DIFF 
 
      DO ng = itask + 1, ngroup, nthread
         mtn = iparg(1, ng)
         IF (mtn == 151) THEN
            nel = iparg(2, ng)
            nft = iparg(3, ng)
            ity = iparg(5, ng)
            jale = iparg(7, ng)
            isolnod = iparg(28, ng)
            IF (ity == 1) THEN
C     Solid
               IF (isolnod == 4) THEN
C     TETRA
                  CALL snorm3t(nel, nft, jale, ixs, xgrid, wgrid, 
     .                 multi_fvm%FACE_DATA%NORMAL(1:3, 1:6, 1 + nft : nel + nft), 
     .                 multi_fvm%FACE_DATA%WFAC(1:3, 1:6, 1 + nft : nel + nft), 
     .                 multi_fvm%FACE_DATA%SURF(1:6, 1 + nft : nel + nft))
                  IF (compute_centroid) THEN
                     CALL centroid3t(nel, multi_fvm%NELEM, nft, ixs, xgrid, 
     .                    multi_fvm%ELEM_DATA%CENTROID(:, 1 + nft : nel + nft), 
     .                    multi_fvm%FACE_DATA%CENTROID(:, :, 1 + nft : nel + nft))
                  ENDIF
               ELSE 
C     OTHER SOLIDS
                  CALL snorm3(nel, nft, jale, ixs, xgrid, wgrid, 
     .                 multi_fvm%FACE_DATA%NORMAL(1:3, 1:6, 1 + nft : nel + nft), 
     .                 multi_fvm%FACE_DATA%WFAC(1:3, 1:6, 1 + nft : nel + nft), 
     .                 multi_fvm%FACE_DATA%SURF(1:6, 1 + nft : nel + nft))
C     
                  IF (compute_centroid) THEN
                     CALL centroid3(nel, multi_fvm%NELEM, nft, ixs, xgrid, 
     .                    multi_fvm%ELEM_DATA%CENTROID(:, 1 + nft : nel + nft), 
     .                    multi_fvm%FACE_DATA%CENTROID(:, :, 1 + nft : nel + nft))
                  ENDIF
               ENDIF
            ELSE IF (ity == 2) THEN
C     QUAD
               CALL qnorm2(nel, nft, jale, multi_fvm%SYM, ixq, xgrid, wgrid, 
     .              multi_fvm%FACE_DATA%NORMAL(1:3, 1:4, 1 + nft : nel + nft), 
     .              multi_fvm%FACE_DATA%WFAC(1:3, 1:4, 1 + nft : nel + nft), 
     .              multi_fvm%FACE_DATA%SURF(1:4, 1 + nft : nel + nft))
               IF (compute_centroid) THEN
                  CALL centroid2(nel, multi_fvm%NELEM, nft, ixq, xgrid, 
     .                 multi_fvm%ELEM_DATA%CENTROID(:, 1 + nft : nel + nft), 
     .                 multi_fvm%FACE_DATA%CENTROID(:, :, 1 + nft : nel + nft))
               ENDIF
            ELSE IF (ity == 7) THEN
C     TRIANGLE
               CALL qnorm2t(nel, nft, jale, multi_fvm%SYM, ixtg, xgrid, wgrid, 
     .              multi_fvm%FACE_DATA%NORMAL(1:3, 1:3, 1 + nft : nel + nft), 
     .              multi_fvm%FACE_DATA%WFAC(1:3, 1:3, 1 + nft : nel + nft), 
     .              multi_fvm%FACE_DATA%SURF(1:3, 1 + nft : nel + nft))
               IF (compute_centroid) THEN
                  CALL centroid2t(nel, multi_fvm%NELEM, nft, ixtg, xgrid, 
     .                 multi_fvm%ELEM_DATA%CENTROID(:, 1 + nft : nel + nft), 
     .                 multi_fvm%FACE_DATA%CENTROID(:, :, 1 + nft : nel + nft))
               ENDIF
            ENDIF
         ENDIF
      ENDDO