spmd_exch_rbe3_pon.F File Reference

#include "implicit_f.inc"
#include "spmd.inc"
#include "com01_c.inc"
#include "task_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	spmd_exch_rbe3_pon (a, ar, ms, in, stifn, stifr, fr_m, iad_m, lcomm, isize, irot)

Function/Subroutine Documentation

spmd_exch_rbe3_pon()

subroutine spmd_exch_rbe3_pon	(	double precision, dimension(6,3,*)	a,
		double precision, dimension(6,3,*)	ar,
		double precision, dimension(6,*)	ms,
		double precision, dimension(6,*)	in,
		double precision, dimension(6,*)	stifn,
		double precision, dimension(6,*)	stifr,
		integer, dimension(*)	fr_m,
		integer, dimension(*)	iad_m,
		integer	lcomm,
		integer	isize,
		integer	irot )

Definition at line 32 of file spmd_exch_rbe3_pon.F.

C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER LCOMM, ISIZE, FR_M(*), IAD_M(*),IROT
      double precision
     .        a(6,3,*), ar(6,3,*), ms(6,*), in(6,*),
     .        stifn(6,*), stifr(6,*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,LOC_PROC,NOD,I,J,L,IDEB,IAD,LEN,
     .        NBINDEX,INDEX,MSGOFF,SIZ,IERROR,K,
     .        STATUS(MPI_STATUS_SIZE),ISIZE6,
     .        REQ_S(NSPMD),REQ_R(NSPMD),INDEXI(NSPMD)
      DATA msgoff/208/
      double precision
     .        sbuf(lcomm*isize*6), rbuf(lcomm*isize*6)
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
      isize6=isize*6
C
      ideb = 1
      l = 0
      DO i = 1, nspmd
        len = iad_m(i+1)-iad_m(i)
        IF(len>0) THEN
          siz = len*isize6
          l=l+1
          indexi(l)=i
          msgtyp = msgoff 
          CALL mpi_irecv(
     s      rbuf(ideb),siz,mpi_double_precision,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(l),ierror)
          ideb = ideb + siz
        ENDIF
      ENDDO
      nbindex = l
C
      ideb = 1
      DO l = 1, nbindex
        i = indexi(l)
        len = iad_m(i+1) - iad_m(i)
        iad = iad_m(i)-1
        IF (irot==0) THEN
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            DO k = 1, 6
             sbuf(ideb)   = a(k,1,nod)
             sbuf(ideb+1) = a(k,2,nod)
             sbuf(ideb+2) = a(k,3,nod)
             sbuf(ideb+3) = ms(k,nod)
             sbuf(ideb+4) = stifn(k,nod)
             ideb = ideb + isize
            ENDDO
          ENDDO
        ELSE
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            DO k = 1, 6
             sbuf(ideb)   = a(k,1,nod)
             sbuf(ideb+1) = a(k,2,nod)
             sbuf(ideb+2) = a(k,3,nod)
             sbuf(ideb+3) = ar(k,1,nod)
             sbuf(ideb+4) = ar(k,2,nod)
             sbuf(ideb+5) = ar(k,3,nod)
             sbuf(ideb+6) = ms(k,nod)
             sbuf(ideb+7) = in(k,nod)
             sbuf(ideb+8) = stifn(k,nod)
             sbuf(ideb+9) = stifr(k,nod)
             ideb = ideb + isize
            ENDDO
          ENDDO
        ENDIF
      ENDDO
C
      ideb = 1
      DO l=1,nbindex
        i = indexi(l)
        len = iad_m(i+1)-iad_m(i)
        siz = len*isize6
        msgtyp = msgoff 
        CALL mpi_isend(
     s    sbuf(ideb),siz,mpi_double_precision,it_spmd(i),msgtyp,
     g    spmd_comm_world,req_s(l),ierror)
        ideb = ideb + siz
      ENDDO
C
      DO l=1,nbindex
        CALL mpi_waitany(nbindex,req_r,index,status,ierror)
        i = indexi(index)
        ideb = 1+(iad_m(i)-1)*isize6
        len = iad_m(i+1)-iad_m(i)
        iad = iad_m(i)-1
        IF (irot==0) THEN
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            DO k = 1, 6
             a(k,1,nod)   = a(k,1,nod) + rbuf(ideb)
             a(k,2,nod)   = a(k,2,nod) + rbuf(ideb+1)
             a(k,3,nod)   = a(k,3,nod) + rbuf(ideb+2)
             ms(k,nod)    = ms(k,nod)  + rbuf(ideb+3)
             stifn(k,nod) = stifn(k,nod)+rbuf(ideb+4)
             ideb = ideb + isize
            ENDDO
          ENDDO
        ELSE
#include      "vectorize.inc"
          DO j = 1, len
            nod = fr_m(iad+j)
            DO k = 1, 6
             a(k,1,nod)   = a(k,1,nod) + rbuf(ideb)
             a(k,2,nod)   = a(k,2,nod) + rbuf(ideb+1)
             a(k,3,nod)   = a(k,3,nod) + rbuf(ideb+2)
             ar(k,1,nod)  = ar(k,1,nod)+ rbuf(ideb+3)
             ar(k,2,nod)  = ar(k,2,nod)+ rbuf(ideb+4)
             ar(k,3,nod)  = ar(k,3,nod)+ rbuf(ideb+5)
             ms(k,nod)    = ms(k,nod)  + rbuf(ideb+6)
             in(k,nod)    = in(k,nod)  + rbuf(ideb+7)
             stifn(k,nod) = stifn(k,nod)+rbuf(ideb+8)
             stifr(k,nod) = stifr(k,nod)+rbuf(ideb+9)
             ideb = ideb + isize
            ENDDO
          END DO
        END IF
      ENDDO
C
      DO l=1,nbindex
        CALL mpi_waitany(nbindex,req_s,index,status,ierror)
      ENDDO
C
#endif
      RETURN