noble_abel_mod Module Reference

Functions/Subroutines
subroutine	noble_abel (iflag, nel, off, eint, mu, espe, dvol, df, vnew, psh, pnew, dpdm, dpde, eos_struct)

Function/Subroutine Documentation

noble_abel()

subroutine noble_abel_mod::noble_abel	(	integer, intent(in)	iflag,
		integer, intent(in)	nel,
		dimension(nel), intent(in)	off,
		dimension(nel), intent(inout)	eint,
		dimension(nel), intent(in)	mu,
		dimension(nel), intent(in)	espe,
		dimension(nel), intent(in)	dvol,
		dimension(nel), intent(in)	df,
		dimension(nel), intent(in)	vnew,
		dimension(nel), intent(inout)	psh,
		dimension(nel), intent(inout)	pnew,
		dimension(nel), intent(inout)	dpdm,
		dimension(nel), intent(inout)	dpde,
		type(eos_param_), intent(in)	eos_struct )

Parameters

[in]

eos_struct

data structure for EoS parameters

Definition at line 41 of file noble_abel.F.

C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C This subroutine contains numerical solving
C of NOBLE-ABEL EOS
!----------------------------------------------------------------------------
!! \details STAGGERED SCHEME IS EXECUTED IN TWO PASSES IN EOSMAIN : IFLG=0 THEN IFLG=1
!! \details COLLOCATED SCHEME IS DOING A SINGLE PASS : IFLG=2
!! \details
!! \details  STAGGERED SCHEME
!! \details     EOSMAIN / IFLG = 0 : DERIVATIVE CALCULATION FOR SOUND SPEED ESTIMATION c[n+1] REQUIRED FOR PSEUDO-VISCOSITY (DPDE:partial derivative, DPDM:total derivative)
!! \details     MQVISCB            : PSEUDO-VISCOSITY Q[n+1]
!! \details     MEINT              : INTERNAL ENERGY INTEGRATION FOR E[n+1] : FIRST PART USING P[n], Q[n], and Q[n+1] CONTRIBUTIONS
!! \details     EOSMAIN / IFLG = 1 : UPDATE P[n+1], T[N+1]
!! \details                          INTERNAL ENERGY INTEGRATION FOR E[n+1] : LAST PART USING P[n+1] CONTRIBUTION
!! \details                            (second order integration dE = -P.dV where P = 0.5(P[n+1] + P[n]) )
!! \details  COLLOCATED SCHEME
!! \details     EOSMAIN / IFLG = 2 : SINGLE PASS FOR P[n+1] AND DERIVATIVES
!----------------------------------------------------------------------------
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
        USE eos_param_mod , ONLY : eos_param_
        USE constant_mod , ONLY : em15,half,one,zero
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        IMPLICIT NONE
#include "my_real.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: IFLAG
      INTEGER,INTENT(IN) :: NEL
      my_real,INTENT(INOUT) :: dpdm(nel),dpde(nel),psh(nel)  ,eint(nel),pnew(nel)
      my_real,INTENT(IN) :: off(nel)  ,mu(nel)
      my_real,INTENT(IN) :: espe(nel) ,dvol(nel) ,df(nel), vnew(nel)
      TYPE(EOS_PARAM_),INTENT(IN) :: EOS_STRUCT !< data structure for EoS parameters
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I
      my_real :: gm1, dvv, pp,bb_,rho0,denom,bb
C-----------------------------------------------
 
      bb_  = eos_struct%UPARAM(1)
      gm1  = eos_struct%UPARAM(2)
      rho0 = eos_struct%UPARAM(3)
      psh(1:nel)  = eos_struct%PSH
 
      IF(iflag == 0) THEN
        DO i=1,nel
          denom   = one-bb_*rho0*(one+mu(i))
          pp      = espe(i)*gm1*(mu(i)+one)/denom
          dpde(i) = gm1*(one+mu(i))/denom
          dpdm(i) = gm1*espe(i)/denom + pp/denom*bb_*rho0 + pp*df(i)*df(i)*dpde(i)
          pnew(i) = max(pp,zero)*off(i)! P(mu[n+1],E[n])
          pnew(i) = pnew(i)-psh(i)
        ENDDO
 
      ELSEIF(iflag == 1) THEN
        DO i=1,nel
          denom   = one-bb_*rho0*(one+mu(i))
          bb      = gm1*(one+mu(i))/denom
          dpde(i) = bb
          dvv     = half*dvol(i)*df(i) / max(em15,vnew(i))
          pnew(i) = (bb*espe(i))/(one+bb*dvv)
          pnew(i) = pnew(i)*off(i)! P(mu[n+1],E[n])
          eint(i) = eint(i) - half*dvol(i)*pnew(i)
          pnew(i) = pnew(i)-psh(i)
        ENDDO
 
      ELSEIF(iflag == 2) THEN
        DO i=1, nel
          IF (vnew(i) > zero) THEN
            denom   = one-bb_*rho0*(one+mu(i))
            pp      = espe(i)*gm1*(mu(i)+one)/denom
            dpde(i) = gm1*(one+mu(i))/denom
            dpdm(i) = gm1*espe(i)/denom + pp/denom*bb_*rho0 + pp*df(i)*df(i)*dpde(i)
            pnew(i) = pp-psh(i)
          ENDIF
        ENDDO
      ENDIF
      RETURN