spmd_exch_rbe2_pon.F File Reference

#include "implicit_f.inc"
#include "spmd.inc"
#include "com01_c.inc"
#include "task_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	spmd_exch_rbe2_pon (a, ar, stifn, stifr, iad_m, fr_m, lcomm, isize)

Function/Subroutine Documentation

spmd_exch_rbe2_pon()

subroutine spmd_exch_rbe2_pon	(	double precision, dimension(3,6,*)	a,
		double precision, dimension(3,6,*)	ar,
		double precision, dimension(6,*)	stifn,
		double precision, dimension(6,*)	stifr,
		integer, dimension(*)	iad_m,
		integer, dimension(*)	fr_m,
		integer	lcomm,
		integer	isize )

Definition at line 31 of file spmd_exch_rbe2_pon.F.

C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER LCOMM, ISIZE, FR_M(*), IAD_M(*)
      double precision
     .        a(3,6,*), ar(3,6,*), stifn(6,*), stifr(6,*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,LOC_PROC,NOD,I,J,L,IDEB,IAD,LEN,
     .        NBINDEX,INDEX,MSGOFF,SIZ,IERROR,K,
     .        STATUS(MPI_STATUS_SIZE),ISIZE6,
     .        REQ_S(NSPMD),REQ_R(NSPMD),INDEXI(NSPMD),IROT
      DATA msgoff/211/
      double precision
     .        sbuf(lcomm*isize*6), rbuf(lcomm*isize*6)
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
      isize6=isize*6
      irot = 0
      IF (isize>4) irot=1
C
      ideb = 1
      l = 0
      DO i = 1, nspmd
        len = iad_m(i+1)-iad_m(i)
        IF(len>0) THEN
          siz = len*isize6
          l=l+1
          indexi(l)=i
          msgtyp = msgoff 
          CALL mpi_irecv(
     s      rbuf(ideb),siz,mpi_double_precision,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(l),ierror)
          ideb = ideb + siz
        ENDIF
      ENDDO
      nbindex = l
C
      ideb = 1
      DO l = 1, nbindex
        i = indexi(l)
        len = iad_m(i+1) - iad_m(i)
        iad = iad_m(i)-1
        IF (irot==0) THEN
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            DO k = 1, 6
             sbuf(ideb)   = a(1,k,nod)
             sbuf(ideb+1) = a(2,k,nod)
             sbuf(ideb+2) = a(3,k,nod)
             sbuf(ideb+3) = stifn(k,nod)
             ideb = ideb + isize
            ENDDO
          ENDDO
        ELSE
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            DO k = 1, 6
             sbuf(ideb)   = a(1,k,nod)
             sbuf(ideb+1) = a(2,k,nod)
             sbuf(ideb+2) = a(3,k,nod)
             sbuf(ideb+3) = ar(1,k,nod)
             sbuf(ideb+4) = ar(2,k,nod)
             sbuf(ideb+5) = ar(3,k,nod)
             sbuf(ideb+6) = stifn(k,nod)
             sbuf(ideb+7) = stifr(k,nod)
             ideb = ideb + isize
            ENDDO
          ENDDO
        ENDIF
      ENDDO
C
      ideb = 1
      DO l=1,nbindex
        i = indexi(l)
        len = iad_m(i+1)-iad_m(i)
        siz = len*isize6
        msgtyp = msgoff
        CALL mpi_isend(
     s    sbuf(ideb),siz,mpi_double_precision,it_spmd(i),msgtyp,
     g    spmd_comm_world,req_s(l),ierror)
        ideb = ideb + siz
      ENDDO
C
      DO l=1,nbindex
        CALL mpi_waitany(nbindex,req_r,index,status,ierror)
        i = indexi(index)
        ideb = 1+(iad_m(i)-1)*isize6
        len = iad_m(i+1)-iad_m(i)
        iad = iad_m(i)-1
        IF (irot==0) THEN
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            DO k = 1, 6
             a(1,k,nod)   = a(1,k,nod) + rbuf(ideb)
             a(2,k,nod)   = a(2,k,nod) + rbuf(ideb+1)
             a(3,k,nod)   = a(3,k,nod) + rbuf(ideb+2)
             stifn(k,nod) = stifn(k,nod)+rbuf(ideb+3)
             ideb = ideb + isize
            ENDDO
          ENDDO
        ELSE
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            DO k = 1, 6
             a(1,k,nod)   = a(1,k,nod) + rbuf(ideb)
             a(2,k,nod)   = a(2,k,nod) + rbuf(ideb+1)
             a(3,k,nod)   = a(3,k,nod) + rbuf(ideb+2)
             ar(1,k,nod)  = ar(1,k,nod)+ rbuf(ideb+3)
             ar(2,k,nod)  = ar(2,k,nod)+ rbuf(ideb+4)
             ar(3,k,nod)  = ar(3,k,nod)+ rbuf(ideb+5)
             stifn(k,nod) = stifn(k,nod)+rbuf(ideb+6)
             stifr(k,nod) = stifr(k,nod)+rbuf(ideb+7)
             ideb = ideb + isize
            ENDDO
          END DO
        END IF
      ENDDO
C
      DO l=1,nbindex
        CALL mpi_waitany(nbindex,req_s,index,status,ierror)
      ENDDO
C
#endif
      RETURN