sigeps01c.F File Reference

#include "implicit_f.inc"
#include "mvsiz_p.inc"
#include "param_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	sigeps01c (jft, jlt, nel, imat, gs, sigoxx, sigoyy, sigoxy, sigoyz, sigozx, signxx, signyy, signxy, signyz, signzx, depsxx, depsyy, depsxy, depsyz, depszx, thk, thklyl, off, pm, ismstr, epsxx, epsyy, epsxy)

Function/Subroutine Documentation

sigeps01c()

subroutine sigeps01c	(	integer	jft,
		integer	jlt,
		integer	nel,
		integer	imat,
			gs,
			sigoxx,
			sigoyy,
			sigoxy,
			sigoyz,
			sigozx,
			signxx,
			signyy,
			signxy,
			signyz,
			signzx,
			depsxx,
			depsyy,
			depsxy,
			depsyz,
			depszx,
			thk,
			thklyl,
			off,
			pm,
		integer	ismstr,
			epsxx,
			epsyy,
			epsxy )

Definition at line 28 of file sigeps01c.F.

C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT,JLT,NPT,NEL,IMAT,ISMSTR
C     REAL
      my_real
     .  thk(*),gs(*), thklyl(nel),off(*),pm(npropm,*),
     .  sigoxx(nel),sigoyy(nel),sigoxy(nel),sigoyz(nel),sigozx(nel),
     .  signxx(nel),signyy(nel),signxy(nel),signyz(nel),signzx(nel),
     .  depsxx(mvsiz),depsyy(mvsiz),depsxy(mvsiz),depsyz(mvsiz),
     .  depszx(mvsiz),epsxx(mvsiz),epsyy(mvsiz),epsxy(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   ezz(mvsiz),nu,g,a1,a2
      my_real
     .   eigv(mvsiz,3,2),trav(mvsiz),rootv(mvsiz),  
     .   eh1(mvsiz),eh2(mvsiz),eb1(mvsiz),eb2(mvsiz),
     .   for1(mvsiz),for2(mvsiz)
C-----------------------------------------------
      nu = pm(21,imat)
      g  = pm(22,imat)
      a1 = pm(24,imat)
      a2 = pm(25,imat)
!
      DO i=jft,jlt
        signxx(i)=sigoxx(i)
        signyy(i)=sigoyy(i)
        signxy(i)=sigoxy(i)
        signyz(i)=sigoyz(i)
        signzx(i)=sigozx(i)
      ENDDO
!---
      IF (ismstr == 10) THEN
        DO i=jft,jlt
          epsxx(i) = epsxx(i) + one
          epsyy(i) = epsyy(i) + one
          epsxy(i) = half * epsxy(i)
        ENDDO
C     principal stretch (def gradient eigenvalues)
        DO i=jft,jlt
          trav(i)  = epsxx(i)+epsyy(i)
          rootv(i) = sqrt((epsxx(i)-epsyy(i))*(epsxx(i)-epsyy(i))
     .               + epsxy(i)*epsxy(i)*four)
          eb1(i) = half*(trav(i)+rootv(i)) 
          eb2(i) = half*(trav(i)-rootv(i)) 
          eh1(i) = half*log(eb1(i))
          eh2(i) = half*log(eb2(i))
          for1(i)= a1*eh1(i)+a2*eh2(i)
          for2(i)= a1*eh2(i)+a2*eh1(i)
        ENDDO
C     rot matrix (eigenvectors), ROOTV= 2R
        DO i=jft,jlt
          IF (abs(eb2(i)-eb1(i)) < em15) THEN
            eigv(i,1,1)=one
            eigv(i,2,1)=zero
            eigv(i,3,1)=zero
            eigv(i,1,2)=zero
            eigv(i,2,2)=one
            eigv(i,3,2)=zero
          ELSE                                             
            eigv(i,1,1) = (epsxx(i)-eb2(i)) / rootv(i)
            eigv(i,2,1) = (epsyy(i)-eb2(i)) / rootv(i)
            eigv(i,3,1) = (epsxy(i)) / rootv(i)
            eigv(i,1,2) = (eb1(i)-epsxx(i)) / rootv(i)
            eigv(i,2,2) = (eb1(i)-epsyy(i)) / rootv(i)
            eigv(i,3,2) =-(epsxy(i)) / rootv(i)            
          ENDIF                          
        ENDDO
      ENDIF ! IF (ISMSTR == 10) THEN
!---
!---------------------------
!     CONTRAINTES ELASTIQUES
!---------------------------
      IF (ismstr /= 10) THEN
        DO i=jft,jlt
          signxx(i) = signxx(i)+a1*depsxx(i)+a2*depsyy(i)
          signyy(i) = signyy(i)+a2*depsxx(i)+a1*depsyy(i)
          signxy(i) = signxy(i)+ g*depsxy(i)
          signyz(i) = signyz(i)+gs(i)*depsyz(i)
          signzx(i) = signzx(i)+gs(i)*depszx(i)
        ENDDO
      ELSE  !  ISMSTR = 10
        DO i=jft,jlt
          signxx(i) = eigv(i,1,1)*for1(i) + eigv(i,1,2)*for2(i)
          signyy(i) = eigv(i,2,1)*for1(i) + eigv(i,2,2)*for2(i)
          signxy(i) = eigv(i,3,1)*for1(i) + eigv(i,3,2)*for2(i)
          signyz(i) = sigoyz(i)+ gs(i)*depsyz(i)
          signzx(i) = sigozx(i)+ gs(i)*depszx(i)
        ENDDO
      ENDIF ! IF (ISMSTR /= 10)
!---
      DO i=jft,jlt
        ezz(i) = -nu * (depsxx(i) + depsyy(i)) / (one-nu)
        thk(i) = thk(i) + ezz(i) * thklyl(i)*off(i)
      ENDDO
!---
      RETURN