read_sensors.F File Reference

#include "implicit_f.inc"
#include "scr07_c.inc"
#include "scr17_c.inc"
#include "task_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	read_sensors (sensors, python)

Function/Subroutine Documentation

read_sensors()

subroutine read_sensors	(	type (sensors_), intent(inout)	sensors,
		type(python_), intent(in)	python )

Definition at line 39 of file read_sensors.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE python_funct_mod
      USE sensor_mod
      USE message_mod
      USE names_and_titles_mod, ONLY: nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include "implicit_f.inc"
#include "scr07_c.inc"
#include "scr17_c.inc"
#include "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (SENSORS_) ,INTENT(INOUT) :: SENSORS
      TYPE(PYTHON_), INTENT(IN) :: PYTHON
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,ISEN,LEN,IAD,NFIX,NPARI,NPARR,NVAR,TYP,NSENSOR,IERR
      INTEGER, DIMENSION(LTITR) :: ITITLE
      my_real, DIMENSION(:), ALLOCATABLE :: head,rbuf
      CHARACTER(LEN = NCHARTITLE) :: TITLE
      INTEGER :: PYID
C=======================================================================
      nsensor = sensors%NSENSOR
      ALLOCATE(sensors%SENSOR_TAB(nsensor))
      
      IF (nsensor > 0) THEN
        nfix = 11
        ALLOCATE (head(nfix) )
c
        DO isen=1,nsensor
          CALL read_db (head,nfix)
c
          sensors%SENSOR_TAB(isen)%TYPE    = nint(head(1))
          sensors%SENSOR_TAB(isen)%SENS_ID = nint(head(2))
          sensors%SENSOR_TAB(isen)%STATUS  = nint(head(3))
          sensors%SENSOR_TAB(isen)%TCRIT   = head(4)
          sensors%SENSOR_TAB(isen)%TMIN    = head(5)
          sensors%SENSOR_TAB(isen)%TDELAY  = head(6)
          sensors%SENSOR_TAB(isen)%TSTART  = head(7) 
          sensors%SENSOR_TAB(isen)%VALUE   = head(8)
          sensors%SENSOR_TAB(isen)%NPARI   = nint(head(9))
          sensors%SENSOR_TAB(isen)%NPARR   = nint(head(10))
          sensors%SENSOR_TAB(isen)%NVAR    = nint(head(11))
c
          npari = sensors%SENSOR_TAB(isen)%NPARI
          nparr = sensors%SENSOR_TAB(isen)%NPARR
          nvar  = sensors%SENSOR_TAB(isen)%NVAR
          
          ALLOCATE(sensors%SENSOR_TAB(isen)%IPARAM(npari))
          ALLOCATE(sensors%SENSOR_TAB(isen)%RPARAM(nparr))
          ALLOCATE(sensors%SENSOR_TAB(isen)%VAR(nvar))
c
          len   = npari + nparr + nvar
          ALLOCATE (rbuf(len) )
          CALL read_db (rbuf,len)
c
          iad = 0
          IF (npari > 0) THEN
            DO i = 1,npari
              sensors%SENSOR_TAB(isen)%IPARAM(i) = nint(rbuf(iad+i))
            END DO
            iad = iad + npari
          END IF
          IF (nparr > 0) THEN
            DO i = 1,nparr
              sensors%SENSOR_TAB(isen)%RPARAM(i) = rbuf(iad+i)
            END DO
            iad = iad + nparr
          END IF
          IF (nvar > 0) THEN
            DO i = 1,nvar
              sensors%SENSOR_TAB(isen)%VAR(i) = rbuf(iad+i)
            END DO
            iad = iad + nvar
          END IF
c           
          DEALLOCATE (rbuf)
c
c         read sensor title
          CALL read_i_c(ititle,ltitr)
          CALL fretitl2(title,ititle,ltitr)
          sensors%SENSOR_TAB(isen)%TITLE = title
c
          typ = sensors%SENSOR_TAB(isen)%TYPE
          IF (typ == 29 .OR. typ == 30 .OR. typ == 31)THEN
 
              ALLOCATE(sensors%SENSOR_TAB(isen)%INTEGER_USERPARAM(nsenpari))
              ALLOCATE(sensors%SENSOR_TAB(isen)%FLOAT_USERPARAM(nsenparr))
 
              ALLOCATE(sensors%SENSOR_TAB(isen)%INTEGER_USERBUF(isenbuf))
              ALLOCATE(sensors%SENSOR_TAB(isen)%FLOAT_USERBUF(lsenbuf))
 
              CALL read_i_c(sensors%SENSOR_TAB(isen)%INTEGER_USERPARAM,nsenpari)
              CALL read_i_c(sensors%SENSOR_TAB(isen)%INTEGER_USERBUF,isenbuf)
 
              CALL read_db (sensors%SENSOR_TAB(isen)%FLOAT_USERPARAM,nsenparr)
              CALL read_db (sensors%SENSOR_TAB(isen)%FLOAT_USERBUF,lsenbuf)
 
          ENDIF
          IF( typ == 40) THEN ! python senso
             CALL read_i_c(sensors%SENSOR_TAB(isen)%PYTHON_FUNCTION_ID,1)
              pyid = sensors%SENSOR_TAB(isen)%PYTHON_FUNCTION_ID
             CALL copy_python_function(python%FUNCTS(pyid),sensors%SENSOR_TAB(isen)%PYTHON_FUNCTION)
          ENDIF
 
        END DO
c
c--------------------------------------
c       Read Logical sensor index array
c
        CALL read_i_c(sensors%LOGICAL_SENSOR_COUNT,1)
 
        ALLOCATE(sensors%LOGICAL_SENSORS_LIST(sensors%LOGICAL_SENSOR_COUNT))
        CALL read_i_c(sensors%LOGICAL_SENSORS_LIST,sensors%LOGICAL_SENSOR_COUNT)
c
c--------------------------------------
c       Read spmd/PON exchange arrays
c
        ALLOCATE (sensors%FSAV(12,6,sensors%SFSAV)  ,stat=ierr)
        ALLOCATE (sensors%TABSENSOR(sensors%STABSEN),stat=ierr)
 
        CALL read_dpdb(sensors%FSAV,12*6*sensors%SFSAV)
 
        CALL read_i_c(sensors%TABSENSOR,sensors%STABSEN)
 
c--------------------------------------
        IF (mcheck /= 0 ) THEN
           CALL read_i_c(sensors%STOP ,sensors%NSTOP)   ! Must be read at any chkpt restart
        ENDIF
        IF (mcheck /= 0 .and. ispmd == 0) THEN
          CALL read_i_c(sensors%STAT ,sensors%NSTAT)
          CALL read_i_c(sensors%OUTP ,sensors%NOUTP)
          CALL read_i_c(sensors%ANIM ,sensors%NANIM)
        END IF 
c
        DEALLOCATE (head)
c
      END IF ! NSENSOR > 0
c--------------------------------------
      RETURN