read_dfs_detcord.F File Reference

#include "implicit_f.inc"
#include "com04_c.inc"
#include "units_c.inc"
#include "param_c.inc"
#include "tabsiz_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	read_dfs_detcord (detonators, x, igrnod, ipm, itabm1, unitab, lsubmodel, itab)

Function/Subroutine Documentation

read_dfs_detcord()

subroutine read_dfs_detcord	(	type(detonators_struct_), intent(inout)	detonators,
		dimension(3,numnod), intent(in)	x,
		type (group_), dimension(ngrnod), intent(in)	igrnod,
		integer, dimension(npropmi,nummat), intent(in)	ipm,
		integer, dimension(sitabm1), intent(in)	itabm1,
		type (unit_type_), intent(in)	unitab,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel,
		integer, dimension(numnod), intent(in)	itab )

Definition at line 47 of file read_dfs_detcord.F.

C-----------------------------------------------
C   M o d u l e s
C----------------------------------------------- 
      USE unitab_mod
      USE message_mod
      USE detonators_mod
      USE groupdef_mod
      USE hm_option_read_mod
      USE submodel_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharkey
      USE format_mod , ONLY : fmw_10i
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "units_c.inc"
#include      "param_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN)               :: UNITAB
      INTEGER,INTENT(IN)                         :: ITABM1(SITABM1),ITAB(NUMNOD)
      INTEGER,INTENT(IN)                         :: IPM(NPROPMI,NUMMAT)
      my_real,INTENT(IN)                         :: x(3,numnod)
      TYPE(SUBMODEL_DATA),INTENT(IN)             :: LSUBMODEL(NSUBMOD)
      TYPE(DETONATORS_STRUCT_),INTENT(INOUT)     :: DETONATORS
      TYPE (GROUP_),DIMENSION(NGRNOD),INTENT(IN) :: IGRNOD
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER              :: I, MAT, J, NPEM, K,IGU,IGS,JJ,MDET,DET_ID,IDET
      INTEGER              :: IBID,  NODE_ID1, NODE_ID2,uID1,uID2, IOPT, IUNIT, UID
      INTEGER              :: FLAG_FMT,IMAT,IFLAGUNIT,UNUSED,NNOD
      INTEGER              :: STAT,NPE,NPE2
      my_real              :: xc, yc, zc, alt, xc1, yc1, zc1, xc2, yc2, zc2, nx, ny, nz, bid, vcj
      CHARACTER*40         :: MESS
      CHARACTER*64         :: chain1,chain2
      CHARACTER(LEN=NCHARKEY) :: KEY, KEY2
      CHARACTER(LEN=NCHARTITLE) :: TITR
      LOGICAL              :: IS_ENCRYPTED, IS_AVAILABLE
      INTEGER              :: NDETPS,NDETSG,NECRAN,NDETPL,NDETCORD
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER,EXTERNAL     :: NODGRNR5, USR2SYS, NINTRI
      INTEGER              :: UNUSED_MAT_DETONATOR
      DATA mess/'DETONATORS DEFINITION                   '/      
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------      
      CALL hm_option_start('/DFS/DETCORD')
 
      DO idet=1,detonators%N_DET_CORD
 
        CALL hm_option_read_key(lsubmodel,option_id=det_id, unit_id=uid,keyword2=key,keyword3=key2)
        IF (len_trim(key) > 0) key = key(1:7)
        IF (len_trim(key2) > 0) key2 = key2(1:4)
 
        is_encrypted= .false.
        is_available = .false.
        CALL hm_option_is_encrypted(is_encrypted)
        !---------------------------------!
        !             READING             !
        !---------------------------------!
        CALL hm_get_floatv('magnitude', vcj, is_available, lsubmodel, unitab)
        CALL hm_get_floatv('rad_det_time', alt, is_available, lsubmodel, unitab)
        CALL hm_get_intv('rad_det_iopt', iopt, is_available, lsubmodel)
        CALL hm_get_intv('rad_det_materialid', mat, is_available, lsubmodel)
        CALL hm_get_intv('entityid', igu, is_available, lsubmodel)
 
        !---------------------------------!
        !      CHECKING USER FLAGS        !
        !      +INTERNAL ID               !
        !---------------------------------!
        mdet=mat !bak
        IF (alt > infinity) alt=infinity
        IF (alt < -infinity)alt=-infinity
        nnod = nodgrnr5(igu ,igs,detonators%CORD(idet)%NODES,igrnod,itabm1,mess)
        IF(igrnod(igs)%SORTED /= 1)THEN
            CALL ancmsg(msgid   = 104,msgtype = msgerror,anmode  = aninfo,
     .                  c1      = '/DFS/DETCORD',
     .                  i1      = det_id,
     .                  c2      = 'ORDERED GROUP OF NODES IS REQUIRED')
        ENDIF
        unused = 0
        IF(mat > 0)unused=unused_mat_detonator(mat,nummat,ipm)
        IF (mat < 0) THEN
          CALL ancmsg(msgid=102,msgtype=msgerror,anmode=aninfo,
     .                i1=det_id,
     .                c1='DETONATOR IS REFERRING TO A NEGATIVE MATERIAL ID',
     .                c2='/DFS/DETCORD',
     .                i2=mdet)
        ELSEIF (unused==1) THEN
          CALL ancmsg(msgid=102,
     .                msgtype=msgerror,
     .                anmode=aninfo,
     .                i1=det_id,
     .                c1='DETONATOR IS REFERRING TO AN UNKNOWN MATERIAL ID',
     .                c2='/DFS/DETCORD',
     .                i2=mdet)
        ELSEIF (unused==2) THEN
          CALL ancmsg(msgid=102,msgtype=msgerror,anmode=aninfo,
     .                i1=det_id,
     .                c1='DETONATOR MUST REFER TO A JWL MATERIAL LAW (LAWS 5, 51, 97, 151)',
     .                c2='/DFS/DETCORD',
     .                i2=mdet)
        ELSEIF (nnod == 0) THEN
 
        ELSE
          detonators%CORD(idet)%IS_MAT_VALID = .true.
          !---------------------------------!
          !        LISTING PRINTOUT         !
          !---------------------------------!
          !IOPT=0  : def=3
          !IOPT=1  : Vdet  - multiple segments (experimental / osbslete)
          !IOPT=2  : instantaneous - multiple segments (experimental / obsolete)
          !IOPT=3  : Centripetal-Catmull-Rom SPLINE interpolation + projection along neutral fiber
          IF(is_encrypted) WRITE(iout,1001)
          IF(iopt == 0)iopt=3
          IF(iopt == 2)THEN
            IF(.NOT.is_encrypted)WRITE(iout,1700) det_id,igu,nnod,alt,mdet
          ELSEIF(iopt == 1)THEN
            IF(.NOT.is_encrypted)WRITE(iout,1701) det_id,igu,nnod,alt,vcj,mdet
          ELSEIF(iopt==3)THEN
            IF(.NOT.is_encrypted)WRITE(iout,1700) det_id,igu,nnod,alt,mdet
          ENDIF
 
          IF(.NOT.is_encrypted)WRITE(iout,fmt=fmw_10i) (itab(detonators%CORD(idet)%NODES(i)),i=1,nnod)
          DO i=1,nnod
            CALL ifrontplus(detonators%CORD(idet)%NODES(i),1)
          END DO
          IF(iopt == 1 .AND. vcj <= zero)iopt=2
 
          CALL detcord0(detonators%CORD(idet),alt,x,vcj,iopt)
 
          !---------------------------------!
          detonators%CORD(idet)%TDET= alt
          detonators%CORD(idet)%MAT = mat
          detonators%CORD(idet)%VDET = vcj
          detonators%CORD(idet)%IOPT = iopt
        END IF
 
      END do!next IDET
 
