sigeps119c.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sigeps119c            ../engine/source/materials/mat/mat119/sigeps119c.F
!||--- called by ------------------------------------------------------
!||    mulawc                ../engine/source/materials/mat_share/mulawc.F90
!||--- calls      -----------------------------------------------------
!||    law119_membrane       ../engine/source/materials/mat/mat119/law119_membrane.F
!||--- uses       -----------------------------------------------------
!||    interface_table_mod   ../engine/share/modules/table_mod.F
!||    table_mod             ../engine/share/modules/table_mod.F
!||====================================================================
      SUBROUTINE sigeps119c(
     .            NEL     ,IPT     ,NPT     ,NUPARAM ,NUVAR   ,
     .            NUMTABL ,ITABLE  ,TABLE   ,UVAR    ,UPARAM  ,
     .            THK     ,THKLYL  ,SHF     ,SSP     ,OFF     ,
     .            IQEPH   ,ZCFAC   ,DEPSXX  ,DEPSYY  ,DEPSXY  ,
     .            EPSXX   ,EPSYY   ,EPSXY   ,EPSYZ   ,EPSZX   ,
     .            SIGOXX  ,SIGOYY  ,SIGOXY  ,SIGOYZ  ,SIGOZX  ,
     .            SIGNXX  ,SIGNYY  ,SIGNXY  ,SIGNYZ  ,SIGNZX  ,
     .            WMC     ,THLY    ,THK0)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE table_mod
      USE interface_table_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      LOGICAL ,INTENT(IN) :: IQEPH
      INTEGER ,INTENT(IN) :: NEL,IPT,NPT,NUPARAM,NUVAR,NUMTABL
      INTEGER ,DIMENSION(NUMTABL) ,INTENT(IN)  :: ITABLE
      my_real ,DIMENSION(NUPARAM) ,INTENT(IN)  :: UPARAM
      my_real ,DIMENSION(NEL)     ,INTENT(IN)  :: SHF,OFF,
     .   DEPSXX,DEPSYY,DEPSXY,EPSXX,EPSYY,EPSXY,EPSYZ,EPSZX,
     .   SIGOXX,SIGOYY,SIGOXY,SIGOYZ,SIGOZX,THK0
      my_real ,DIMENSION(MVSIZ,2),INTENT(INOUT) :: ZCFAC
      my_real ,DIMENSION(MVSIZ)  ,INTENT(INOUT) :: wmc
      my_real, DIMENSION(NEL)    ,INTENT(INOUT) :: thk,thly,thklyl
      my_real ,DIMENSION(NEL,NUVAR) ,INTENT(INOUT) :: uvar
      my_real ,DIMENSION(NEL) ,INTENT(OUT) :: ssp,
     .   signxx,signyy,signxy,signyz,signzx
      TYPE(ttable), DIMENSION(NTABLE) ::  TABLE
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I
      my_real :: nu,g12,gs,gc,a1c,a2c,tcoat,dezz
      my_real ,DIMENSION(NEL) :: et
C=======================================================================
      nu      = uparam(5)
      g12     = uparam(6)
      a1c     = uparam(14)
      a2c     = uparam(15)
      tcoat   = uparam(16)
      ssp     = uparam(17)
      gc      = uparam(20)
      gs      = g12*shf(1) 
c-------------------------------------------------------------------------
      IF (npt == 1) THEN ! membrane only
 
        CALL law119_membrane(
     .       nel    ,nuparam,nuvar  ,uparam ,uvar   ,
     .       gs     ,et     ,depsxx ,depsyy ,depsxy ,
     .       epsxx  ,epsyy  ,epsxy  ,epsyz  ,epszx  ,
     .       sigoxx ,sigoyy ,sigoxy ,sigoyz ,sigozx ,
     .       signxx ,signyy ,signxy ,signyz ,signzx ,
     .       numtabl,itable ,table  )
 
      ELSE  ! membrane + coating
 
        IF (ipt == 2) THEN
          CALL law119_membrane(
     .       nel    ,nuparam,nuvar  ,uparam ,uvar   ,
     .       gs     ,et     ,depsxx ,depsyy ,depsxy ,
     .       epsxx  ,epsyy  ,epsxy  ,epsyz  ,epszx  ,
     .       sigoxx ,sigoyy ,sigoxy ,sigoyz ,sigozx ,
     .       signxx ,signyy ,signxy ,signyz ,signzx ,
     .       numtabl,itable ,table  )
          thklyl(1:nel) = thk0(1:nel) - two*tcoat
          thly(1:nel)= one - two * tcoat / thk0(1:nel)
          wmc(1:nel) = zero
        ELSE    ! IPT = 1,3 => coating
          DO i=1,nel
            signxx(i) = a1c*epsxx(i) + a2c*epsyy(i)
            signyy(i) = a2c*epsxx(i) + a1c*epsyy(i)
            signxy(i) = gc*epsxy(i)
            signyz(i) = gc*epsyz(i)*shf(1)
            signzx(i) = gc*epszx(i)*shf(1)
          END DO
          thklyl(1:nel) = tcoat
          DO i=1,nel
            thly(i) = tcoat*(thk0(i)-tcoat) / (thk0(i)**2)
          END DO
          IF (ipt == 1) THEN
            wmc(1:nel) =-half*thly(1:nel)
          ELSE IF(ipt == 3) THEN
            wmc(1:nel) = half*thly(1:nel)
          END IF
        END IF
      END IF
c------------------------------------            
c       thickness update:
c------------------------------------            
      DO i=1,nel
        dezz = -(depsxx(i)+depsyy(i))*nu/(one-nu)
        thk(i) = thk(i) + dezz * thklyl(i)*off(i)
      ENDDO
C
C------for QEPH-------       
      IF (iqeph) THEN
        DO i=1,nel
          zcfac(i,1) = zcfac(i,1) + et(i) / npt
          zcfac(i,2) = min(et(i),zcfac(i,2))
        ENDDO
      ENDIF
c-----------
      RETURN
      END