spmd_exch_a_scnd_pon.F File Reference

#include "implicit_f.inc"
#include "spmd.inc"
#include "com01_c.inc"
#include "task_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	spmd_exch_a_scnd_pon (fr_cdnm, iad_cdnm, addcncdn, procncdn, fr_nbcccdn, isize, lenr, lens, fskycdn)

Function/Subroutine Documentation

spmd_exch_a_scnd_pon()

subroutine spmd_exch_a_scnd_pon	(	integer, dimension(*)	fr_cdnm,
		integer, dimension(*)	iad_cdnm,
		integer, dimension(*)	addcncdn,
		integer, dimension(*)	procncdn,
		integer, dimension(2,*)	fr_nbcccdn,
		integer	isize,
		integer	lenr,
		integer	lens,
			fskycdn )

Definition at line 35 of file spmd_exch_a_scnd_pon.F.

C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IAD_CDNM(*),FR_CDNM(*),FR_NBCCCDN(2,*),
     .        ADDCNCDN(*), PROCNCDN(*),ISIZE ,LENR ,LENS
      my_real
     .        fskycdn(isize,*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,I,NOD,LOC_PROC,IERROR, INDEXI, NISKYF, N, IDEB,
     .        SIZ, J, L, CC, NBIRECV, NBISEND, II, MSGOFF,
     .        IAD_RECV(NSPMD+1), INDEXR(NSPMD),INDEXS(NSPMD),
     .        REQ_R(NSPMD),REQ_S(NSPMD),
     .        STATUS(MPI_STATUS_SIZE),K
      my_real
     .        rbuf(lenr*isize),sbuf(lens*isize)
      DATA msgoff/1718/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
C
      nbirecv = 0
      nbisend = 0
      l = 1
      iad_recv(1) = 1
      DO i = 1, nspmd
        IF(fr_nbcccdn(2,i)>0) THEN
          siz = isize*fr_nbcccdn(2,i)
          msgtyp = msgoff
          nbirecv = nbirecv + 1
          indexr(nbirecv) = i
          CALL mpi_irecv(
     s      rbuf(l),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(nbirecv),ierror)
          l = l + siz
        ENDIF
        iad_recv(i+1) = l
        IF(fr_nbcccdn(1,i)>0) THEN
          nbisend = nbisend + 1
          indexs(nbisend) = i
        ENDIF
      ENDDO
C
C preparation envoi
C
      l = 1
      DO ii=1, nbisend
        i = indexs(ii)
           DO j=iad_cdnm(i),iad_cdnm(i+1)-1
            nod = fr_cdnm(j)
            DO cc = addcncdn(nod),addcncdn(nod+1)-1
              IF(procncdn(cc)==loc_proc) THEN
               DO k = 1, isize
                sbuf(l+k-1)   = fskycdn(k,cc)
               END DO
                l = l + isize
              ENDIF
            ENDDO
           END DO
      ENDDO
C
C   echange messages
C
      l = 1
      DO ii=1,nbisend
        i = indexs(ii)
        siz = isize*fr_nbcccdn(1,i) 
        msgtyp = msgoff 
        CALL mpi_isend(
     s      sbuf(l),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_s(ii),ierror)
        l = l + siz
      ENDDO
C
C decompactage
C
      DO ii=1,nbirecv
        CALL mpi_waitany(nbirecv,req_r,indexi,status,ierror)
        i = indexr(indexi)
        l = iad_recv(i)
           DO j=iad_cdnm(i),iad_cdnm(i+1)-1
            nod = fr_cdnm(j)
            DO cc = addcncdn(nod), addcncdn(nod+1)-1
              IF(procncdn(cc)==i) THEN
               DO k = 1, isize
                fskycdn(k,cc) = rbuf(l+k-1)
               END DO 
                l = l + isize
              ENDIF
            ENDDO
           END DO
      END DO
C
C   wait terminaison isend
C
      DO l=1,nbisend
        CALL mpi_waitany(nbisend,req_s,indexi,status,ierror)
      ENDDO
C
#endif
      RETURN