qrota_group.F File Reference

#include "implicit_f.inc"
#include "mvsiz_p.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	qrota_group (x, ixq, kcvt, tens, gama, nel, isorth)

Function/Subroutine Documentation

qrota_group()

subroutine qrota_group	(		x,
		integer, dimension(nixq,*)	ixq,
		integer	kcvt,
			tens,
			gama,
		integer	nel,
		integer, intent(in)	isorth )

Definition at line 30 of file qrota_group.F.

      use element_mod , only : nixq
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: ISORTH
C     REAL
      my_real
     .   x(3,*),tens(6,*),gama(6,*)
      INTEGER IXQ(NIXQ,*), KCVT, NEL
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
C     REAL
      my_real
     .   y1(mvsiz), y2(mvsiz), y3(mvsiz), y4(mvsiz),
     .   z1(mvsiz), z2(mvsiz), z3(mvsiz), z4(mvsiz),
     .   r22(mvsiz),r23(mvsiz),r32(mvsiz),r33(mvsiz),
     .   
     .   sy(mvsiz),sz(mvsiz),ty(mvsiz),tz(mvsiz),
     .   g22,g33,g23,g32,
     .   ct,cs,suma,
     .   t1,t2,t3,t4,s1,s2,s4
      INTEGER NC1(MVSIZ), NC2(MVSIZ), NC3(MVSIZ), NC4(MVSIZ),
     .    I
C-----------------------------------------------
      IF (kcvt == 0) THEN
        DO i=1,nel
          nc1(i)=ixq(2,i)
          nc2(i)=ixq(3,i)
          nc3(i)=ixq(4,i)
          nc4(i)=ixq(5,i)
C----------------------------
C     NODE COORDINATES
C----------------------------
          y1(i)=x(2,nc1(i))
          z1(i)=x(3,nc1(i))
          y2(i)=x(2,nc2(i))
          z2(i)=x(3,nc2(i))
          y3(i)=x(2,nc3(i))
          z3(i)=x(3,nc3(i))
          y4(i)=x(2,nc4(i))
          z4(i)=x(3,nc4(i))
C---------------------------------------
C     LOCAL REFERENCE FRAME (ISOPARAMETRIC)
C---------------------------------------
          sy(i)=half*(y2(i)+y3(i)-y1(i)-y4(i))
          sz(i)=half*(z2(i)+z3(i)-z1(i)-z4(i))
          ty(i)=half*(y3(i)+y4(i)-y1(i)-y2(i))
          tz(i)=half*(z3(i)+z4(i)-z1(i)-z2(i))
        ENDDO
C-----------
C       convected frame
C-----------
        DO i=1,nel
          ct = ty(i)*ty(i)+tz(i)*tz(i)
          cs = sy(i)*sy(i)+sz(i)*sz(i)
          IF(cs /= zero) THEN
            suma = sqrt(ct/max(em20,cs))
            sy(i) = sy(i)*suma + tz(i)
            sz(i) = sz(i)*suma - ty(i)
          ELSEIF(ct /= zero)THEN
            suma = sqrt(cs/max(em20,ct))
            sy(i) = sy(i) + tz(i)*suma
            sz(i) = sz(i) - ty(i)*suma
          END IF 
          suma=one/max(sqrt(sy(i)**2+sz(i)**2),em20)
          sy(i)=sy(i)*suma
          sz(i)=sz(i)*suma
C-----------
C       TRANSFORMATION MATRIX GLOBAL -> CONVECTED
C-----------
          r22(i)= sy(i)
          r32(i)=-sz(i)
          r23(i)= sz(i)
          r33(i)= sy(i)
        ENDDO
c
      ELSEIF (isorth /= 0) THEN
        DO i=1,nel
          g22=gama(i,2)
          g32=gama(i,3)
          g23=gama(i,5)
          g33=gama(i,6)
C-----------
c       TRANSFORMATION MATRIX ORTHOTROPIC -> CONVECTED
C-----------
          r22(i)= g22
          r23(i)=-g23
          r32(i)=-g32
          r33(i)= g33
        ENDDO
      END IF
c
      DO i=1,nel
C-----------
C       SIZE(TENS)=6 STORED AS SOLIDS BUT ONLY USE 1, 2 and 4
C-----------
        s1=tens(1,i)
        s2=tens(2,i)
        s4=tens(4,i)
C-----------
        IF (kcvt == 0) THEN
C-----------
C      Rotation from GLOBAL FRAME TO CONVECTED FRAME 
C-----------
          t1=s1*r22(i)+s4*r23(i)
          t2=s4*r32(i)+s2*r33(i)
          t3=s1*r32(i)+s4*r33(i)
          t4=s4*r22(i)+s2*r23(i)
          tens(1,i)=r22(i)*t1+r23(i)*t4
          tens(2,i)=r32(i)*t3+r33(i)*t2
          tens(4,i)=r22(i)*t3+r23(i)*t2
        ELSE
C-----------
C      Rotation from ORTHO FRAME TO CONVECTED FRAME
C-----------
          t1=s1*r22(i)-s4*r23(i)
          t2=-s4*r32(i)+s2*r33(i)
          t3=-s1*r32(i)+s4*r33(i)
          t4=s4*r22(i)-s2*r23(i)
          tens(1,i)=r22(i)*t1-r23(i)*t4
          tens(2,i)=-r32(i)*t3+r33(i)*t2
          tens(4,i)=r22(i)*t3-r23(i)*t2
        ENDIF
      ENDDO
C-----------
      RETURN