spmd_exch_a_scnd_pon.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_exch_a_scnd_pon   ../engine/source/mpi/elements/spmd_exch_a_scnd_pon.F
!||--- called by ------------------------------------------------------
!||    s10cndamp              ../engine/source/elements/solid/solide10/s10cndf.F
!||    s10cndf1               ../engine/source/elements/solid/solide10/s10cndf.F
!||    s10cndf2               ../engine/source/elements/solid/solide10/s10cndf.F
!||    s10cnidamp             ../engine/source/elements/solid/solide10/s10cndf.F
!||    s10cnistat             ../engine/source/elements/solid/solide10/s10cndf.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod    ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_exch_a_scnd_pon(
     1   FR_CDNM,IAD_CDNM,ADDCNCDN,PROCNCDN,FR_NBCCCDN,
     2   ISIZE,LENR   ,LENS   ,FSKYCDN)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IAD_CDNM(*),FR_CDNM(*),FR_NBCCCDN(2,*),
     .        ADDCNCDN(*), PROCNCDN(*),ISIZE ,LENR ,LENS
      my_real
     .        fskycdn(isize,*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,I,NOD,LOC_PROC,IERROR, INDEXI, NISKYF, N, IDEB,
     .        SIZ, J, L, CC, NBIRECV, NBISEND, II, MSGOFF,
     .        iad_recv(nspmd+1), indexr(nspmd),indexs(nspmd),
     .        req_r(nspmd),req_s(nspmd),
     .        status(mpi_status_size),k
      my_real
     .        rbuf(lenr*isize),sbuf(lens*isize)
      DATA msgoff/1718/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
C
      nbirecv = 0
      nbisend = 0
      l = 1
      iad_recv(1) = 1
      DO i = 1, nspmd
        IF(fr_nbcccdn(2,i)>0) THEN
          siz = isize*fr_nbcccdn(2,i)
          msgtyp = msgoff
          nbirecv = nbirecv + 1
          indexr(nbirecv) = i
          CALL mpi_irecv(
     s      rbuf(l),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(nbirecv),ierror)
          l = l + siz
        ENDIF
        iad_recv(i+1) = l
        IF(fr_nbcccdn(1,i)>0) THEN
          nbisend = nbisend + 1
          indexs(nbisend) = i
        ENDIF
      ENDDO
C
C preparation envoi
C
      l = 1
      DO ii=1, nbisend
        i = indexs(ii)
           DO j=iad_cdnm(i),iad_cdnm(i+1)-1
            nod = fr_cdnm(j)
            DO cc = addcncdn(nod),addcncdn(nod+1)-1
              IF(procncdn(cc)==loc_proc) THEN
               DO k = 1, isize
                sbuf(l+k-1)   = fskycdn(k,cc)
               END DO
                l = l + isize
              ENDIF
            ENDDO
           END DO
      ENDDO
C
C   echange messages
C
      l = 1
      DO ii=1,nbisend
        i = indexs(ii)
        siz = isize*fr_nbcccdn(1,i) 
        msgtyp = msgoff 
        CALL mpi_isend(
     s      sbuf(l),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_s(ii),ierror)
        l = l + siz
      ENDDO
C
C decompactage
C
      DO ii=1,nbirecv
        CALL mpi_waitany(nbirecv,req_r,indexi,status,ierror)
        i = indexr(indexi)
        l = iad_recv(i)
           DO j=iad_cdnm(i),iad_cdnm(i+1)-1
            nod = fr_cdnm(j)
            DO cc = addcncdn(nod), addcncdn(nod+1)-1
              IF(procncdn(cc)==i) THEN
               DO k = 1, isize
                fskycdn(k,cc) = rbuf(l+k-1)
               END DO 
                l = l + isize
              ENDIF
            ENDDO
           END DO
      END DO
C
C   wait terminaison isend
C
      DO l=1,nbisend
        CALL mpi_waitany(nbisend,req_s,indexi,status,ierror)
      ENDDO
C
#endif
      RETURN
      END SUBROUTINE