C-----------------------------------------------
C   O u t p u t   F o r m a t
C-----------------------------------------------      
 1001 FORMAT(///5x,
     &          'DETONATING CORD           ',i10,/5x,
     &          '---------------           ',/5x,
     &          'CONFIDENTIAL DATA')    
 1700 FORMAT(///5x,
     &          'DETONATING CORD            ',i10,/5x,
     &          '----------------           ',/5x,
     &          'NODE GROUP IDENTIFIER     =',i10     ,/5x,
     &          'NUMBER OF POINTS(CORD)    =',i10     ,/5x,         
     &          'LIGHTING TIME             =',1pg20.13,/5x,
     &          'EXPLOSIVE MATERIAL NUMBER =',i10     ,/5x,
     &          'CORD DEFINITION :          ')     
 1701 FORMAT(///5x,
     &          'DETONATING CORD            ',i10,/5x,
     &          '----------------           ',/5x,
     &          'NODE GROUP IDENTIFIER     =',i10     ,/5x,
     &          'NUMBER OF POINTS(CORD)    =',i10     ,/5x,         
     &          'LIGHTING TIME             =',1pg20.13,/5x,
     &          'DETONATION VELOCITY       =',1pg20.13,/5x,     
     &          'EXPLOSIVE MATERIAL NUMBER =',i10     ,/5x,
     &          'CORD DEFINITION :          ')     
C-----------------------------------------------