spmd_exch_rbe3.F File Reference

Go to the source code of this file.

Functions/Subroutines
subroutine	spmd_exch_rbe3 (a, ar, ms, in, stifn, stifr, fr_m, iad_m, lcomm, isize, irot)

Function/Subroutine Documentation

spmd_exch_rbe3()

subroutine spmd_exch_rbe3	(		a,
			ar,
			ms,
			in,
			stifn,
			stifr,
		integer, dimension(*)	fr_m,
		integer, dimension(*)	iad_m,
		integer	lcomm,
		integer	isize,
		integer	irot )

Definition at line 31 of file spmd_exch_rbe3.F.

C realise le cumul des acc et masses aux noeuds main d'Rbe3
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER LCOMM, ISIZE, FR_M(*), IAD_M(*),IROT
      my_real
     .        a(3,*), ar(3,*), ms(*), in(*),
     .        stifn(*), stifr(*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,LOC_PROC,NOD,I,J,L,IDEB,IAD,LEN,
     .        NBINDEX,INDEX,MSGOFF,SIZ,IERROR,
     .        STATUS(MPI_STATUS_SIZE),
     .        REQ_S(NSPMD),REQ_R(NSPMD),INDEXI(NSPMD)
      DATA msgoff/207/
      my_real
     .        sbuf(lcomm*isize), rbuf(lcomm*isize)
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
C
      ideb = 1
      l = 0
      DO i = 1, nspmd
        len = iad_m(i+1)-iad_m(i)
        IF(len>0) THEN
          siz = len*isize
          l=l+1
          indexi(l)=i
          msgtyp = msgoff 
          CALL mpi_irecv(
     s      rbuf(ideb),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(l),ierror)
          ideb = ideb + siz
        ENDIF
      ENDDO
      nbindex = l
C
      ideb = 1
      DO l = 1, nbindex
        i = indexi(l)
        len = iad_m(i+1) - iad_m(i)
        iad = iad_m(i)-1
        IF (irot==0) THEN
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            sbuf(ideb)   = a(1,nod)
            sbuf(ideb+1) = a(2,nod)
            sbuf(ideb+2) = a(3,nod)
            sbuf(ideb+3) = ms(nod)
            sbuf(ideb+4) = stifn(nod)
            ideb = ideb + isize
          ENDDO
        ELSE
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            sbuf(ideb)   = a(1,nod)
            sbuf(ideb+1) = a(2,nod)
            sbuf(ideb+2) = a(3,nod)
            sbuf(ideb+3) = ar(1,nod)
            sbuf(ideb+4) = ar(2,nod)
            sbuf(ideb+5) = ar(3,nod)
            sbuf(ideb+6) = ms(nod)
            sbuf(ideb+7) = in(nod)
            sbuf(ideb+8) = stifn(nod)
            sbuf(ideb+9) = stifr(nod)
            ideb = ideb + isize
          ENDDO
        ENDIF
      ENDDO
C
      ideb = 1
      DO l=1,nbindex
        i = indexi(l)
        len = iad_m(i+1)-iad_m(i)
        siz = len*isize
        msgtyp = msgoff 
        CALL mpi_isend(
     s    sbuf(ideb),siz,real,it_spmd(i),msgtyp,
     g    spmd_comm_world,req_s(l),ierror)
        ideb = ideb + siz
      ENDDO
C
      DO l=1,nbindex
        CALL mpi_waitany(nbindex,req_r,index,status,ierror)
        i = indexi(index)
        ideb = 1+(iad_m(i)-1)*isize
        len = iad_m(i+1)-iad_m(i)
        iad = iad_m(i)-1
        IF (irot==0) THEN
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            a(1,nod)   = a(1,nod) + rbuf(ideb)
            a(2,nod)   = a(2,nod) + rbuf(ideb+1)
            a(3,nod)   = a(3,nod) + rbuf(ideb+2)
            ms(nod)    = ms(nod)  + rbuf(ideb+3)
            stifn(nod) = stifn(nod)+rbuf(ideb+4)
            ideb = ideb + isize
          ENDDO
        ELSE
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            a(1,nod)   = a(1,nod) + rbuf(ideb)
            a(2,nod)   = a(2,nod) + rbuf(ideb+1)
            a(3,nod)   = a(3,nod) + rbuf(ideb+2)
            ar(1,nod)  = ar(1,nod)+ rbuf(ideb+3)
            ar(2,nod)  = ar(2,nod)+ rbuf(ideb+4)
            ar(3,nod)  = ar(3,nod)+ rbuf(ideb+5)
            ms(nod)    = ms(nod)  + rbuf(ideb+6)
            in(nod)    = in(nod)  + rbuf(ideb+7)
            stifn(nod) = stifn(nod)+rbuf(ideb+8)
            stifr(nod) = stifr(nod)+rbuf(ideb+9)
            ideb = ideb + isize
          END DO
        END IF
      ENDDO
C
      DO l=1,nbindex
        CALL mpi_waitany(nbindex,req_s,index,status,ierror)
      ENDDO
C
#endif
      RETURN