sensor_hic.F File Reference

#include "implicit_f.inc"
#include "comlock.inc"
#include "param_c.inc"
#include "units_c.inc"
#include "com08_c.inc"
#include "task_c.inc"
#include "lockon.inc"
#include "lockoff.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	sensor_hic (sensor, accn, accel)

Function/Subroutine Documentation

sensor_hic()

subroutine sensor_hic	(	type (sensor_str_), target	sensor,
		dimension(3,*)	accn,
		dimension(llaccelm,*)	accel )

Definition at line 32 of file sensor_hic.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "units_c.inc"
#include      "com08_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real, DIMENSION(3,*) :: accn
      my_real, DIMENSION(LLACCELM,*) :: accel
      TYPE (SENSOR_STR_) ,TARGET :: SENSOR
C----------------------------------------------------------
C Local Variables
C----------------------------------------------------------
      INTEGER I,J,IDIR,IACC,ISENSOR_TYPE,NPOINT,INDX,NVAR,ICRIT
c
      my_real :: time_unit,time,xindx, integral,increment,time_interval
      my_real :: hic_period,hic_crit,hic,hic_prec,hic_tmp
      my_real :: time_prec,test_time,delta_t,beta
      my_real :: acc_x,acc_y,acc_z,acc,accg,acc_prec,current_value,gravity
      my_real :: period_tmp,opt_period,t1,t2,tmin,tdelay
      my_real ,DIMENSION(:) ,POINTER :: value_table
c
      DATA nvar/4/
c-----------------------------------------------------------------------
c     Sensor state variables
c        SENSOR%VAR(1) :  TIME_PREC   = beginning of current time interval
c        SENSOR%VAR(2) :  Integral of acceleration over time within current time interval
c        SENSOR%VAR(3) :  Index of current time interval in data table
c        SENSOR%VAR(4) :  Previous HIC value
c        SENSOR%VAR(5...5+NPOINT)  : average acceleration data table by time intervals
C=======================================================================
      IF (sensor%STATUS == 1) RETURN   ! already activated
c
      tmin   = sensor%TMIN
      tdelay = sensor%TDELAY
      isensor_type = sensor%IPARAM(1)
      iacc         = sensor%IPARAM(2)
      npoint       = sensor%IPARAM(3)
      idir         = sensor%IPARAM(4)
 
      hic_period   = sensor%RPARAM(1)
      hic_crit     = sensor%RPARAM(2)
      gravity      = sensor%RPARAM(3)
      time_unit    = sensor%RPARAM(4)
c
      time = tt
      beta = 2.5d0
      value_table(1:npoint) => sensor%VAR(nvar+1:nvar+npoint)
c      
      IF (isensor_type == 1) THEN   ! Acceletator based
        acc_x = accel(20,iacc)
        acc_y = accel(21,iacc)
        acc_z = accel(22,iacc)
      ELSE                          ! Node based
        acc_x = accn(1,iacc)
        acc_y = accn(2,iacc)
        acc_z = accn(3,iacc)
      END IF        
c
      IF (idir == 1) THEN     ! Resultant
        acc = sqrt(acc_x**2 + acc_y**2 + acc_z**2)
      ELSEIF (idir == 2) THEN    !  X
        acc = acc_x   
      ELSEIF (idir == 3) THEN    !  Y
        acc = acc_y  
      ELSE    !  Z
        acc = acc_z    
      END IF
      accg = acc / gravity
c
c...  Get last sensor state variables
 
      time_prec = sensor%VAR(1)
      acc_prec  = sensor%VAR(2)
      xindx     = sensor%VAR(3)
      hic_prec  = sensor%VAR(4)
      indx  = nint(xindx)
      icrit = 0
c
      time_interval = hic_period / npoint
      test_time = time_prec + time_interval
c
c.... Calculate new HIC value (only at the start of new time interval) 
c
      IF (time > test_time) THEN
        delta_t = time - time_prec
        ! average acceleration from previous time interval
        current_value = (acc_prec + accg*dt12) / delta_t
c
        IF (indx == npoint) THEN               
c         shift data to make place for new time interval when HIC_PERIOD is reached
          DO i = 1,npoint-1
            value_table(i) = value_table(i+1)   
          END DO                                
        ELSE          ! advance data index for next time interval                          
          indx = indx + 1                       
        ENDIF
        value_table(indx) = current_value       
c
c       Calculation of HIC
c       Searching for the period (lower or equal to HIC_PERIOD) maximizing HIC
c
        opt_period = zero
        hic  = zero
        DO i = 1,indx
          integral = zero
          DO j = i,indx
            integral = integral + value_table(j)*delta_t
          END DO
          increment = indx + 1 - i
          period_tmp = delta_t * increment
          hic_tmp = period_tmp * ((integral/period_tmp)**beta)
          hic_tmp = hic_tmp * time_unit          ! convert to seconds ???
          IF (hic_tmp > hic) THEN
            hic = hic_tmp
            opt_period = period_tmp            
            t1 = max(time - opt_period, zero)  
            t2 = time                          
          ENDIF
        END DO
c
c       Save sensor status, for next step
        sensor%VAR(1) = time
        sensor%VAR(2) = zero       ! reinitialize integral for next time interval
        sensor%VAR(3) = indx
        IF (hic >= hic_prec) THEN
          sensor%VAR(4) = hic
          icrit = 1
        ENDIF 
c
c.......Check Sensor State
        IF (sensor%TCRIT + tmin > tt) THEN
          IF (icrit == 0) THEN
            sensor%TCRIT = infinity
          ELSE IF (sensor%TCRIT == infinity) THEN
            sensor%TCRIT = min(sensor%TCRIT, tt)
          END IF
        ELSE IF (sensor%TSTART == infinity) THEN
          sensor%TSTART = sensor%TCRIT + tmin + tdelay
        END IF
c
        IF (sensor%TSTART <= tt) THEN   ! sensor activation
          sensor%STATUS = 1
        END IF
c
      ELSE    ! TIME < TEST_TIME
c       Calculate acceleration integral within current time interval 
        sensor%VAR(2) = sensor%VAR(2) + accg*dt12
      ENDIF  ! Fin of TIME test
c-----------------------------------------------------------------------      
      IF (sensor%STATUS == 1 .and. ispmd == 0) THEN
#include "lockon.inc"
        WRITE (istdo,1100 ) sensor%SENS_ID,sensor%TSTART
        WRITE (iout ,1100 ) sensor%SENS_ID,sensor%TSTART
        WRITE (iout ,1200)  hic, hic_period
        WRITE (iout ,1300)  t1, t2
#include "lockoff.inc"
      ENDIF
c-----------------------------------------------------------------------      
1100  FORMAT(' SENSOR NUMBER ',i10,' ,ACTIVATED AT TIME ',1pe12.5)
1200  FORMAT('      HIC     = ',1pe12.5,'  ,HIC PERIOD  = ',1pe12.5)           
1300  FORMAT('      TIME T1 = ',1pe12.5,'  ,TIME T2 = ',1pe12.5)
c-----------------------------------------------------------------------      
      RETURN