fvvolu_mod Module Reference

Functions/Subroutines
subroutine	fvvolu (ityp, nns, nntr, npolh, ibuf, ibufa, elema, tagela, x, ivolu, rvolu, ifvnod, rfvnod, ifvtri, ifvpoly, ifvtadr, ifvpolh, ifvpadr, mpolh, epolh, vpolh_ini)

Function/Subroutine Documentation

fvvolu()

subroutine fvvolu_mod::fvvolu	(	integer	ityp,
		integer	nns,
		integer	nntr,
		integer	npolh,
		integer, dimension(*)	ibuf,
		integer, dimension(*)	ibufa,
		integer, dimension(3,*)	elema,
		integer, dimension(*)	tagela,
			x,
		integer, dimension(*)	ivolu,
			rvolu,
		integer, dimension(3,*)	ifvnod,
			rfvnod,
		integer, dimension(6,*)	ifvtri,
		integer, dimension(*)	ifvpoly,
		integer, dimension(*)	ifvtadr,
		integer, dimension(*)	ifvpolh,
		integer, dimension(*)	ifvpadr,
			mpolh,
			epolh,
			vpolh_ini )

Definition at line 37 of file fvvolu.F.

C-----------------------------------------------
C   M o d u l e s 
C-----------------------------------------------
CC      USE FVBAG_MOD
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITYP, NNS, NNTR, NPOLH
      INTEGER IBUF(*),   IBUFA(*),  ELEMA(3,*), TAGELA(*), 
     .        IVOLU(*),  IFVNOD(3,*),IFVTRI(6,*),
     .        IFVPOLY(*),IFVTADR(*),IFVPOLH(*), IFVPADR(*)
      my_real
     .        x(3,*), rvolu(*), rfvnod(2,*), 
     .        mpolh(*), epolh(*),vpolh_ini(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,  J,  K,  I1,  I2,  IEL, JJ,  KK,
     .        N1, N2, N3, NN1, NN2, NN3,
     .        NSTR, NCTR, NPOLH_N
      my_real
     .        x1, y1, z1, x2, y2, z2, x3, y3, z3, 
     .        nx, ny, nz, area2, ksi, eta, area, fac, 
     .        pnod(3,nns),  pvolu(npolh),  volph,
     .        parea(nntr),  pnorm(3,nntr), areap
      my_real
     .        cpai, cpbi, cpci, cpdi, cpei, cpfi,
     .        rmwi, pini, ti,   ti2,  rhoi, efac 
C---------------------------------------------------
C Noeuds des volumes finis
C---------------------------------------------------
      x1 = zero
      y1 = zero
      z1 = zero
      x2 = zero
      y2 = zero
      z2 = zero
      x3 = zero
      y3 = zero
      z3 = zero
      nx = zero
      ny = zero
      nz = zero
 
 
      DO i=1,nns
         IF (ifvnod(1,i)==1) THEN
            iel=ifvnod(2,i)
            ksi=rfvnod(1,i)
            eta=rfvnod(2,i)
C
            n1=elema(1,iel)
            n2=elema(2,iel)
            n3=elema(3,iel)
C
            IF (tagela(iel)>0) THEN
               nn1=ibuf(n1)
               nn2=ibuf(n2)
               nn3=ibuf(n3)
               x1=x(1,nn1)
               y1=x(2,nn1)
               z1=x(3,nn1)
               x2=x(1,nn2)
               y2=x(2,nn2)
               z2=x(3,nn2)
               x3=x(1,nn3)
               y3=x(2,nn3)
               z3=x(3,nn3)
            ELSEIF (tagela(iel)<0) THEN
               nn1=ibufa(n1)
               nn2=ibufa(n2)
               nn3=ibufa(n3)
               x1=x(1,nn1)
               y1=x(2,nn1)
               z1=x(3,nn1)
               x2=x(1,nn2)
               y2=x(2,nn2)
               z2=x(3,nn2)
               x3=x(1,nn3)
               y3=x(2,nn3)
               z3=x(3,nn3)
            ENDIF
            pnod(1,i)=(one-ksi-eta)*x1+ksi*x2+eta*x3
            pnod(2,i)=(one-ksi-eta)*y1+ksi*y2+eta*y3
            pnod(3,i)=(one-ksi-eta)*z1+ksi*z2+eta*z3
C
         ELSEIF (ifvnod(1,i)==2) THEN
            i2=ifvnod(2,i)
            pnod(1,i)=x(1,i2)
            pnod(2,i)=x(2,i2)
            pnod(3,i)=x(3,i2)
         ENDIF
      ENDDO
C
      DO i=1,nns
         IF (ifvnod(1,i)==3) THEN
            i1=ifvnod(2,i)
            i2=ifvnod(3,i)
            fac=rfvnod(1,i)
            pnod(1,i)=fac*pnod(1,i1)+(one-fac)*pnod(1,i2)
            pnod(2,i)=fac*pnod(2,i1)+(one-fac)*pnod(2,i2)
            pnod(3,i)=fac*pnod(3,i1)+(one-fac)*pnod(3,i2)
         ENDIF
      ENDDO
C----------------------------
C Normale, aire des triangles
C----------------------------
      DO i=1,nntr
         n1=ifvtri(1,i)
         n2=ifvtri(2,i)
         n3=ifvtri(3,i)
         CALL fvnormal(pnod,n1,n2,n3,0,nx,ny,nz)
         area2=sqrt(nx*nx+ny*ny+nz*nz)
         parea(i)=half*area2
         IF (area2>0) THEN
            pnorm(1,i)=nx/area2
            pnorm(2,i)=ny/area2
            pnorm(3,i)=nz/area2
         ELSE
            pnorm(1,i)=zero
            pnorm(2,i)=zero
            pnorm(3,i)=zero
         ENDIF
      ENDDO
C----------------------
C Volume des polyhedres
C----------------------
      DO i=1,npolh
         pvolu(i)=zero
C Boucle sur les polygones du polyhedre
         DO j=ifvpadr(i),ifvpadr(i+1)-1
            jj=ifvpolh(j)
C Boucle sur les triangles du polygone
            DO k=ifvtadr(jj), ifvtadr(jj+1)-1
               kk=ifvpoly(k)
               area=parea(kk)
               iel=ifvtri(4,kk)
               IF (iel>0) THEN
                  nx=pnorm(1,kk)
                  ny=pnorm(2,kk)
                  nz=pnorm(3,kk)
               ELSE
                  IF (ifvtri(5,kk)==i) THEN
                     nx=pnorm(1,kk)
                     ny=pnorm(2,kk)
                     nz=pnorm(3,kk)
                  ELSEIF (ifvtri(6,kk)==i) THEN
                     nx=-pnorm(1,kk)
                     ny=-pnorm(2,kk)
                     nz=-pnorm(3,kk)
                  ENDIF   
               ENDIF      
               n1=ifvtri(1,kk)
               x1=pnod(1,n1)
               y1=pnod(2,n1)
               z1=pnod(3,n1)
               pvolu(i)=pvolu(i)+third*area*(x1*nx+y1*ny+z1*nz)
            ENDDO
         ENDDO
      ENDDO
C---------------------------------------------------
C Impressions
C---------------------------------------------------
      volph=zero
      areap=zero
      npolh_n=0
      DO i=1,npolh
         volph=volph+pvolu(i)
         IF (pvolu(i)<=zero) npolh_n=npolh_n+1
      ENDDO
C
      nstr=0
      nctr=0
      DO i=1,nntr
         IF (ifvtri(4,i)>0) THEN
            nstr=nstr+1
            areap=areap+parea(i)
         ELSE
            nctr=nctr+1
         ENDIF
      ENDDO
C
      WRITE(iout,1000) ivolu(1),nstr,nctr,npolh,npolh_n,volph,areap
C
C---------------------------------------------------
C Update des quantites dans les polyhedres
C---------------------------------------------------
      cpai =rvolu(7)
      cpbi =rvolu(8)
      cpci =rvolu(9)
      rmwi =rvolu(10)
      pini =rvolu(12)
      ti   =rvolu(13)
      ti2 =ti*ti
      efac=ti*(cpai+half*cpbi*ti+third*cpci*ti2-rmwi)
      rhoi=pini/(ti*rmwi)
      cpdi=rvolu(56)
      cpei=rvolu(57)
      cpfi=rvolu(58)
      IF(ityp == 8) THEN
         efac=efac+fourth*cpdi*ti2*ti2-cpei/ti+one_fifth*cpfi*ti2*ti2*ti          
      ENDIF
      DO i=1,npolh
         mpolh(i)=rhoi*pvolu(i)
         epolh(i)=mpolh(i)*efac
         vpolh_ini(i)=pvolu(i)
      ENDDO
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7--
1000  FORMAT(
     . //'     FVMBAG: FINITE VOLUME MESH ON INITIAL GEOMETRY'/
     .   '     ----------------------------------------------'/
     .       /5x,'VOLUME NUMBER ',i10,
     .       /5x,'NUMBER OF SURFACE TRIANGLES . . . . . . .=',i10,
     .       /5x,'NUMBER OF COMMUNICATION TRIANGLES . . . .=',i10,
     .       /5x,'NUMBER OF FINITE VOLUMES. . . . . . . . .=',i10,
     .       /5x,'NUMBER OF FINITE VOLUMES WITH VOLUME <0 .=',i10,
     .       /5x,'SUM VOLUME OF FINITE VOLUMES. . . . . . .=',1pg20.13,
     .       /5x,'SUM AREA SURFACE TRIANGLES. . . . . . . .=',1pg20.13/)
      RETURN