murnaghan_mod Module Reference

Functions/Subroutines
subroutine	murnaghan (iflag, nel, pmin, off, eint, mu, dvol, vnew, psh, pnew, dpdm, dpde, eos_struct)

Function/Subroutine Documentation

murnaghan()

subroutine murnaghan_mod::murnaghan	(	integer, intent(in)	iflag,
		integer, intent(in)	nel,
		intent(in)	pmin,
		dimension(nel), intent(in)	off,
		dimension(nel), intent(inout)	eint,
		dimension(nel), intent(in)	mu,
		dimension(nel), intent(in)	dvol,
		dimension(nel), intent(in)	vnew,
		dimension(nel), intent(inout)	psh,
		dimension(nel), intent(inout)	pnew,
		dimension(nel), intent(inout)	dpdm,
		dimension(nel), intent(inout)	dpde,
		type(eos_param_), intent(in)	eos_struct )

Definition at line 41 of file murnaghan.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE constant_mod , ONLY : zero, em15, half, one, two, three, three100
      USE eos_param_mod , ONLY : eos_param_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C This subroutine contains numerical solving
C of MURNAGHAN EOS
!----------------------------------------------------------------------------
!! \details STAGGERED SCHEME IS EXECUTED IN TWO PASSES IN EOSMAIN : IFLG=0 THEN IFLG=1
!! \details COLLOCATED SCHEME IS DOING A SINGLE PASS : IFLG=2
!! \details
!! \details  STAGGERED SCHEME
!! \details     EOSMAIN / IFLG = 0 : DERIVATIVE CALCULATION FOR SOUND SPEED ESTIMATION c[n+1] REQUIRED FOR PSEUDO-VISCOSITY (DPDE:partial derivative, DPDM:total derivative)
!! \details     MQVISCB            : PSEUDO-VISCOSITY Q[n+1]
!! \details     MEINT              : INTERNAL ENERGY INTEGRATION FOR E[n+1] : FIRST PART USING P[n], Q[n], and Q[n+1] CONTRIBUTIONS
!! \details     EOSMAIN / IFLG = 1 : UPDATE P[n+1], T[N+1]
!! \details                          INTERNAL ENERGY INTEGRATION FOR E[n+1] : LAST PART USING P[n+1] CONTRIBUTION
!! \details                            (second order integration dE = -P.dV where P = 0.5(P[n+1] + P[n]) )
!! \details  COLLOCATED SCHEME
!! \details     EOSMAIN / IFLG = 2 : SINGLE PASS FOR P[n+1] AND DERIVATIVES
!----------------------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
      IMPLICIT NONE
#include  "my_real.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) ::  IFLAG, NEL
      my_real,INTENT(IN) ::  pmin,  off(nel) ,mu(nel), dvol(nel) ,vnew(nel)
      my_real, INTENT(INOUT) :: psh(nel),pnew(nel) ,dpdm(nel),dpde(nel),eint(nel)
      TYPE(EOS_PARAM_),INTENT(IN) :: EOS_STRUCT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER I
        my_real :: p0,k0,k1
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      k0         = eos_struct%UPARAM(1)
      p0         = eos_struct%UPARAM(2)
      psh(1:nel) = eos_struct%PSH
      k1         = eos_struct%UPARAM(3)
 
      IF(iflag == 0) THEN
        DO i=1,nel
          dpdm(i) = k0*exp( k1*log(1+mu(i)) )/(one+mu(i))     !total derivative
          dpde(i) = zero                                      !partial derivative
          pnew(i) = k0/k1 * (exp(k1*log(one+mu(i))) - one )  + p0
          pnew(i) = max(pnew(i),pmin)*off(i)
          pnew(i) = pnew(i)-psh(i)
        ENDDO
 
      ELSEIF(iflag == 1) THEN
        DO i=1,nel
          pnew(i) = k0/k1 * (exp(k1*log(one+mu(i))) - one )  + p0
          pnew(i) = max(pnew(i),pmin)*off(i)
          eint(i) = eint(i) - half*dvol(i)*(pnew(i)+psh(i))
          pnew(i) = pnew(i)-psh(i)
          dpde(i) = zero
        ENDDO
 
       ELSEIF(iflag == 2) THEN
         DO i=1,nel
           IF (vnew(i) > zero) THEN
             pnew(i) = k0/k1 * (exp(k1*log(1+mu(i))) - one )  + p0
             dpdm(i) = k0*exp( k1*log(1+mu(i)) )/(one+mu(i)) !total derivative
             dpde(i) = zero
             pnew(i) = max(pnew(i),pmin)*off(i)
             pnew(i) = pnew(i)-psh(i)
           ENDIF
         ENDDO
      ENDIF
C------------------------      
      RETURN